[gentoo-commits] repo/gentoo:master commit in: media-sound/aqualung/, media-sound/aqualung/files/

[Daniel Pielmeier]

commit:     f434b4ffd69af0afcb2f372ec73dc48d8a98a328
Author:     Daniel Pielmeier <billie <AT> gentoo <DOT> org>
AuthorDate: Wed Aug  5 18:23:42 2020 +0000
Commit:     Daniel Pielmeier <billie <AT> gentoo <DOT> org>
CommitDate: Wed Aug  5 18:23:42 2020 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=f434b4ff

media-sound/aqualung: Revision bump to aqualung-1.0-r5.

Fixes bug #735984. Thanks to Agostino Sarubbo for the report.

Package-Manager: Portage-2.3.103, Repoman-2.3.23
Signed-off-by: Daniel Pielmeier <billie <AT> gentoo.org>

 media-sound/aqualung/aqualung-1.0-r5.ebuild      | 108 +++++++++++++++++++++++
 media-sound/aqualung/files/aqualung-1.0-ar.patch |  17 ++++
 2 files changed, 125 insertions(+)

diff --git a/media-sound/aqualung/aqualung-1.0-r5.ebuild b/media-sound/aqualung/aqualung-1.0-r5.ebuild
new file mode 100644
index 00000000000..602335f9377
--- /dev/null
+++ b/media-sound/aqualung/aqualung-1.0-r5.ebuild
@@ -0,0 +1,108 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit autotools desktop xdg
+
+MY_PV=${PV/_/-}
+
+DESCRIPTION="Music player for a wide range of formats designed for gapless playback"
+HOMEPAGE="http://aqualung.jeremyevans.net/ https://github.com/jeremyevans/aqualung"
+SRC_URI="mirror://sourceforge/aqualung/${PN}-${MY_PV}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="alsa cdda cddb debug flac ffmpeg ifp jack ladspa lame libsamplerate
+	lua mac modplug mp3 musepack oss podcast pulseaudio sndfile speex systray
+	vorbis wavpack"
+
+BDEPEND="
+	virtual/pkgconfig
+	sys-devel/gettext
+"
+RDEPEND="
+	app-arch/bzip2
+	dev-libs/libxml2
+	sys-libs/zlib
+	x11-libs/gtk+:2
+	alsa? ( media-libs/alsa-lib )
+	cdda? ( dev-libs/libcdio-paranoia )
+	cddb? ( media-libs/libcddb )
+	ffmpeg? ( media-video/ffmpeg:0= )
+	flac? ( media-libs/flac )
+	ifp? ( media-libs/libifp )
+	jack? ( virtual/jack )
+	ladspa? ( media-libs/liblrdf )
+	lame? ( media-sound/lame )
+	libsamplerate? ( media-libs/libsamplerate )
+	lua? ( dev-lang/lua:0= )
+	mac? ( media-sound/mac )
+	modplug? ( media-libs/libmodplug )
+	mp3? ( media-libs/libmad )
+	musepack? ( >=media-sound/musepack-tools-444 )
+	pulseaudio? ( media-sound/pulseaudio )
+	sndfile? ( media-libs/libsndfile )
+	speex? ( media-libs/speex media-libs/liboggz media-libs/libogg )
+	vorbis? ( media-libs/libvorbis media-libs/libogg )
+	wavpack? ( media-sound/wavpack )
+"
+DEPEND="
+	${RDEPEND}
+"
+
+S=${WORKDIR}/${PN}-${MY_PV}
+
+PATCHES=(
+	"${FILESDIR}/${P}-ffmpeg3.patch"
+	"${FILESDIR}/${P}-gcc10.patch"
+	"${FILESDIR}/${P}-ar.patch"
+)
+
+src_prepare() {
+	default
+
+	eautoreconf
+}
+
+src_configure() {
+	econf \
+		--disable-rpath \
+		--enable-loop \
+		--enable-nls \
+		--enable-transcoding \
+		$(use_enable debug) \
+		$(use_enable podcast) \
+		$(use_enable systray) \
+		$(use_enable jack jack-mgmt) \
+		$(use_with alsa) \
+		$(use_with cdda) \
+		$(use_with cddb) \
+		$(use_with ffmpeg lavc) \
+		$(use_with flac) \
+		$(use_with ifp) \
+		$(use_with jack) \
+		$(use_with ladspa) \
+		$(use_with lame) \
+		$(use_with libsamplerate src) \
+		$(use_with lua) \
+		$(use_with mac) \
+		$(use_with modplug mod) \
+		$(use_with mp3 mpeg) \
+		$(use_with musepack mpc) \
+		$(use_with oss) \
+		$(use_with pulseaudio pulse) \
+		$(use_with sndfile) \
+		$(use_with speex) \
+		$(use_with vorbis vorbis) \
+		$(use_with vorbis vorbisenc) \
+		$(use_with wavpack)
+}
+
+src_install() {
+	default
+
+	newicon src/img/icon_64.png aqualung.png
+	make_desktop_entry aqualung Aqualung
+}

diff --git a/media-sound/aqualung/files/aqualung-1.0-ar.patch b/media-sound/aqualung/files/aqualung-1.0-ar.patch
new file mode 100644
index 00000000000..3df4d75eaf1
--- /dev/null
+++ b/media-sound/aqualung/files/aqualung-1.0-ar.patch
@@ -0,0 +1,17 @@
+diff -Naur aqualung-1.0_orig/configure.ac aqualung-1.0/configure.ac
+--- aqualung-1.0_orig/configure.ac	2020-08-05 20:00:50.758797358 +0200
++++ aqualung-1.0/configure.ac	2020-08-05 20:01:33.198796503 +0200
+@@ -25,11 +25,12 @@
+ 
+ 
+ # Checks for programs.
++AC_USE_SYSTEM_EXTENSIONS
+ AC_PROG_CC
+ AC_PROG_RANLIB
+ AC_PROG_CXX
+ AM_PROG_CC_C_O
+-AC_USE_SYSTEM_EXTENSIONS
++AM_PROG_AR
+ m4_ifndef([AM_GNU_GETTEXT],
+     [m4_fatal([GNU gettext is required to prepare the Aqualung build])])
+ AM_GNU_GETTEXT([external])