[gentoo-commits] repo/gentoo:master commit in: media-gfx/imagemagick/

[Lars Wendler]

commit:     34695c7bae56cc42d84ba0024d39efa9d249d684
Author:     Lars Wendler <polynomial-c <AT> gentoo <DOT> org>
AuthorDate: Sun Jan 29 06:39:25 2017 +0000
Commit:     Lars Wendler <polynomial-c <AT> gentoo <DOT> org>
CommitDate: Sun Jan 29 06:39:41 2017 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=34695c7b

media-gfx/imagemagick: Removed old.

Package-Manager: Portage-2.3.3, Repoman-2.3.1

 media-gfx/imagemagick/Manifest                   |   1 -
 media-gfx/imagemagick/imagemagick-6.9.7.3.ebuild | 178 -----------------------
 2 files changed, 179 deletions(-)

diff --git a/media-gfx/imagemagick/Manifest b/media-gfx/imagemagick/Manifest
index 2610c12..a747765 100644
--- a/media-gfx/imagemagick/Manifest
+++ b/media-gfx/imagemagick/Manifest
@@ -1,5 +1,4 @@
 DIST ImageMagick-6.9.6-6.tar.xz 8787060 SHA256 9cd1fe001d3ecb68b7d053ede40950d411956d47afc5267acc3ca57a77070d0a SHA512 6721f9f7973d6931006314c6afa090209766432b2d14d4e37e3d11b1042797012c9fe41e469c169bbe6862cdfc4c832eac4f9a6f8c052e1c0d41e40a13c9d95e WHIRLPOOL 32b92606bf03e36e5ac09a2be9da2ddba6590093edd68aa320c6126f5406c0c82dfeaf80f31258109b2875d0c2af3ced3e27911e7df54c159c895caa6f3ff27f
-DIST ImageMagick-6.9.7-3.tar.xz 8795016 SHA256 801767344b835b810a5f88c26f062f0fa01a97264dfe9bf5e5adf59a0b5c91a1 SHA512 e0d247691d49e17a35569e2579ac63f3d7016411959d8c2e8a69042618af896a737a3ae2b3a32028e8306d78f6a7f9ec23550760f8ef0370125ab4e6c8dbd5ba WHIRLPOOL 509e32634e17b9f2604b7052291e9b1e1225957c2d5e6b625beb6ff2083b6e8758d47dff6e4af5546fd5fd72f9d7fc7fd5d806428364c448e1284536ecfea63b
 DIST ImageMagick-6.9.7-4.tar.xz 8797776 SHA256 68842c55ed9c958b84aae17974961cefff4212bf7146f09fd15c09dbdc2d9629 SHA512 9ee9cf01c486575183a67e418bdbdcf4ac2b7ea2f9ff033db6a74f8271af0567da00f020dd8c18e042221d20444bed21d5d5256944ddeaf9916b62bf1844acf6 WHIRLPOOL 7c75006dafd28bb0fe02e130b4fcbae5fe54c6fbfdb29ba6b49796a14354e7aeb56b80c498eb57a4a8c7b383af025406dfeba66735ba89fd35d61125b51e7d41
 DIST ImageMagick-6.9.7-6.tar.xz 8808024 SHA256 f65fb923ce44795c5675bd73509f3b47eb2875c266ce57547969658d7e1fec9e SHA512 503d9a38c85d60f05483fdf2498c24d17172bd976abfb06611efd888ed912ec30bbf3b21d613bd6d30b8d728a24c278c29ba81455157b7c7739fcc89a495f4d9 WHIRLPOOL b5e20d87efac8936bdd2e4dd2047cd943525e5e2eb40c57f2cb9faa7bac054dd7a65162270dfa31ae3c5ac07de0c57d60f4f71c2798c372e01f145461f2d3d57
 DIST ImageMagick-7.0.4-6.tar.xz 8298208 SHA256 1ee004740b7ab47fff3c92ae4a89dcbd0181c4d5f31fcb7e3697412ea384a0da SHA512 8d5479fe25da6790cc617da0acf9da8e4a499b9b8b4ea372cfafc173307497009c6f01e394b5d2588617edd94b6bd3b4e285696c75a04567bd338513582822ce WHIRLPOOL a103774df222588af6b8d808eb125d5abee5aaf2176fb2f532e0ddabf2d20042ea6b78ecbbf0bbe93061127c8d2519150b07e3ca689909102f4b05a7cfe3a4c2

