[gentoo-commits] gentoo-x86 commit in dev-cpp/sptk: ChangeLog sptk-4.13-r1.ebuild

[Samuli Suominen (ssuominen)]

ssuominen    12/02/07 16:35:53

  Modified:             ChangeLog
  Added:                sptk-4.13-r1.ebuild
  Log:
  Punt broken aspell support wrt #402149 by Agostino Sarubbo. Also, correct other dependencies and USE flags for the 4.13 release.
  
  (Portage version: 2.2.0_alpha84/cvs/Linux x86_64)

Revision  Changes    Path
1.76                 dev-cpp/sptk/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-cpp/sptk/ChangeLog?rev=1.76&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-cpp/sptk/ChangeLog?rev=1.76&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-cpp/sptk/ChangeLog?r1=1.75&r2=1.76

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-cpp/sptk/ChangeLog,v
retrieving revision 1.75
retrieving revision 1.76
diff -u -r1.75 -r1.76
--- ChangeLog	6 Feb 2012 20:15:39 -0000	1.75
+++ ChangeLog	7 Feb 2012 16:35:53 -0000	1.76
@@ -1,6 +1,12 @@
 # ChangeLog for dev-cpp/sptk
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-cpp/sptk/ChangeLog,v 1.75 2012/02/06 20:15:39 ssuominen Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-cpp/sptk/ChangeLog,v 1.76 2012/02/07 16:35:53 ssuominen Exp $
+
+*sptk-4.13-r1 (07 Feb 2012)
+
+  07 Feb 2012; Samuli Suominen <ssuominen@g.o> +sptk-4.13-r1.ebuild:
+  Punt broken aspell support wrt #402149 by Agostino Sarubbo. Also, correct
+  other dependencies and USE flags for the 4.13 release.
 
 *sptk-4.13 (06 Feb 2012)
 



1.1                  dev-cpp/sptk/sptk-4.13-r1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-cpp/sptk/sptk-4.13-r1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-cpp/sptk/sptk-4.13-r1.ebuild?rev=1.1&content-type=text/plain

Index: sptk-4.13-r1.ebuild
===================================================================
# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-cpp/sptk/sptk-4.13-r1.ebuild,v 1.1 2012/02/07 16:35:53 ssuominen Exp $

EAPI=4
CMAKE_IN_SOURCE_BUILD=1
inherit cmake-utils multilib

DESCRIPTION="C++ user interface toolkit for X with database and Excel support"
HOMEPAGE="http://www.sptk.net/"
SRC_URI="http://www.sptk.net/${P}.tbz2"

LICENSE="GPL-2 LGPL-2 LGPL-2.1"
SLOT="4"
KEYWORDS="~alpha ~amd64 ~mips ~ppc ~sparc ~x86"
IUSE="doc examples excel fltk mysql odbc pcre postgres sqlite ssl" # spell

# spell? ( >=app-text/aspell-0.60 )
RDEPEND="
	fltk? (
		>=media-libs/libpng-1.2:0
		sys-libs/zlib
		>=x11-libs/fltk-1.3.0:1
		)
	mysql? ( virtual/mysql )
	odbc? ( >=dev-db/unixODBC-2.3.0 )
	pcre? ( dev-libs/libpcre )
	postgres? ( >=dev-db/postgresql-base-8.0 )
	sqlite? ( >=dev-db/sqlite-3 )
	ssl? ( dev-libs/openssl:0 )"
DEPEND="${RDEPEND}
	doc? ( app-doc/doxygen )"

DOCS="AUTHORS README"

src_configure() {
	# $(cmake-utils_use_no spell ASPELL)

	local mycmakeargs=(
		-DLIBDIR=$(get_libdir)
		-DNO_ASPELL=ON
		-DNO_EXAMPLES=ON
		$(cmake-utils_use_no excel)
		$(cmake-utils_use_no fltk)
		$(cmake-utils_use_no mysql)
		$(cmake-utils_use_no odbc)
		$(cmake-utils_use_no ssl OPENSSL)
		$(cmake-utils_use_no pcre)
		$(cmake-utils_use_no postgres POSTGRESQL)
		$(cmake-utils_use_no sqlite SQLITE3)
		)

	cmake-utils_src_configure
}

src_compile() {
	cmake-utils_src_compile

	if use doc; then
		doxygen sptk4.doxygen
	fi
}

src_install () {
	cmake-utils_src_install

	if use doc; then
		insinto /usr/share/doc/${PF}
		doins -r docs pictures
	fi

	if use examples; then
		insinto /usr/share/doc/${PF}
		doins -r applications examples
	fi

	if [[ -e ${ED}/usr/bin/sql2cpp.pl ]]; then
		dosym sql2cpp.pl /usr/bin/sql2cpp
	fi
}