[gentoo-commits] gentoo-x86 commit in net-misc/dropbox: metadata.xml ChangeLog dropbox-2.2.8.ebuild

[Justin Lecher (jlec)]

jlec        13/07/02 10:33:32

  Modified:             metadata.xml ChangeLog
  Added:                dropbox-2.2.8.ebuild
  Log:
  net-misc/dropbox: Version Bump
  
  (Portage version: 2.2.0_alpha186/cvs/Linux x86_64, signed Manifest commit with key 8009D6F070EB7916)

Revision  Changes    Path
1.5                  net-misc/dropbox/metadata.xml

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/dropbox/metadata.xml?rev=1.5&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/dropbox/metadata.xml?rev=1.5&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/dropbox/metadata.xml?r1=1.4&r2=1.5

Index: metadata.xml
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-misc/dropbox/metadata.xml,v
retrieving revision 1.4
retrieving revision 1.5
diff -u -r1.4 -r1.5
--- metadata.xml	25 Feb 2012 13:28:28 -0000	1.4
+++ metadata.xml	2 Jul 2013 10:33:32 -0000	1.5
@@ -1,10 +1,10 @@
 <?xml version="1.0" encoding="UTF-8"?>
 <!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
 <pkgmetadata>
-	<maintainer>
-		<email>naota@g.o</email>
-	</maintainer>
-	<use>
-		<flag name="librsync-bundled">Use bundled librsync library</flag>
-	</use>
+  <maintainer>
+    <email>naota@g.o</email>
+  </maintainer>
+  <use>
+    <flag name="librsync-bundled">Use bundled librsync library</flag>
+  </use>
 </pkgmetadata>



1.37                 net-misc/dropbox/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/dropbox/ChangeLog?rev=1.37&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/dropbox/ChangeLog?rev=1.37&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/dropbox/ChangeLog?r1=1.36&r2=1.37

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-misc/dropbox/ChangeLog,v
retrieving revision 1.36
retrieving revision 1.37
diff -u -r1.36 -r1.37
--- ChangeLog	15 May 2013 22:29:37 -0000	1.36
+++ ChangeLog	2 Jul 2013 10:33:32 -0000	1.37
@@ -1,6 +1,12 @@
 # ChangeLog for net-misc/dropbox
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-misc/dropbox/ChangeLog,v 1.36 2013/05/15 22:29:37 naota Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-misc/dropbox/ChangeLog,v 1.37 2013/07/02 10:33:32 jlec Exp $
+
+*dropbox-2.2.8 (02 Jul 2013)
+
+  02 Jul 2013; Justin Lecher <jlec@g.o> +dropbox-2.2.8.ebuild,
+  metadata.xml:
+  Version Bump
 
   15 May 2013; Naohiro Aota <naota@g.o> -dropbox-1.2.48-r1.ebuild,
   -dropbox-1.2.51-r2.ebuild, -dropbox-1.4.17.ebuild, -dropbox-1.4.23.ebuild,



1.1                  net-misc/dropbox/dropbox-2.2.8.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/dropbox/dropbox-2.2.8.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/dropbox/dropbox-2.2.8.ebuild?rev=1.1&content-type=text/plain

Index: dropbox-2.2.8.ebuild
===================================================================
# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-misc/dropbox/dropbox-2.2.8.ebuild,v 1.1 2013/07/02 10:33:32 jlec Exp $

EAPI=5

inherit eutils gnome2-utils pax-utils

DESCRIPTION="Dropbox daemon (pretends to be GUI-less)"
HOMEPAGE="http://dropbox.com/"
SRC_URI="
	x86? ( http://dl-web.dropbox.com/u/17/dropbox-lnx.x86-${PV}.tar.gz )
	amd64? ( http://dl-web.dropbox.com/u/17/dropbox-lnx.x86_64-${PV}.tar.gz )"

LICENSE="CC-BY-ND-3.0 FTL MIT LGPL-2 openssl dropbox"
SLOT="0"
KEYWORDS="~amd64 ~x86 ~x86-linux"
IUSE="+librsync-bundled X"
RESTRICT="mirror strip"

QA_PREBUILT="opt/.*"
QA_EXECSTACK="opt/dropbox/dropbox"

DEPEND="librsync-bundled? ( dev-util/patchelf )"

# Be sure to have GLIBCXX_3.4.9, #393125
# USE=X require wxGTK's dependencies. system-library cannot be used due to
# missing symbol (CtlColorEvent). #443686
RDEPEND="
	X? (
		dev-libs/glib:2
		media-libs/libpng:1.2
		sys-libs/zlib
		virtual/jpeg
		x11-libs/gtk+:2
		x11-libs/libSM
		x11-libs/libXinerama
		x11-libs/libXxf86vm
		x11-libs/pango[X]
		x11-themes/hicolor-icon-theme
	)
	app-arch/bzip2
	dev-libs/popt
	!librsync-bundled? ( net-libs/librsync )
	net-misc/wget
	>=sys-devel/gcc-4.2.0
	sys-libs/zlib
"

src_unpack() {
	unpack ${A}
	mkdir -p "${S}"
	mv "${WORKDIR}"/.dropbox-dist/* "${S}" || die
	rmdir .dropbox-dist
}

src_prepare() {
	rm -vf libbz2* libpopt.so.0 libpng12.so.0 || die
	if use X ; then
		mv images/hicolor/16x16/status "${T}" || die
	else
		rm -vrf *wx* images || die
	fi
	if use librsync-bundled ; then
		patchelf --set-rpath '$ORIGIN' _librsync.so || die
	else
		rm -vf librsync.so.1 || die
	fi
	rm -rf *.egg library.zip || die
	ln -s dropbox library.zip || die
	pax-mark cm dropbox
	mv README ACKNOWLEDGEMENTS "${T}" || die
}

src_install() {
	local targetdir="/opt/dropbox"

	insinto "${targetdir}"
	doins -r *
	fperms a+x "${targetdir}"/{dropbox,dropboxd}
	dosym "${targetdir}/dropboxd" "/opt/bin/dropbox"

	use X && doicon -s 16 -c status "${T}"/status

	newinitd "${FILESDIR}"/dropbox.initd dropbox
	newconfd "${FILESDIR}"/dropbox.conf dropbox

	dodoc "${T}"/{README,ACKNOWLEDGEMENTS}
}

pkg_preinst() {
	gnome2_icon_savelist
}

pkg_postinst() {
	gnome2_icon_cache_update
}

pkg_postrm() {
	gnome2_icon_cache_update
}