[gentoo-commits] gentoo-x86 commit in dev-util/wiggle: ChangeLog wiggle-0.8-r1.ebuild

[Jonathan Callen (abcd)]

abcd        10/09/29 02:59:50

  Modified:             ChangeLog
  Added:                wiggle-0.8-r1.ebuild
  Log:
  Revbump; patch to fix buffer overflows (bug 339073)
  
  (Portage version: 2.2_rc86_p7/cvs/Linux i686)

Revision  Changes    Path
1.21                 dev-util/wiggle/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-util/wiggle/ChangeLog?rev=1.21&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-util/wiggle/ChangeLog?rev=1.21&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-util/wiggle/ChangeLog?r1=1.20&r2=1.21

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-util/wiggle/ChangeLog,v
retrieving revision 1.20
retrieving revision 1.21
diff -u -r1.20 -r1.21
--- ChangeLog	24 Mar 2010 18:15:28 -0000	1.20
+++ ChangeLog	29 Sep 2010 02:59:50 -0000	1.21
@@ -1,6 +1,12 @@
 # ChangeLog for dev-util/wiggle
 # Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-util/wiggle/ChangeLog,v 1.20 2010/03/24 18:15:28 robbat2 Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-util/wiggle/ChangeLog,v 1.21 2010/09/29 02:59:50 abcd Exp $
+
+*wiggle-0.8-r1 (29 Sep 2010)
+
+  29 Sep 2010; Jonathan Callen <abcd@g.o> +wiggle-0.8-r1.ebuild,
+  +files/wiggle-0.8-buffer-overflow.patch:
+  Revbump; patch to fix buffer overflows (bug 339073)
 
 *wiggle-0.8 (24 Mar 2010)
 



1.1                  dev-util/wiggle/wiggle-0.8-r1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-util/wiggle/wiggle-0.8-r1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-util/wiggle/wiggle-0.8-r1.ebuild?rev=1.1&content-type=text/plain

Index: wiggle-0.8-r1.ebuild
===================================================================
# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-util/wiggle/wiggle-0.8-r1.ebuild,v 1.1 2010/09/29 02:59:50 abcd Exp $

EAPI=3

inherit eutils fixheadtails toolchain-funcs

DESCRIPTION="program for applying patches that patch cannot apply because of conflicting changes"
HOMEPAGE="http://neil.brown.name/wiggle http://neil.brown.name/git?p=wiggle"
SRC_URI="http://neil.brown.name/${PN}/${P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~x86 ~amd64-linux ~x86-linux"
IUSE="test"

# The 'p' tool does support bitkeeper, but I'm against just dumping it in here
# due to it's size.  I've explictly listed every other dependancy here due to
# the nature of the shell program 'p'
RDEPEND="dev-util/diffstat
	dev-util/patchutils
	sys-apps/diffutils
	sys-apps/findutils
	sys-apps/gawk
	sys-apps/grep
	sys-apps/less
	sys-apps/sed
	sys-apps/coreutils
	sys-devel/patch"
DEPEND="${RDEPEND}
	sys-apps/groff
	test? ( sys-process/time )"

src_prepare() {
	epatch "${FILESDIR}/${P}-buffer-overflow.patch"

	# Fix the reference to the help file so `p help' works
	sed -i "s:\$0.help:${EPREFIX}/usr/share/wiggle/p.help:" p || die "sed failed on p"

	# Don't add Neil Brown's default sign off line to every patch
	sed -i '/$CERT/,+4s,^,#,' p || die "sed failed on p"

	# Use prefixed time binary
	sed -i "s:/usr/bin/time:${EPREFIX}/usr/bin/time:" dotest || die "sed failed on dotest"

	ht_fix_file p
}

src_compile() {
	emake CC="$(tc-getCC)" CFLAGS="${CFLAGS} -Wall" \
		wiggle || die "emake wiggle failed."
}

src_install() {
	dobin wiggle p || die "failed to install binaries"
	doman wiggle.1 || die "failed to install man page"
	dodoc ANNOUNCE INSTALL TODO DOC/diff.ps notes || die "failed to install docs"
	insinto /usr/share/wiggle
	doins p.help || die "failed to install help file"
}