[gentoo-commits] repo/gentoo:master commit in: dev-python/pykerberos/

[Michał Górny]

commit:     36f156a18f5f00366009fc51b63c6b18b244422e
Author:     Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Sun Sep 27 21:47:02 2020 +0000
Commit:     Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Mon Sep 28 15:52:48 2020 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=36f156a1

dev-python/pykerberos: Remove py2.7 in revbump

Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>

 dev-python/pykerberos/pykerberos-1.3.0-r1.ebuild | 45 ++++++++++++++++++++++++
 1 file changed, 45 insertions(+)

diff --git a/dev-python/pykerberos/pykerberos-1.3.0-r1.ebuild b/dev-python/pykerberos/pykerberos-1.3.0-r1.ebuild
new file mode 100644
index 00000000000..0d5435a1f31
--- /dev/null
+++ b/dev-python/pykerberos/pykerberos-1.3.0-r1.ebuild
@@ -0,0 +1,45 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+DISTUTILS_USE_SETUPTOOLS=rdepend
+PYTHON_COMPAT=( python3_{6..9} )
+inherit distutils-r1
+
+MY_P=PyKerberos-${PV}
+DESCRIPTION="A high-level Python wrapper for Kerberos/GSSAPI operations"
+HOMEPAGE="
+	https://trac.calendarserver.org/wiki/PyKerberos
+	https://github.com/apple/ccs-pykerberos/
+	https://pypi.org/project/kerberos/"
+SRC_URI="
+	https://github.com/apple/ccs-pykerberos/archive/${MY_P}.tar.gz"
+S=${WORKDIR}/ccs-pykerberos-${MY_P}
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="amd64 ~arm arm64 ~hppa ~ppc64 x86"
+# test environment is non-trivial to set up, so just use docker
+# (see python_test below)
+# also for alpha/beta Python releases support:
+# https://github.com/apple/ccs-pykerberos/pull/83/commits/5f1130a1305b5f6e7d7d8b41067c4713f0c8950f
+RESTRICT="test"
+
+RDEPEND="app-crypt/mit-krb5"
+DEPEND="${RDEPEND}"
+
+python_test() {
+	set -- docker run \
+		-v "${PWD}:/app" \
+		-w /app \
+		-e PYENV=$("${EPYTHON}" -c 'import sys; print(sys.version.split()[0])') \
+		-e KERBEROS_USERNAME=administrator \
+		-e KERBEROS_PASSWORD=Password01 \
+		-e KERBEROS_REALM=example.com \
+		-e KERBEROS_PORT=80 \
+		ubuntu:16.04 \
+		/bin/bash .travis.sh
+	echo "${@}" >&2
+	"${@}" || die "Tests failed with ${EPYTHON}"
+}