[gentoo-commits] gentoo-x86 commit in dev-util/qbs: qbs-1.3.0.ebuild ChangeLog

[Davide Pesavento (pesa)]

pesa        14/08/29 05:12:58

  Modified:             ChangeLog
  Added:                qbs-1.3.0.ebuild
  Log:
  Version bump.
  
  (Portage version: 2.2.12/cvs/Linux x86_64, signed Manifest commit with key 0xDADED6B2671CB57D!)

Revision  Changes    Path
1.4                  dev-util/qbs/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-util/qbs/ChangeLog?rev=1.4&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-util/qbs/ChangeLog?rev=1.4&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-util/qbs/ChangeLog?r1=1.3&r2=1.4

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-util/qbs/ChangeLog,v
retrieving revision 1.3
retrieving revision 1.4
diff -u -r1.3 -r1.4
--- ChangeLog	31 Jul 2014 23:36:22 -0000	1.3
+++ ChangeLog	29 Aug 2014 05:12:58 -0000	1.4
@@ -1,6 +1,11 @@
 # ChangeLog for dev-util/qbs
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-util/qbs/ChangeLog,v 1.3 2014/07/31 23:36:22 pesa Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-util/qbs/ChangeLog,v 1.4 2014/08/29 05:12:58 pesa Exp $
+
+*qbs-1.3.0 (29 Aug 2014)
+
+  29 Aug 2014; Davide Pesavento <pesa@g.o> +qbs-1.3.0.ebuild:
+  Version bump.
 
 *qbs-1.2.2 (31 Jul 2014)
 



1.1                  dev-util/qbs/qbs-1.3.0.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-util/qbs/qbs-1.3.0.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-util/qbs/qbs-1.3.0.ebuild?rev=1.1&content-type=text/plain

Index: qbs-1.3.0.ebuild
===================================================================
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-util/qbs/qbs-1.3.0.ebuild,v 1.1 2014/08/29 05:12:58 pesa Exp $

EAPI=5

inherit multilib qmake-utils

DESCRIPTION="Qt Build Suite"
HOMEPAGE="http://qt-project.org/wiki/qbs"
SRC_URI="http://download.qt-project.org/official_releases/${PN}/${PV}/${P}.src.tar.gz"

LICENSE="LGPL-2.1"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="doc +qt4 qt5 test"

RDEPEND="
	qt4? (
		>=dev-qt/qtcore-4.8:4
		>=dev-qt/qtgui-4.8:4
		>=dev-qt/qtscript-4.8:4
	)
	qt5? (
		dev-qt/qtcore:5
		dev-qt/qtgui:5
		dev-qt/qtscript:5
		dev-qt/qtwidgets:5
		dev-qt/qtxml:5
	)
"
DEPEND="${RDEPEND}
	doc? (
		qt4? ( >=dev-qt/qthelp-4.8:4 )
		qt5? ( dev-qt/qthelp:5 )
	)
	test? (
		qt4? ( >=dev-qt/qttest-4.8:4 )
		qt5? ( dev-qt/qttest:5 )
	)
"

REQUIRED_USE="^^ ( qt4 qt5 )"

src_prepare() {
	sed -i -e "/destdirPrefix/ s:/lib:/$(get_libdir):" \
		src/plugins/plugins.pri || die

	if ! use test; then
		sed -i -e '/SUBDIRS = auto/d' \
			tests/tests.pro || die
	fi
}

src_configure() {
	local myqmakeargs=(
		-recursive
		CONFIG+=disable_rpath
		QBS_INSTALL_PREFIX="${EPREFIX}/usr"
		QBS_LIBRARY_DIRNAME="$(get_libdir)"
	)

	if use qt4; then
		eqmake4 "${myqmakeargs[@]}"
	elif use qt5; then
		eqmake5 "${myqmakeargs[@]}"
	fi
}

src_test() {
	export HOME=${T}
	export LD_LIBRARY_PATH=${S}/$(get_libdir)

	local qmakepath=${EROOT}usr/$(get_libdir)/$(usev qt4 || usev qt5)/bin/qmake
	[[ -x ${qmakepath} ]] || qmakepath=${EROOT}usr/bin/qmake

	einfo "Setting up test environment in ${T}"

	"${S}"/bin/qbs-setup-toolchains --detect || die
	"${S}"/bin/qbs-setup-qt "${qmakepath}" qbs_autotests || die

	default
}

src_install() {
	emake INSTALL_ROOT="${D}" install

	# install documentation
	if use doc; then
		emake docs
		dodoc doc/qbs.qch
		docompress -x /usr/share/doc/${PF}/qbs.qch
		dohtml -r doc/html/*
	fi
}