[gentoo-commits] gentoo-x86 commit in app-mobilephone/gammu: ChangeLog gammu-1.27.0.ebuild

[Christian Faulhammer (fauli)]

fauli       10/02/01 21:46:21

  Modified:             ChangeLog
  Added:                gammu-1.27.0.ebuild
  Log:
  version bump for bug 298020
  (Portage version: 2.1.7.16/cvs/Linux i686)

Revision  Changes    Path
1.79                 app-mobilephone/gammu/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-mobilephone/gammu/ChangeLog?rev=1.79&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-mobilephone/gammu/ChangeLog?rev=1.79&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-mobilephone/gammu/ChangeLog?r1=1.78&r2=1.79

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-mobilephone/gammu/ChangeLog,v
retrieving revision 1.78
retrieving revision 1.79
diff -u -r1.78 -r1.79
--- ChangeLog	24 Oct 2009 11:02:16 -0000	1.78
+++ ChangeLog	1 Feb 2010 21:46:20 -0000	1.79
@@ -1,6 +1,11 @@
 # ChangeLog for app-mobilephone/gammu
-# Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-mobilephone/gammu/ChangeLog,v 1.78 2009/10/24 11:02:16 nixnut Exp $
+# Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/app-mobilephone/gammu/ChangeLog,v 1.79 2010/02/01 21:46:20 fauli Exp $
+
+*gammu-1.27.0 (01 Feb 2010)
+
+  01 Feb 2010; Christian Faulhammer <fauli@g.o> +gammu-1.27.0.ebuild:
+  version bump for bug 298020
 
   24 Oct 2009; nixnut <nixnut@g.o> gammu-1.25.0-r1.ebuild:
   ppc stable #283672



1.1                  app-mobilephone/gammu/gammu-1.27.0.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-mobilephone/gammu/gammu-1.27.0.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-mobilephone/gammu/gammu-1.27.0.ebuild?rev=1.1&content-type=text/plain

Index: gammu-1.27.0.ebuild
===================================================================
# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-mobilephone/gammu/gammu-1.27.0.ebuild,v 1.1 2010/02/01 21:46:20 fauli Exp $

EAPI="2"

inherit cmake-utils distutils

DESCRIPTION="a fork of the gnokii project, a tool to handle your cellular phone"
HOMEPAGE="http://www.gammu.org"
SRC_URI="http://dl.cihar.com/gammu/releases/${P}.tar.bz2"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~x86"
IUSE="curl debug bluetooth irda mysql postgres dbi nls python usb"

RDEPEND="bluetooth? ( || ( net-wireless/bluez net-wireless/bluez-libs ) )
	curl? ( net-misc/curl )
	usb? ( dev-libs/libusb:1 )
	mysql? ( virtual/mysql )
	postgres? ( virtual/postgresql-server )
	dbi? ( >=dev-db/libdbi-0.8.3 )
	dev-util/dialog
	dev-lang/python
	!dev-python/python-gammu" # needs to be removed from the tree
DEPEND="${RDEPEND}
	irda? ( virtual/os-headers )
	nls? ( sys-devel/gettext )
	dev-util/cmake"

# sys-devel/gettext is needed for creating .mo files
# Supported languages and translated documentation
# Be sure all languages are prefixed with a single space!
MY_AVAILABLE_LINGUAS=" af bg ca cs da de el es et fi fr gl he hu id it ko nl pl pt_BR ru sk sv sw zh_CN zh_TW"
IUSE="${IUSE} ${MY_AVAILABLE_LINGUAS// / linguas_}"

src_prepare() {
	epatch "${FILESDIR}"/${PN}-skip-locktest.patch

	local lang support_linguas=no
	for lang in ${MY_AVAILABLE_LINGUAS} ; do
		if use linguas_${lang} ; then
			support_linguas=yes
			break
		fi
	done
	# install all languages when all selected LINGUAS aren't supported
	if [ "${support_linguas}" = "yes" ]; then
		for lang in ${MY_AVAILABLE_LINGUAS} ; do
			if ! use linguas_${lang} ; then
				rm -rf locale/${lang} || die
			fi
		done
	fi
}

src_configure() {
	# debug flag is used inside cmake-utils.eclass
	local mycmakeargs="$(cmake-utils_use_with bluetooth Bluez) \
		$(cmake-utils_use_with irda IRDA) \
		$(cmake-utils_use_with curl CURL) \
		$(cmake-utils_use_with usb USB) \
		$(cmake-utils_use_with python PYTHON) \
		$(cmake-utils_use_with mysql MySQL) \
		$(cmake-utils_use_with postgres Postgres) \
		$(cmake-utils_use_with dbi LibDBI) \
		$(cmake-utils_use_with nls GettextLibs) \
		$(cmake-utils_use_with nls Iconv) \
		-DBUILD_SHARED_LIBS=ON -DINSTALL_DOC_DIR=share/doc/${PF}"
	if use python; then
		mycmakeargs="${mycmakeargs} -DBUILD_PYTHON=/usr/bin/python"
	fi
	cmake-utils_src_configure
}

src_compile() {
	cmake-utils_src_compile
}

src_test() {
	LD_LIBRARY_PATH="${WORKDIR}"/${PN}_build/common cmake-utils_src_test
}

src_install() {
	cmake-utils_src_install
}