[gentoo-commits] repo/gentoo:master commit in: dev-libs/libclsync/

[Andrew Savchenko]

commit:     ad4f3583dc62407e096048f3f72f8f6e72419cc9
Author:     Andrew Savchenko <bircoph <AT> gentoo <DOT> org>
AuthorDate: Fri Sep 30 12:03:27 2016 +0000
Commit:     Andrew Savchenko <bircoph <AT> gentoo <DOT> org>
CommitDate: Fri Sep 30 12:03:50 2016 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=ad4f3583

dev-libs/libclsync: version bump

Bump to 0.4.2, update ebuild to EAPI 6.

Package-Manager: portage-2.3.1
Signed-off-by: Andrew Savchenko <bircoph <AT> gentoo.org>

 dev-libs/libclsync/Manifest               |  1 +
 dev-libs/libclsync/libclsync-0.4.2.ebuild | 72 +++++++++++++++++++++++++++++++
 2 files changed, 73 insertions(+)

diff --git a/dev-libs/libclsync/Manifest b/dev-libs/libclsync/Manifest
index 22e7548..994df4e 100644
--- a/dev-libs/libclsync/Manifest
+++ b/dev-libs/libclsync/Manifest
@@ -1 +1,2 @@
 DIST clsync-0.4.1.tar.gz 253890 SHA256 3f14a72d7c3c1747ea908e373f25bd1918ce00450492fbb7094549db6bf21e27 SHA512 875280f706026d44806b92c22fa58d016136b2792f67a6b7e77f932465081da7a1ebaf22c25e538e4b58bfe04cd1cd5450ecab99c3df53ddd2a0fa966442d444 WHIRLPOOL 10ab11821766f7d16d03993069ac4da5fe362a1e5977ea6721e49ada7044d3659e59b507b03be4de09609b0a0ca9d7878407d7b6e1f40df5dbe1d041dac373cb
+DIST clsync-0.4.2.tar.gz 256042 SHA256 1af63b86c1d0bd663311f2129792446dc8fc4def5559f76658b51b69a8d0c3bd SHA512 d14a2efc4bf58d9d5c7a3fe5634cacdd182cd7cd814b0e9ebd99024a7282b056d1f7ceeec6903666391c3572d599a18e205af818b098ed7768d5c0e0f4cd1200 WHIRLPOOL a59446337282cb63455b43bbbf17ad1213e39713d9c267ca5ee8785d863bc90e7b99e5938e4d5be02f3103a98b1bb5d5a628580160952d821e6caaad72fa2679

diff --git a/dev-libs/libclsync/libclsync-0.4.2.ebuild b/dev-libs/libclsync/libclsync-0.4.2.ebuild
new file mode 100644
index 00000000..094b8d9
--- /dev/null
+++ b/dev-libs/libclsync/libclsync-0.4.2.ebuild
@@ -0,0 +1,72 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=6
+
+MY_PN=${PN#lib}
+MY_P="${MY_PN}-${PV}"
+
+inherit autotools eutils
+
+DESCRIPTION="Control and monitoring library for clsync"
+HOMEPAGE="http://ut.mephi.ru/oss/clsync https://github.com/xaionaro/clsync"
+SRC_URI="https://github.com/xaionaro/${MY_PN}/archive/v${PV}.tar.gz -> ${MY_P}.tar.gz"
+LICENSE="GPL-3+"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="debug extra-debug extra-hardened hardened static-libs"
+S="${WORKDIR}/${MY_P}"
+
+REQUIRED_USE="
+	extra-debug? ( debug )
+	extra-hardened? ( hardened )
+"
+
+DEPEND="virtual/pkgconfig"
+RDEPEND="
+	=app-admin/clsync-0.4*[control-socket]
+	=app-doc/clsync-docs-0.4*"
+
+src_prepare() {
+	eapply_user
+	eautoreconf
+}
+
+src_configure() {
+	local harden_level=0
+	use hardened && harden_level=1
+	use extra-hardened && harden_level=2
+
+	local debug_level=0
+	use debug && debug_level=1
+	use extra-debug && debug_level=2
+
+	econf \
+		--docdir="${EPREFIX}/usr/share/doc/${PF}" \
+		--enable-socket-library \
+		--disable-clsync \
+		--enable-debug=${debug_level} \
+		--enable-paranoid=${harden_level} \
+		--without-bsm \
+		--without-kqueue \
+		--disable-capabilities \
+		--disable-cluster \
+		--enable-socket \
+		--disable-highload-locks \
+		--disable-unshare \
+		--disable-seccomp \
+		--without-libcgroup \
+		--without-gio \
+		--with-inotify=native \
+		--without-mhash
+}
+
+src_install() {
+	emake DESTDIR="${D}" install
+	prune_libtool_files
+	use static-libs || find "${ED}" -name "*.a" -delete || die "failed to remove static libs"
+
+	# docs go into clsync-docs
+	rm -rf "${ED}/usr/share/doc" || die
+}