[gentoo-commits] gentoo-x86 commit in net-misc/curl: ChangeLog curl-7.19.2.ebuild curl-7.19.1.ebuild curl-7.19.0.ebuild

[Peter Alfredsen (loki_val)]

loki_val    08/11/22 05:33:50

  Modified:             ChangeLog
  Added:                curl-7.19.2.ebuild
  Removed:              curl-7.19.1.ebuild curl-7.19.0.ebuild
  Log:
  Bumb, as per 247029.
  (Portage version: 2.2_rc14/cvs/Linux 2.6.28-rc4 x86_64)

Revision  Changes    Path
1.130                net-misc/curl/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-misc/curl/ChangeLog?rev=1.130&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-misc/curl/ChangeLog?rev=1.130&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-misc/curl/ChangeLog?r1=1.129&r2=1.130

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-misc/curl/ChangeLog,v
retrieving revision 1.129
retrieving revision 1.130
diff -u -r1.129 -r1.130
--- ChangeLog	8 Nov 2008 00:19:03 -0000	1.129
+++ ChangeLog	22 Nov 2008 05:33:50 -0000	1.130
@@ -1,6 +1,12 @@
 # ChangeLog for net-misc/curl
 # Copyright 2002-2008 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-misc/curl/ChangeLog,v 1.129 2008/11/08 00:19:03 dragonheart Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-misc/curl/ChangeLog,v 1.130 2008/11/22 05:33:50 loki_val Exp $
+
+*curl-7.19.2 (22 Nov 2008)
+
+  22 Nov 2008; Peter Alfredsen <loki_val@g.o> -curl-7.19.0.ebuild,
+  -curl-7.19.1.ebuild, +curl-7.19.2.ebuild:
+  Bumb, as per 247029.
 
 *curl-7.19.1 (08 Nov 2008)
 



1.1                  net-misc/curl/curl-7.19.2.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-misc/curl/curl-7.19.2.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-misc/curl/curl-7.19.2.ebuild?rev=1.1&content-type=text/plain

Index: curl-7.19.2.ebuild
===================================================================
# Copyright 1999-2008 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-misc/curl/curl-7.19.2.ebuild,v 1.1 2008/11/22 05:33:50 loki_val Exp $

# NOTE: If you bump this ebuild, make sure you bump dev-python/pycurl!

inherit multilib eutils

#MY_P=${P/_pre/-}
DESCRIPTION="A Client that groks URLs"
HOMEPAGE="http://curl.haxx.se/ http://curl.planetmirror.com"
#SRC_URI="http://cool.haxx.se/curl-daily/${MY_P}.tar.bz2"
#SRC_URI="http://curl.planetmirror.com/download/${P}.tar.bz2"
SRC_URI="http://curl.haxx.se/download/${P}.tar.bz2"

LICENSE="MIT X11"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~sparc-fbsd ~x86 ~x86-fbsd"
#IUSE="ssl ipv6 ldap ares gnutls nss idn kerberos test"
IUSE="ssl ipv6 ldap ares gnutls libssh2 nss idn kerberos test"

# TODO - change to openssl USE flag in the not too distant future
# https://bugs.gentoo.org/show_bug.cgi?id=207653#c3 (April 2008)

RDEPEND="gnutls? ( net-libs/gnutls app-misc/ca-certificates )
	nss? ( !gnutls? ( dev-libs/nss app-misc/ca-certificates ) )
	ssl? ( !gnutls? ( !nss? ( dev-libs/openssl app-misc/ca-certificates ) ) )
	ldap? ( net-nds/openldap )
	idn? ( net-dns/libidn )
	ares? ( >=net-dns/c-ares-1.4.0 )
	kerberos? ( virtual/krb5 )
	libssh2? ( >=net-libs/libssh2-0.16 )"

# fbopenssl (not in gentoo) --with-spnego
# krb4 http://web.mit.edu/kerberos/www/krb4-end-of-life.html

DEPEND="${RDEPEND}
	test? (
		sys-apps/diffutils
		dev-lang/perl
	)"
# used - but can do without in self test: net-misc/stunnel
#S="${WORKDIR}"/${MY_P}

src_unpack() {
	unpack ${A}
	cd "${S}"
	epatch "${FILESDIR}"/curl-7.17.0-strip-ldflags.patch
}

src_compile() {

	myconf="$(use_enable ldap)
		$(use_enable ldap ldaps)
		$(use_with idn libidn)
		$(use_with kerberos gssapi /usr)
		$(use_with libssh2)
		$(use_enable ipv6)
		--enable-http
		--enable-ftp
		--enable-gopher
		--enable-file
		--enable-dict
		--enable-manual
		--enable-telnet
		--enable-nonblocking
		--enable-largefile
		--enable-maintainer-mode
		--disable-sspi
		--without-krb4
		--without-spnego"

	if use ipv6 && use ares; then
		elog "c-ares support disabled because it is incompatible with ipv6."
		myconf="${myconf} --disable-ares"
	else
		myconf="${myconf} $(use_enable ares)"
	fi

	if use gnutls; then
		myconf="${myconf} --without-ssl --with-gnutls --without-nss"
		myconf="${myconf} --with-ca-bundle=/etc/ssl/certs/ca-certificates.crt"
	elif use nss; then
		myconf="${myconf} --without-ssl --without-gnutls --with-nss"
		myconf="${myconf} --with-ca-bundle=/etc/ssl/certs/ca-certificates.crt"
	elif use ssl; then
		myconf="${myconf} --without-gnutls --without-nss --with-ssl"
		myconf="${myconf} --without-ca-bundle --with-ca-path=/etc/ssl/certs"
	else
		myconf="${myconf} --without-gnutls --without-nss --without-ssl"
	fi

	econf ${myconf} || die 'configure failed'

	emake || die "install failed for current version"
}

src_install() {
	emake DESTDIR="${D}" install || die "installed failed for current version"
	rm -rf "${D}"/etc/

	# https://sourceforge.net/tracker/index.php?func=detail&aid=1705197&group_id=976&atid=350976
	insinto /usr/share/aclocal
	doins docs/libcurl/libcurl.m4

	dodoc CHANGES README
	dodoc docs/FEATURES docs/INTERNALS
	dodoc docs/MANUAL docs/FAQ docs/BUGS docs/CONTRIBUTE
}

pkg_postinst() {
	if [[ -e "${ROOT}"/usr/$(get_libdir)/libcurl.so.3 ]] ; then
		elog "You must re-compile all packages that are linked against"
		elog "curl-7.15.* by using revdep-rebuild from gentoolkit:"
		elog "# revdep-rebuild --library libcurl.so.3"
	fi
}