[gentoo-commits] gentoo-x86 commit in media-sound/banshee: banshee-1.7.4.ebuild ChangeLog metadata.xml

[Arun Raghavan (ford_prefect)]

ford_prefect    10/08/31 11:44:16

  Modified:             ChangeLog metadata.xml
  Added:                banshee-1.7.4.ebuild
  Log:
  Add 1.7.4 (masked). This is a development release, with a bunch of new features (Amazon support, etc.), deps (gtk-sharp-beans, gio-sharp, gstreamer-sharp, none of which are in-tree), and bugs.
  
  (Portage version: 2.2_rc71/cvs/Linux x86_64)

Revision  Changes    Path
1.118                media-sound/banshee/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-sound/banshee/ChangeLog?rev=1.118&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-sound/banshee/ChangeLog?rev=1.118&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-sound/banshee/ChangeLog?r1=1.117&r2=1.118

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-sound/banshee/ChangeLog,v
retrieving revision 1.117
retrieving revision 1.118
diff -u -r1.117 -r1.118
--- ChangeLog	12 Jul 2010 18:03:07 -0000	1.117
+++ ChangeLog	31 Aug 2010 11:44:15 -0000	1.118
@@ -1,6 +1,16 @@
 # ChangeLog for media-sound/banshee
 # Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-sound/banshee/ChangeLog,v 1.117 2010/07/12 18:03:07 fauli Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-sound/banshee/ChangeLog,v 1.118 2010/08/31 11:44:15 ford_prefect Exp $
+
+*banshee-1.7.4 (31 Aug 2010)
+
+  31 Aug 2010; Arun Raghavan <ford_prefect@g.o>
+  +banshee-1.7.4.ebuild, +files/banshee-1.7.4-fix-collisions.patch,
+  +files/banshee-1.7.4-fix-gdu-build.patch,
+  +files/banshee-1.7.4-make-webkit-optional.patch, metadata.xml:
+  Add 1.7.4 (masked). This is a development release, with a bunch of new
+  features (Amazon support, etc.), deps (gtk-sharp-beans, gio-sharp,
+  gstreamer-sharp, none of which are in-tree), and bugs.
 
   12 Jul 2010; Christian Faulhammer <fauli@g.o> banshee-1.6.1.ebuild:
   stable x86, bug 324241



1.12                 media-sound/banshee/metadata.xml

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-sound/banshee/metadata.xml?rev=1.12&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-sound/banshee/metadata.xml?rev=1.12&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-sound/banshee/metadata.xml?r1=1.11&r2=1.12

Index: metadata.xml
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-sound/banshee/metadata.xml,v
retrieving revision 1.11
retrieving revision 1.12
diff -u -r1.11 -r1.12
--- metadata.xml	17 Mar 2010 18:58:33 -0000	1.11
+++ metadata.xml	31 Aug 2010 11:44:15 -0000	1.12
@@ -9,7 +9,10 @@
     <flag name="daap">Build with Daap support</flag>
     <flag name="karma">Build with karma support</flag>
     <flag name="podcast">Build with podcasting support</flag>
