[gentoo-commits] gentoo-x86 commit in dev-ml/ocamlnet: ChangeLog ocamlnet-4.0.1.ebuild

[Alexis Ballier (aballier)]

aballier    15/02/09 14:37:04

  Modified:             ChangeLog
  Added:                ocamlnet-4.0.1.ebuild
  Log:
  version bump
  
  Signed-off-by: aballier@g.o
  (Portage version: 2.2.16/cvs/Linux x86_64, signed Manifest commit with key 160F534A)

Revision  Changes    Path
1.85                 dev-ml/ocamlnet/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-ml/ocamlnet/ChangeLog?rev=1.85&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-ml/ocamlnet/ChangeLog?rev=1.85&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-ml/ocamlnet/ChangeLog?r1=1.84&r2=1.85

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-ml/ocamlnet/ChangeLog,v
retrieving revision 1.84
retrieving revision 1.85
diff -u -r1.84 -r1.85
--- ChangeLog	28 Nov 2014 17:10:46 -0000	1.84
+++ ChangeLog	9 Feb 2015 14:37:04 -0000	1.85
@@ -1,6 +1,11 @@
 # ChangeLog for dev-ml/ocamlnet
-# Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-ml/ocamlnet/ChangeLog,v 1.84 2014/11/28 17:10:46 aballier Exp $
+# Copyright 1999-2015 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/dev-ml/ocamlnet/ChangeLog,v 1.85 2015/02/09 14:37:04 aballier Exp $
+
+*ocamlnet-4.0.1 (09 Feb 2015)
+
+  09 Feb 2015; Alexis Ballier <aballier@g.o> +ocamlnet-4.0.1.ebuild:
+  version bump
 
   28 Nov 2014; Alexis Ballier <aballier@g.o> ocamlnet-3.7.7.ebuild:
   update deps for ocaml 4.02



1.1                  dev-ml/ocamlnet/ocamlnet-4.0.1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-ml/ocamlnet/ocamlnet-4.0.1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-ml/ocamlnet/ocamlnet-4.0.1.ebuild?rev=1.1&content-type=text/plain

Index: ocamlnet-4.0.1.ebuild
===================================================================
# Copyright 1999-2015 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-ml/ocamlnet/ocamlnet-4.0.1.ebuild,v 1.1 2015/02/09 14:37:04 aballier Exp $

EAPI="5"

inherit eutils findlib

MY_P=${P/_beta/test}
DESCRIPTION="Modules for OCaml application-level Internet protocols"
HOMEPAGE="http://projects.camlcity.org/projects/ocamlnet.html"
SRC_URI="http://download.camlcity.org/download/${MY_P}.tar.gz"

LICENSE="ZLIB GPL-2+"
SLOT="0/${PV}"
KEYWORDS="~amd64 ~ppc ~x86 ~x86-fbsd"
IUSE="gtk kerberos tk httpd +ocamlopt +pcre ssl zip"
RESTRICT="installsources"

# the auth-dh compile flag has been disabled as well, since it depends on
# ocaml-cryptgps, which is not available.

RDEPEND=">=dev-ml/findlib-1.0
		pcre? ( >=dev-ml/pcre-ocaml-5:= )
		>=dev-lang/ocaml-3.10.2:=[ocamlopt?]
		tk? ( || ( dev-ml/labltk:= <dev-lang/ocaml-4.02[tk] ) )
		ssl? ( net-libs/gnutls:= )
		gtk? ( >=dev-ml/lablgtk-2:= )
		kerberos? ( virtual/krb5 )
		zip? ( dev-ml/camlzip:= )
		"
DEPEND="${RDEPEND}
	virtual/pkgconfig
"

S=${WORKDIR}/${MY_P}

ocamlnet_use_with() {
	if use $1; then
		echo "-with-$2"
	else
		echo "-without-$2"
	fi
}

ocamlnet_use_enable() {
	if use $1; then
		echo "-enable-$2"
	else
		echo "-disable-$2"
	fi
}

src_configure() {
	./configure \
		-bindir /usr/bin \
		-datadir /usr/share/${PN} \
		$(ocamlnet_use_enable ssl gnutls) \
		$(ocamlnet_use_enable gtk gtk2) \
		$(ocamlnet_use_enable kerberos gssapi) \
		$(ocamlnet_use_enable pcre pcre) \
		$(ocamlnet_use_enable tk tcl) \
		$(ocamlnet_use_enable zip zip) \
		$(ocamlnet_use_with httpd nethttpd) \
		|| die "Error : econf failed!"
}

src_compile() {
	emake -j1 all
	if use ocamlopt; then
		emake -j1 opt
	fi
}

src_install() {
	export STRIP_MASK="*/bin/*"
	findlib_src_install
}