[gentoo-commits] repo/gentoo:master commit in: app-emacs/emacs-ipython-notebook/files/, app-emacs/emacs-ipython-notebook/

[Maciej Barć]

commit:     eb2b4325dbc9d5418675d95424c3706d9aee7643
Author:     Maciej Barć <xgqt <AT> gentoo <DOT> org>
AuthorDate: Wed May  4 13:40:19 2022 +0000
Commit:     Maciej Barć <xgqt <AT> gentoo <DOT> org>
CommitDate: Wed May  4 13:40:40 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=eb2b4325

app-emacs/emacs-ipython-notebook: new package; add 0.17.0_p20220419

2022.04.19 snapshot

Signed-off-by: Maciej Barć <xgqt <AT> gentoo.org>

 app-emacs/emacs-ipython-notebook/Manifest          |  1 +
 .../emacs-ipython-notebook-0.17.0_p20220419.ebuild | 66 ++++++++++++++++++++++
 .../files/50emacs-ipython-notebook-gentoo.el       |  4 ++
 app-emacs/emacs-ipython-notebook/metadata.xml      | 13 +++++
 4 files changed, 84 insertions(+)

diff --git a/app-emacs/emacs-ipython-notebook/Manifest b/app-emacs/emacs-ipython-notebook/Manifest
new file mode 100644
index 000000000000..41326ee84aa3
--- /dev/null
+++ b/app-emacs/emacs-ipython-notebook/Manifest
@@ -0,0 +1 @@
+DIST emacs-ipython-notebook-0.17.0_p20220419.tar.gz 313340 BLAKE2B 5ab9b82d8d17c3f64c375de7638aa4006e7dc47137260ab0a8222f7c507a54b32aa145d1630b3d0018c8303e0f116da81b61df27cd401875dfad5fd49ecdae13 SHA512 f6c2c293e7d2ddcba9dfac751523e0f8d55047ed01d4546ba1ece1f8833a1d54a1bcc066f34f06e111c34baee21a97c2ede2d90d188d7a05f407631acfd74037

diff --git a/app-emacs/emacs-ipython-notebook/emacs-ipython-notebook-0.17.0_p20220419.ebuild b/app-emacs/emacs-ipython-notebook/emacs-ipython-notebook-0.17.0_p20220419.ebuild
new file mode 100644
index 000000000000..9e0ed53eda37
--- /dev/null
+++ b/app-emacs/emacs-ipython-notebook/emacs-ipython-notebook-0.17.0_p20220419.ebuild
@@ -0,0 +1,66 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+# NOTICE: Check package version in "lisp/ein-pkg.el".
+# NOTICE: File "lisp/ein-pkg.el" is needed by the "ein:dev-sys-info" function.
+
+EAPI=8
+
+H=388c8f753cfb99b4f82acbdff26bbe27189d2299
+NEED_EMACS=25
+
+inherit elisp readme.gentoo-r1
+
+DESCRIPTION="Jupyter notebook client in Emacs"
+HOMEPAGE="https://github.com/millejoh/emacs-ipython-notebook/"
+SRC_URI="https://github.com/millejoh/${PN}/archive/${H}.tar.gz -> ${P}.tar.gz"
+S="${WORKDIR}"/${PN}-${H}
+
+LICENSE="GPL-3+"
+KEYWORDS="~amd64 ~x86"
+SLOT="0"
+IUSE="test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	app-emacs/anaphora
+	app-emacs/dash
+	app-emacs/deferred
+	app-emacs/polymode
+	app-emacs/request
+	app-emacs/websocket
+	app-emacs/with-editor
+	dev-python/ipython
+	dev-python/notebook
+	www-servers/tornado
+"
+BDEPEND="
+	${RDEPEND}
+	test? ( app-emacs/ert-runner )
+"
+
+DOCS=( README.rst thumbnail.png )
+DOC_CONTENTS="There may be problems with connecting to Jupyter Notebooks
+	because of the tokens, in that case you can try running	\"jupyter
+	notebook\" with --NotebookApp.token=\"\" (and --NotebookApp.ip=127.0.0.1 to
+	limit connections only to local machine), but be warned that this can
+	compromise your system if used without caution! For reference check out
+	https://github.com/millejoh/emacs-ipython-notebook/issues/838"
+
+SITEFILE="50${PN}-gentoo.el"
+
+src_compile() {
+	BYTECOMPFLAGS="-L lisp" elisp-compile lisp/*.el
+}
+
+src_test() {
+	ert-runner -L lisp -L test -l test/testein.el \
+			   --reporter ert+duration test/test-ein*.el || die
+}
+
+src_install() {
+	elisp-install ${PN} lisp/*.el{,c}
+	elisp-site-file-install "${FILESDIR}/${SITEFILE}"
+
+	readme.gentoo_create_doc
+}

diff --git a/app-emacs/emacs-ipython-notebook/files/50emacs-ipython-notebook-gentoo.el b/app-emacs/emacs-ipython-notebook/files/50emacs-ipython-notebook-gentoo.el
new file mode 100644
index 000000000000..97bab14bcf69
--- /dev/null
+++ b/app-emacs/emacs-ipython-notebook/files/50emacs-ipython-notebook-gentoo.el
@@ -0,0 +1,4 @@
+(add-to-list 'load-path "@SITELISP@")
+(autoload 'ein:ipynb-mode "ein-ipynb-mode"
+  "A simple mode for ipynb file." t)
+(add-to-list 'auto-mode-alist '("\\.ipynb\\'" . ein:ipynb-mode))

diff --git a/app-emacs/emacs-ipython-notebook/metadata.xml b/app-emacs/emacs-ipython-notebook/metadata.xml
new file mode 100644
index 000000000000..d0e5ba20a2d5
--- /dev/null
+++ b/app-emacs/emacs-ipython-notebook/metadata.xml
@@ -0,0 +1,13 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "https://www.gentoo.org/dtd/metadata.dtd">
+
+<pkgmetadata>
+  <maintainer type="project">
+    <email>gnu-emacs@g.o</email>
+    <name>Gentoo GNU Emacs project</name>
+  </maintainer>
+  <upstream>
+    <bugs-to>https://github.com/millejoh/emacs-ipython-notebook/issues/</bugs-to>
+    <remote-id type="github">millejoh/emacs-ipython-notebook</remote-id>
+  </upstream>
+</pkgmetadata>