-	<flag name="wikipedia">Enable the Wikipedia context pane (requires
+	<flag name="wikipedia">Enable the Wikipedia context pane (require
+		<pkg>net-libs/webkit-gtk</pkg>)</flag>
+	<flag name="web">Enable support for plugins that access web-based services
+		such as Amazon and wikipedia (requires
 		<pkg>net-libs/webkit-gtk</pkg>)</flag>
 	<flag name="youtube">Enable the Youtube plugin</flag>
   </use>



1.1                  media-sound/banshee/banshee-1.7.4.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-sound/banshee/banshee-1.7.4.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-sound/banshee/banshee-1.7.4.ebuild?rev=1.1&content-type=text/plain

Index: banshee-1.7.4.ebuild
===================================================================
# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-sound/banshee/banshee-1.7.4.ebuild,v 1.1 2010/08/31 11:44:15 ford_prefect Exp $

EAPI=2

inherit eutils autotools mono gnome2-utils fdo-mime versionator

GVER=0.10.7

DESCRIPTION="Import, organize, play, and share your music using a simple and powerful interface."
HOMEPAGE="http://banshee-project.org"

#BANSHEE_V2=$(get_version_component_range 2)
#[[ $((${BANSHEE_V2} % 2)) -eq 0 ]] && RELTYPE=stable || RELTYPE=unstable
#SRC_URI="http://download.banshee-project.org/${PN}/${RELTYPE}/${PV}/${PN}-1-${PV}.tar.bz2"
SRC_URI="http://download.banshee-project.org/${PN}/stable/${PV}/${PN}-1-${PV}.tar.bz2"

LICENSE="MIT"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="+aac +cdda boo daap doc +encode ipod karma mtp podcast test web youtube"

# Hal is required until upstream bug 612616 is solved
RDEPEND=">=dev-lang/mono-2.4.3
	gnome-base/gnome-settings-daemon
	x11-themes/gnome-icon-theme
	sys-apps/dbus
	sys-apps/hal
	>=dev-dotnet/gtk-sharp-2.12
	>=dev-dotnet/gconf-sharp-2.24.0
	>=dev-dotnet/notify-sharp-0.4.0_pre20080912-r1
	>=media-libs/gstreamer-0.10.21-r3
	>=media-libs/gst-plugins-base-0.10.25.2
	>=media-libs/gst-plugins-bad-${GVER}
	>=media-libs/gst-plugins-good-${GVER}
	>=media-libs/gst-plugins-ugly-${GVER}
	>=media-plugins/gst-plugins-meta-0.10-r2:0.10
	>=media-plugins/gst-plugins-gnomevfs-${GVER}
	>=media-plugins/gst-plugins-gconf-${GVER}
	cdda? (
		|| (
			>=media-plugins/gst-plugins-cdparanoia-${GVER}
			>=media-plugins/gst-plugins-cdio-${GVER}
		)
	)
	media-libs/musicbrainz:1
	>=dev-dotnet/dbus-glib-sharp-0.4.1
	>=dev-dotnet/dbus-sharp-0.6.1a
	>=dev-dotnet/mono-addins-0.4[gtk]
	>=dev-dotnet/taglib-sharp-2.0.3.7
	>=dev-db/sqlite-3.4
	karma? ( >=media-libs/libkarma-0.1.0-r1 )
	aac? ( >=media-plugins/gst-plugins-faad-${GVER} )
	boo? (
		>=dev-lang/boo-0.8.1
	)
	daap? (
		>=dev-dotnet/mono-zeroconf-0.8.0-r1
	)
	doc? (
		virtual/monodoc
		>=app-text/gnome-doc-utils-0.17.3
	)
	encode? (
		>=media-plugins/gst-plugins-lame-${GVER}
		>=media-plugins/gst-plugins-taglib-${GVER}
	)
	ipod? (
		>=dev-dotnet/ipod-sharp-0.8.5
		>=dev-dotnet/podsleuth-0.6.7
	)
	mtp? (
		media-libs/libmtp
	)
	web? (
		>=net-libs/webkit-gtk-1.2.2
		>=net-libs/libsoup-2.26:2.4
		>=net-libs/libsoup-gnome-2.26:2.4
	)
	youtube? (
		>=dev-dotnet/google-gdata-sharp-1.4
	)"

DEPEND="${RDEPEND}
	dev-util/pkgconfig"

DOCS="AUTHORS ChangeLog HACKING NEWS README"

S=${WORKDIR}/${PN}-1-${PV}

src_prepare () {
	# Fix intltool b0rkage similar to
	# https://bugzilla.gnome.org/show_bug.cgi?id=577133
	sed "s:'\^\$\$lang\$\$':\^\$\$lang\$\$:g" -i po/Makefile.in.in \
		|| die "sed failed"

	epatch "${FILESDIR}/${P}-fix-gdu-build.patch"
	epatch "${FILESDIR}/${P}-make-webkit-optional.patch"
	epatch "${FILESDIR}/${P}-fix-collisions.patch"
	AT_M4DIR="-I build/m4/banshee -I build/m4/shamrock -I build/m4/shave" \
		eautoreconf
}

src_configure() {
	# Disable gio till gtk-sharp-beans and gio-sharp are in-tree
	# Ditto gst-sharp
	local myconf="--disable-dependency-tracking --disable-static
		--enable-gnome --enable-schemas-install
		--with-gconf-schema-file-dir=/etc/gconf/schemas
		--with-vendor-build-id=Gentoo/${PN}/${PVR}
		--enable-gapless-playback
		--disable-gio --disable-gst-sharp
		--disable-torrent
		--disable-shave"

	econf \
		$(use_enable doc docs) \
		$(use_enable doc user-help) \
		$(use_enable boo) \
		$(use_enable mtp) \
		$(use_enable daap) \
		$(use_enable ipod) \
		$(use_enable podcast) \
		$(use_enable karma) \
		$(use_enable web webkit) \
		$(use_enable youtube) \
		${myconf}
}

src_compile() {
	emake MCS=/usr/bin/gmcs
}

src_install() {
	emake DESTDIR="${D}" install || die "emake install efailed"
	find "${D}" -name '*.la' -delete
}

pkg_preinst() {
	gnome2_icon_savelist
}

pkg_postinst() {
	ewarn
	ewarn "If ${PN} doesn't play some format, please check your"
	ewarn "USE flags on media-plugins/gst-plugins-meta"
	ewarn

	fdo-mime_desktop_database_update
	fdo-mime_mime_database_update
	gnome2_icon_cache_update
}

pkg_postrm() {
	fdo-mime_desktop_database_update
	fdo-mime_mime_database_update
	gnome2_icon_cache_update
}