[gentoo-commits] gentoo-x86 commit in dev-util/desktop-file-utils: ChangeLog desktop-file-utils-0.20-r1.ebuild

[Samuli Suominen (ssuominen)]

ssuominen    12/04/05 07:10:13

  Modified:             ChangeLog
  Added:                desktop-file-utils-0.20-r1.ebuild
  Log:
  New main category XFCE for Xfce 4.10 compability.
  
  (Portage version: 2.2.0_alpha98/cvs/Linux x86_64)

Revision  Changes    Path
1.116                dev-util/desktop-file-utils/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-util/desktop-file-utils/ChangeLog?rev=1.116&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-util/desktop-file-utils/ChangeLog?rev=1.116&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-util/desktop-file-utils/ChangeLog?r1=1.115&r2=1.116

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-util/desktop-file-utils/ChangeLog,v
retrieving revision 1.115
retrieving revision 1.116
diff -u -r1.115 -r1.116
--- ChangeLog	18 Mar 2012 15:31:46 -0000	1.115
+++ ChangeLog	5 Apr 2012 07:10:13 -0000	1.116
@@ -1,6 +1,13 @@
 # ChangeLog for dev-util/desktop-file-utils
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-util/desktop-file-utils/ChangeLog,v 1.115 2012/03/18 15:31:46 armin76 Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-util/desktop-file-utils/ChangeLog,v 1.116 2012/04/05 07:10:13 ssuominen Exp $
+
+*desktop-file-utils-0.20-r1 (05 Apr 2012)
+
+  05 Apr 2012; Samuli Suominen <ssuominen@g.o>
+  +desktop-file-utils-0.20-r1.ebuild,
+  +files/desktop-file-utils-0.20-validate_Categories_XFCE.patch:
+  New main category XFCE for Xfce 4.10 compability.
 
   18 Mar 2012; Raúl Porcel <armin76@g.o>
   desktop-file-utils-0.19.ebuild:



1.1                  dev-util/desktop-file-utils/desktop-file-utils-0.20-r1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-util/desktop-file-utils/desktop-file-utils-0.20-r1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-util/desktop-file-utils/desktop-file-utils-0.20-r1.ebuild?rev=1.1&content-type=text/plain

Index: desktop-file-utils-0.20-r1.ebuild
===================================================================
# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-util/desktop-file-utils/desktop-file-utils-0.20-r1.ebuild,v 1.1 2012/04/05 07:10:13 ssuominen Exp $

EAPI=4
inherit elisp-common eutils

DESCRIPTION="Command line utilities to work with desktop menu entries"
HOMEPAGE="http://freedesktop.org/wiki/Software/desktop-file-utils"
SRC_URI="http://www.freedesktop.org/software/${PN}/releases/${P}.tar.xz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~x86-fbsd ~x86-interix ~amd64-linux ~x86-linux ~x86-macos ~sparc-solaris ~x64-solaris ~x86-solaris"
IUSE="emacs"

RDEPEND=">=dev-libs/glib-2.12
	emacs? ( virtual/emacs )"
DEPEND="${RDEPEND}
	dev-util/pkgconfig"

SITEFILE=50${PN}-gentoo.el

DOCS=( AUTHORS ChangeLog HACKING NEWS README )

src_prepare() {
	epatch "${FILESDIR}"/${P}-validate_Categories_XFCE.patch

	sed -i -e '/SUBDIRS =/s:misc::' Makefile.in || die
}

src_configure() {
	econf "$(use_with emacs lispdir "${SITELISP}"/${PN})"
}

src_compile() {
	default
	use emacs && elisp-compile misc/desktop-entry-mode.el
}

src_install() {
	default
	if use emacs; then
		elisp-install ${PN} misc/*.el misc/*.elc || die
		elisp-site-file-install "${FILESDIR}"/${SITEFILE} || die
	fi
}

pkg_postinst() {
	use emacs && elisp-site-regen
}

pkg_postrm() {
	use emacs && elisp-site-regen
}