[gentoo-commits] gentoo-x86 commit in dev-python/axiom: ChangeLog axiom-0.6.0.ebuild

[Arfrever Frehtes Taifersar Arahesis (arfrever)]

arfrever    09/11/30 12:46:51

  Modified:             ChangeLog
  Added:                axiom-0.6.0.ebuild
  Log:
  Version bump. Set SUPPORT_PYTHON_ABIS.
  (Portage version: 14920-svn/cvs/Linux x86_64)

Revision  Changes    Path
1.29                 dev-python/axiom/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-python/axiom/ChangeLog?rev=1.29&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-python/axiom/ChangeLog?rev=1.29&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-python/axiom/ChangeLog?r1=1.28&r2=1.29

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-python/axiom/ChangeLog,v
retrieving revision 1.28
retrieving revision 1.29
diff -u -r1.28 -r1.29
--- ChangeLog	6 Sep 2009 23:00:11 -0000	1.28
+++ ChangeLog	30 Nov 2009 12:46:51 -0000	1.29
@@ -1,6 +1,12 @@
 # ChangeLog for dev-python/axiom
 # Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-python/axiom/ChangeLog,v 1.28 2009/09/06 23:00:11 idl0r Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-python/axiom/ChangeLog,v 1.29 2009/11/30 12:46:51 arfrever Exp $
+
+*axiom-0.6.0 (30 Nov 2009)
+
+  30 Nov 2009; Arfrever Frehtes Taifersar Arahesis <arfrever@g.o>
+  +axiom-0.6.0.ebuild:
+  Version bump. Set SUPPORT_PYTHON_ABIS.
 
   06 Sep 2009; Christian Ruppert <idl0r@g.o>
   -files/axiom-0.5.20-sqlite3.patch, -files/axiom-0.5.27-sqlite3.patch:



1.1                  dev-python/axiom/axiom-0.6.0.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-python/axiom/axiom-0.6.0.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-python/axiom/axiom-0.6.0.ebuild?rev=1.1&content-type=text/plain

Index: axiom-0.6.0.ebuild
===================================================================
# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-python/axiom/axiom-0.6.0.ebuild,v 1.1 2009/11/30 12:46:51 arfrever Exp $

EAPI="2"
SUPPORT_PYTHON_ABIS="1"

# setup.py uses epsilon.setuphelper.autosetup(), which tries to use
# build-${PYTHON_ABI} directories as packages.
DISTUTILS_USE_SEPARATE_SOURCE_DIRECTORIES="1"

inherit distutils eutils twisted

MY_PN="Axiom"
MY_P="${MY_PN}-${PV}"

DESCRIPTION="Axiom is an object database implemented on top of SQLite."
HOMEPAGE="http://divmod.org/trac/wiki/DivmodAxiom http://pypi.python.org/pypi/Axiom"
SRC_URI="http://pypi.python.org/packages/source/${MY_PN:0:1}/${MY_PN}/${MY_P}.tar.gz"

LICENSE="MIT"
SLOT="0"
KEYWORDS="~amd64 ~ia64 ~ppc64 ~x86"
IUSE=""

DEPEND="|| ( >=dev-lang/python-2.5[sqlite]
	( >=dev-lang/python-2.4 >=dev-python/pysqlite-2.0 ) )
	>=dev-db/sqlite-3.2.1
	>=dev-python/twisted-2.4
	>=dev-python/twisted-conch-0.7.0-r1
	>=dev-python/epsilon-0.6"
RDEPEND="${DEPEND}"
RESTRICT_PYTHON_ABIS="3.*"

S=${WORKDIR}/${MY_P}

DOCS="NAME.txt"

src_prepare() {
	epatch "${FILESDIR}/${PN}-0.5.30-sqlite3.patch"
	epatch "${FILESDIR}/${PN}-0.5.30-sqlite3_3.6.4.patch"
	python_copy_sources
}

src_compile() {
	# Skip distutils_src_compile to avoid installation of $(python_get_sitedir)/build directory.
	:
}

src_test() {
	testing() {
		PYTHONPATH="." trial axiom
	}
	python_execute_function testing
}

src_install() {
	PORTAGE_PLUGINCACHE_NOOP="1" distutils_src_install
}

update_axiom_plugin_cache() {
	einfo "Updating axiom plugin cache..."
	"$(PYTHON)" -c 'from twisted.plugin import IPlugin, getPlugIns;from axiom import plugins; list(getPlugIns(IPlugin, plugins))'
}

pkg_postrm() {
	twisted_pkg_postrm
	python_execute_function update_axiom_plugin_cache
}

pkg_postinst() {
	twisted_pkg_postinst
	python_execute_function update_axiom_plugin_cache
}