[gentoo-commits] gentoo-x86 commit in net-mail/libpst: libpst-0.6.59.ebuild ChangeLog

[Patrick Lauer (patrick)]

patrick     13/05/23 06:06:08

  Modified:             ChangeLog
  Added:                libpst-0.6.59.ebuild
  Log:
  Bump
  
  (Portage version: 2.2.0_alpha176/cvs/Linux x86_64, unsigned Manifest commit)

Revision  Changes    Path
1.42                 net-mail/libpst/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-mail/libpst/ChangeLog?rev=1.42&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-mail/libpst/ChangeLog?rev=1.42&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-mail/libpst/ChangeLog?r1=1.41&r2=1.42

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-mail/libpst/ChangeLog,v
retrieving revision 1.41
retrieving revision 1.42
diff -u -r1.41 -r1.42
--- ChangeLog	26 Mar 2013 11:41:30 -0000	1.41
+++ ChangeLog	23 May 2013 06:06:08 -0000	1.42
@@ -1,6 +1,11 @@
 # ChangeLog for net-mail/libpst
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-mail/libpst/ChangeLog,v 1.41 2013/03/26 11:41:30 ago Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-mail/libpst/ChangeLog,v 1.42 2013/05/23 06:06:08 patrick Exp $
+
+*libpst-0.6.59 (23 May 2013)
+
+  23 May 2013; Patrick Lauer <patrick@g.o> +libpst-0.6.59.ebuild:
+  Bump
 
   26 Mar 2013; Agostino Sarubbo <ago@g.o> libpst-0.6.58.ebuild:
   Stable for x86, wrt bug #463120



1.1                  net-mail/libpst/libpst-0.6.59.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-mail/libpst/libpst-0.6.59.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-mail/libpst/libpst-0.6.59.ebuild?rev=1.1&content-type=text/plain

Index: libpst-0.6.59.ebuild
===================================================================
# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-mail/libpst/libpst-0.6.59.ebuild,v 1.1 2013/05/23 06:06:08 patrick Exp $

EAPI=4
PYTHON_DEPEND="python? 2"

inherit autotools eutils python

DESCRIPTION="Tools and library for reading Outlook files (.pst format)"
HOMEPAGE="http://www.five-ten-sg.com/libpst/"
SRC_URI="http://www.five-ten-sg.com/${PN}/packages/${P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86"
IUSE="debug dii doc python static-libs"

RDEPEND="dii? ( media-gfx/imagemagick[png] )
	gnome-extra/libgsf"
DEPEND="${RDEPEND}
	virtual/libiconv
	virtual/pkgconfig
	dii? ( media-libs/gd[png] )
	python? ( >=dev-libs/boost-1.48[python] )"

pkg_setup() {
	if use python; then
		python_set_active_version 2
		python_pkg_setup
	fi
}

src_prepare() {
	# don't build the static python library
	epatch "${FILESDIR}"/${PN}-0.6.52-no-static-python-lib.patch

	# fix pkgconfig file for static linking
	epatch "${FILESDIR}"/${PN}-0.6.53-pkgconfig-static.patch

	# conditionally install the extra documentation
	use doc || { sed -i -e "/SUBDIRS/s: html::" Makefile.am || die; }

	# don't install duplicate docs
	sed -i -e "/^html_DATA =/d" Makefile.am || die

	eautoreconf
}

src_configure() {
	econf \
		--enable-libpst-shared \
		$(use_enable debug pst-debug) \
		$(use_enable dii) \
		$(use_enable python) \
		$(use_enable static-libs static) \
		$(use python && echo --with-boost-python=boost_python-${PYTHON_ABI})
}

src_install() {
	default
	prune_libtool_files --all
}