[gentoo-commits] repo/gentoo:master commit in: net-misc/electrum/

[Michał Górny]

commit:     afd23a153e6571f38b15fead9165ec109b43c78c
Author:     Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Thu Apr  1 07:24:15 2021 +0000
Commit:     Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Thu Apr  1 07:24:15 2021 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=afd23a15

net-misc/electrum: Bump to 4.1.0

Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>

 net-misc/electrum/Manifest              |  1 +
 net-misc/electrum/electrum-4.1.0.ebuild | 97 +++++++++++++++++++++++++++++++++
 2 files changed, 98 insertions(+)

diff --git a/net-misc/electrum/Manifest b/net-misc/electrum/Manifest
index bb1df357394..4c90e54bf0b 100644
--- a/net-misc/electrum/Manifest
+++ b/net-misc/electrum/Manifest
@@ -1 +1,2 @@
 DIST electrum-4.0.9.gh.tar.gz 4435268 BLAKE2B e1dfe319f7b4beffd039164c97d247f5d267d9d99313480bf06f9b748d095b33859cd8ea5dd5a135b38a1a206858e08ce500af8982ef7a6e3b3f7ff0233b9637 SHA512 a9a04163c8d76006ca18e1c50f38cabd7c3d7d75b16c8504627b9eb49bf9dca91800e18a585e7afd0b98fafeeeb821b967bea29928a46d10f65f0abc3fb90887
+DIST electrum-4.1.0.gh.tar.gz 4539032 BLAKE2B 72ef52a000799e496e6ccca152dc8bec827aef23d4e3290fd2e86ace0f96e9267f68b56c390b873658dc8f6e6998080bd0283494ee74603c360dfe250b64c282 SHA512 7dd94bfc23f78e915f42f1043f6b7e9d0d6d5de7303418da8d2f3bd53ece794c74c3cd0dd9d77b370a6c6f049261273b170ddcb67f6c3dc7189869b200e8d437

diff --git a/net-misc/electrum/electrum-4.1.0.ebuild b/net-misc/electrum/electrum-4.1.0.ebuild
new file mode 100644
index 00000000000..434ffec4d5b
--- /dev/null
+++ b/net-misc/electrum/electrum-4.1.0.ebuild
@@ -0,0 +1,97 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI="7"
+
+PYTHON_COMPAT=( python3_8 )
+PYTHON_REQ_USE="ncurses?"
+
+inherit desktop distutils-r1 xdg-utils
+
+DESCRIPTION="User friendly Bitcoin client"
+HOMEPAGE="https://electrum.org/"
+SRC_URI="
+	https://github.com/spesmilo/electrum/archive/${PV}.tar.gz
+		-> ${P}.gh.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="cli ncurses qrcode +qt5"
+REQUIRED_USE="|| ( cli ncurses qt5 )"
+
+RDEPEND="${PYTHON_DEPS}
+	dev-libs/libsecp256k1
+	>=dev-python/aiohttp-socks-0.3[${PYTHON_USEDEP}]
+	=dev-python/aiorpcX-0.19*[${PYTHON_USEDEP}]
+	>=dev-python/attrs-19.2.0[${PYTHON_USEDEP}]
+	dev-python/bitstring[${PYTHON_USEDEP}]
+	dev-python/cryptography[${PYTHON_USEDEP}]
+	>=dev-python/dnspython-2[${PYTHON_USEDEP}]
+	dev-python/pbkdf2[${PYTHON_USEDEP}]
+	dev-python/PySocks[${PYTHON_USEDEP}]
+	dev-python/qrcode[${PYTHON_USEDEP}]
+	dev-python/requests[${PYTHON_USEDEP}]
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	dev-python/six[${PYTHON_USEDEP}]
+	>=dev-python/protobuf-python-3.12[${PYTHON_USEDEP}]
+	qrcode? ( media-gfx/zbar[v4l] )
+	qt5? (
+		dev-python/PyQt5[gui,widgets,${PYTHON_USEDEP}]
+	)
+	ncurses? ( $(python_gen_impl_dep 'ncurses') )
+"
+BDEPEND="
+	test? (
+		dev-python/pyaes[${PYTHON_USEDEP}]
+		dev-python/pycryptodome[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+src_prepare() {
+	eapply "${FILESDIR}/3.1.2-no-user-root.patch"
+	eapply "${FILESDIR}/3.3.2-desktop.patch"
+
+	# unbind aiorpcX dep
+	sed -e '/aiorpcX/s:,<0.19::' \
+		-i contrib/requirements/requirements.txt || die
+
+	# Prevent icon from being installed in the wrong location
+	sed -i '/icons_dirname/d' setup.py || die
+
+	# use backwards-compatible cryptodome API
+	sed -i -e 's:Cryptodome:Crypto:' electrum/crypto.py || die
+
+	local bestgui
+	if use qt5; then
+		bestgui=qt
+	elif use ncurses; then
+		bestgui=text
+	else
+		bestgui=stdio
+	fi
+	sed -i 's/^\([[:space:]]*\)\(config_options\['\''cwd'\''\] = .*\)$/\1\2\n\1config_options.setdefault("gui", "'"${bestgui}"'")\n/' ${PN}/${PN} || die
+
+	eapply_user
+
+	xdg_environment_reset
+	distutils-r1_src_prepare
+}
+
+src_install() {
+	doicon -s 128 electrum/gui/icons/${PN}.png
+	dodoc RELEASE-NOTES
+	distutils-r1_src_install
+}
+
+pkg_postinst() {
+	xdg_icon_cache_update
+	xdg_desktop_database_update
+}
+
+pkg_postrm() {
+	xdg_icon_cache_update
+	xdg_desktop_database_update
+}