[gentoo-commits] gentoo-x86 commit in sci-geosciences/gpsd: ChangeLog gpsd-2.32.ebuild gpsd-2.95-r1.ebuild gpsd-2.95.ebuild

[Steve Arnold (nerdboy)]

nerdboy     11/02/21 03:29:14

  Modified:             ChangeLog gpsd-2.32.ebuild
  Added:                gpsd-2.95-r1.ebuild
  Removed:              gpsd-2.95.ebuild
  Log:
  Update for man pages, working tests, and missing header file.
  
  (Portage version: 2.1.9.40/cvs/Linux x86_64)

Revision  Changes    Path
1.58                 sci-geosciences/gpsd/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sci-geosciences/gpsd/ChangeLog?rev=1.58&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sci-geosciences/gpsd/ChangeLog?rev=1.58&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sci-geosciences/gpsd/ChangeLog?r1=1.57&r2=1.58

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sci-geosciences/gpsd/ChangeLog,v
retrieving revision 1.57
retrieving revision 1.58
diff -u -r1.57 -r1.58
--- ChangeLog	25 Jan 2011 20:14:45 -0000	1.57
+++ ChangeLog	21 Feb 2011 03:29:14 -0000	1.58
@@ -1,6 +1,12 @@
 # ChangeLog for sci-geosciences/gpsd
 # Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sci-geosciences/gpsd/ChangeLog,v 1.57 2011/01/25 20:14:45 jer Exp $
+# $Header: /var/cvsroot/gentoo-x86/sci-geosciences/gpsd/ChangeLog,v 1.58 2011/02/21 03:29:14 nerdboy Exp $
+
+*gpsd-2.95-r1 (21 Feb 2011)
+
+  21 Feb 2011; Steve Arnold <nerdboy@g.o> -gpsd-2.95.ebuild,
+  +gpsd-2.95-r1.ebuild:
+  Update for man pages, working tests, and missing header file.
 
   25 Jan 2011; Jeroen Roovers <jer@g.o> gpsd-2.38.ebuild,
   gpsd-2.39-r1.ebuild:



1.13                 sci-geosciences/gpsd/gpsd-2.32.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sci-geosciences/gpsd/gpsd-2.32.ebuild?rev=1.13&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sci-geosciences/gpsd/gpsd-2.32.ebuild?rev=1.13&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sci-geosciences/gpsd/gpsd-2.32.ebuild?r1=1.12&r2=1.13

Index: gpsd-2.32.ebuild
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sci-geosciences/gpsd/gpsd-2.32.ebuild,v
retrieving revision 1.12
retrieving revision 1.13
diff -u -r1.12 -r1.13
--- gpsd-2.32.ebuild	21 Nov 2010 12:42:45 -0000	1.12
+++ gpsd-2.32.ebuild	21 Feb 2011 03:29:14 -0000	1.13
@@ -1,6 +1,6 @@
-# Copyright 1999-2010 Gentoo Foundation
+# Copyright 1999-2011 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/sci-geosciences/gpsd/gpsd-2.32.ebuild,v 1.12 2010/11/21 12:42:45 armin76 Exp $
+# $Header: /var/cvsroot/gentoo-x86/sci-geosciences/gpsd/gpsd-2.32.ebuild,v 1.13 2011/02/21 03:29:14 nerdboy Exp $
 
 EAPI=1
 



1.1                  sci-geosciences/gpsd/gpsd-2.95-r1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sci-geosciences/gpsd/gpsd-2.95-r1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sci-geosciences/gpsd/gpsd-2.95-r1.ebuild?rev=1.1&content-type=text/plain

Index: gpsd-2.95-r1.ebuild
===================================================================
# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sci-geosciences/gpsd/gpsd-2.95-r1.ebuild,v 1.1 2011/02/21 03:29:14 nerdboy Exp $

EAPI=3

PYTHON_DEPEND="2:2.6"

inherit python base autotools

DESCRIPTION="GPS daemon and library to support USB/serial GPS devices and various GPS/mapping clients."
HOMEPAGE="http://gpsd.berlios.de/"
SRC_URI="mirror://berlios/gpsd/${P}.tar.gz"

LICENSE="BSD"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~ppc64 ~x86"

GPSD_PROTOCOLS="ashtech aivdm clientdebug earthmate evermore fv18 garmin
	garmintxt gpsclock itrax mtk3301 nmea ntrip navcom oceanserver
	oldstyle oncore rtcm104v2 rtcm104v3 sirf superstar2 timing tsip
	tripmate tnt ubx"
for protocol in ${GPSD_PROTOCOLS}; do
	IUSE_GPSD_PROTOCOLS+=" gpsd_protocols_${protocol}"
done

IUSE="${IUSE_GPSD_PROTOCOLS} dbus ipv6 ntp qt4"

# those harddeps are de-facto automagicall
RDEPEND="
	dev-python/pygtk
	sys-libs/ncurses
	virtual/libusb:1
	dbus? (
		sys-apps/dbus
		dev-libs/dbus-glib
	)
	ntp? ( net-misc/ntp )
	qt4? ( x11-libs/qt-gui )"

DEPEND="${RDEPEND}
	app-text/xmlto"

PATCHES=(
	"${FILESDIR}/${PV}-disable-strip.patch"
	"${FILESDIR}/${PV}-fix-ldflags.patch"
)

pkg_setup() {
	python_set_active_version 2

	# Run the gpsd daemon as gpsd and group uucp
	enewuser gpsd -1 -1 -1 "uucp"
}

src_prepare() {
	base_src_prepare
	eautoreconf
}

src_configure() {
	local myopts

	# enable specified protocols
	for protocol in ${GPSD_PROTOCOLS}; do
		myopts+=" $(use_enable gpsd_protocols_${protocol} ${protocol})"
	done

	if ! use qt4 ;  then
		myopts+=" --disable-libQgpsmm --disable-libgpsmm ${myopts}"
	fi

	# --disable-bluetooth: considered experimental -> disable
	# --enable-static is required for tests, see bug 355071
	# Hack to make it not generate docs on the fly; xmlto is
	# needed for man pages (xsltproc is only needed for web pages)
	econf WITH_XMLTO=yes WITH_XSLTPROC=no \
		--build=${CBUILD} \
		--disable-dependency-tracking \
		--disable-bluetooth \
		--enable-static \
		--enable-gpsd-user=gpsd \
		--enable-gpsd-group=uucp \
		$(use_enable dbus) \
		$(use_enable ipv6) \
		$(use_enable ntp ntpshm) \
		$(use_enable ntp pps) \
		${myopts}
}

src_install() {
	# no it can't be done using emake cause it is non-compliant
	make DESTDIR="${D}" install || die

	# needs this header for libQgpsmm
	if use qt4 ; then
		insinto /usr/include
		doins libQgpsmm/libQgpsmm_global.h
	fi

	# no need for .la files here
	find "${D}" -type f -name '*.la' -exec rm -f '{}' +

	newconfd "${FILESDIR}"/gpsd.conf-2 gpsd || die
	newinitd "${FILESDIR}"/gpsd.init-2 gpsd || die
}