diff --git a/media-gfx/imagemagick/imagemagick-6.9.7.3.ebuild b/media-gfx/imagemagick/imagemagick-6.9.7.3.ebuild
deleted file mode 100644
index 9d441ac..00000000
--- a/media-gfx/imagemagick/imagemagick-6.9.7.3.ebuild
+++ /dev/null
@@ -1,178 +0,0 @@
-# Copyright 1999-2017 Gentoo Foundation
-# Distributed under the terms of the GNU General Public License v2
-# $Id$
-
-EAPI=6
-
-inherit eutils flag-o-matic libtool multilib toolchain-funcs versionator
-
-MY_P=ImageMagick-$(replace_version_separator 3 '-')
-
-DESCRIPTION="A collection of tools and libraries for many image formats"
-HOMEPAGE="http://www.imagemagick.org/"
-SRC_URI="mirror://${PN}/${MY_P}.tar.xz"
-
-LICENSE="imagemagick"
-SLOT="0/${PV}"
-KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~ppc-aix ~amd64-fbsd ~x86-fbsd ~x86-interix ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~x64-solaris ~x86-solaris"
-IUSE="autotrace bzip2 corefonts cxx djvu fftw fontconfig fpx graphviz hdri jbig jpeg jpeg2k lcms lqr lzma opencl openexr openmp pango perl png postscript q32 q64 q8 raw static-libs svg test tiff truetype webp wmf X xml zlib"
-
-RESTRICT="perl? ( userpriv )"
-
-RDEPEND="
-	dev-libs/libltdl:0
-	autotrace? ( >=media-gfx/autotrace-0.31.1 )
-	bzip2? ( app-arch/bzip2 )
-	corefonts? ( media-fonts/corefonts )
-	djvu? ( app-text/djvu )
-	fftw? ( sci-libs/fftw:3.0 )
-	fontconfig? ( media-libs/fontconfig )
-	fpx? ( >=media-libs/libfpx-1.3.0-r1 )
-	graphviz? ( media-gfx/graphviz )
-	jbig? ( >=media-libs/jbigkit-2:= )
-	jpeg? ( virtual/jpeg:0 )
-	jpeg2k? ( >=media-libs/openjpeg-2.1.0:2 )
-	lcms? ( media-libs/lcms:2= )
-	lqr? ( media-libs/liblqr )
-	opencl? ( virtual/opencl )
-	openexr? ( media-libs/openexr:0= )
-	pango? ( x11-libs/pango )
-	perl? ( >=dev-lang/perl-5.8.8:0= )
-	png? ( media-libs/libpng:0= )
-	postscript? ( app-text/ghostscript-gpl )
-	raw? ( media-gfx/ufraw )
-	svg? ( gnome-base/librsvg )
-	tiff? ( media-libs/tiff:0= )
-	truetype? (
-		media-fonts/urw-fonts
-		>=media-libs/freetype-2
-		)
-	webp? ( media-libs/libwebp:0= )
-	wmf? ( media-libs/libwmf )
-	X? (
-		x11-libs/libICE
-		x11-libs/libSM
-		x11-libs/libXext
-		x11-libs/libXt
-		)
-	xml? ( dev-libs/libxml2:= )
-	lzma? ( app-arch/xz-utils )
-	zlib? ( sys-libs/zlib:= )"
-DEPEND="${RDEPEND}
-	!media-gfx/graphicsmagick[imagemagick]
-	virtual/pkgconfig
-	X? ( x11-proto/xextproto )"
-
-REQUIRED_USE="corefonts? ( truetype )
-	test? ( corefonts )"
-
-S=${WORKDIR}/${MY_P}
-
-src_prepare() {
-	default
-
-	elibtoolize # for Darwin modules
-
-	# For testsuite, see https://bugs.gentoo.org/show_bug.cgi?id=500580#c3
-	shopt -s nullglob
-	mesa_cards=$(echo -n /dev/dri/card* | sed 's/ /:/g')
-	if test -n "${mesa_cards}"; then
-		addpredict "${mesa_cards}"
-	fi
-	ati_cards=$(echo -n /dev/ati/card* | sed 's/ /:/g')
-	if test -n "${ati_cards}"; then
-		addpredict "${ati_cards}"
-	fi
-	shopt -u nullglob
-	addpredict /dev/nvidiactl
-}
-
-src_configure() {
-	local depth=16
-	use q8 && depth=8
-	use q32 && depth=32
-	use q64 && depth=64
-
-	local openmp=disable
-	use openmp && { tc-has-openmp && openmp=enable; }
-
-	[[ ${CHOST} == *-solaris* ]] && append-ldflags -lnsl -lsocket
-
-	CONFIG_SHELL=$(type -P bash) \
-	econf \
-		$(use_enable static-libs static) \
-		$(use_enable hdri) \
-		$(use_enable opencl) \
-		--with-threads \
-		--with-modules \
-		--with-quantum-depth=${depth} \
-		$(use_with cxx magick-plus-plus) \
-		$(use_with perl) \
-		--with-perl-options='INSTALLDIRS=vendor' \
-		--with-gs-font-dir="${EPREFIX}"/usr/share/fonts/urw-fonts \
-		$(use_with bzip2 bzlib) \
-		$(use_with X x) \
-		$(use_with zlib) \
-		$(use_with autotrace) \
-		$(use_with postscript dps) \
-		$(use_with djvu) \
-		--with-dejavu-font-dir="${EPREFIX}"/usr/share/fonts/dejavu \
-		$(use_with fftw) \
-		$(use_with fpx) \
-		$(use_with fontconfig) \
-		$(use_with truetype freetype) \
-		$(use_with postscript gslib) \
-		$(use_with graphviz gvc) \
-		$(use_with jbig) \
-		$(use_with jpeg) \
-		$(use_with jpeg2k openjp2) \
-		$(use_with lcms) \
-		$(use_with lqr) \
-		$(use_with lzma) \
-		$(use_with openexr) \
-		$(use_with pango) \
-		$(use_with png) \
-		$(use_with svg rsvg) \
-		$(use_with tiff) \
-		$(use_with webp) \
-		$(use_with corefonts windows-font-dir "${EPREFIX}"/usr/share/fonts/corefonts) \
-		$(use_with wmf) \
-		$(use_with xml) \
-		--${openmp}-openmp \
-		--with-gcc-arch=no-automagic
-}
-
-src_test() {
-	LD_LIBRARY_PATH="${S}/coders/.libs:${S}/filters/.libs:${S}/Magick++/lib/.libs:${S}/magick/.libs:${S}/wand/.libs" \
-	emake check
-}
-
-src_install() {
-	# Ensure documentation installation files and paths with each release!
-	emake \
-		DESTDIR="${D}" \
-		DOCUMENTATION_PATH="${EPREFIX}"/usr/share/doc/${PF}/html \
-		install
-
-	rm -f "${ED}"/usr/share/doc/${PF}/html/{ChangeLog,LICENSE,NEWS.txt}
-	dodoc {AUTHORS,README}.txt ChangeLog
-
-	if use perl; then
-		find "${ED}" -type f -name perllocal.pod -exec rm -f {} +
-		find "${ED}" -depth -mindepth 1 -type d -empty -exec rm -rf {} +
-	fi
-
-	find "${ED}" -name '*.la' -exec sed -i -e "/^dependency_libs/s:=.*:='':" {} +
-
-	if use opencl; then
-		cat <<-EOF > "${T}"/99${PN}
-		SANDBOX_PREDICT="/dev/nvidiactl:/dev/ati/card:/dev/dri/card"
-		EOF
-
-		insinto /etc/sandbox.d
-		doins "${T}"/99${PN} #472766
-	fi
-
-	insinto /usr/share/${PN}
-	doins config/*icm
-}