[gentoo-commits] gentoo-x86 commit in media-gfx/darktable: metadata.xml ChangeLog darktable-1.4.ebuild darktable-9999.ebuild

[Markus Meier (maekke)]

maekke      14/01/21 20:35:00

  Modified:             metadata.xml ChangeLog darktable-9999.ebuild
  Added:                darktable-1.4.ebuild
  Log:
  version bump, bug #496138
  - add webp support
  - lua support disabled, as it requires masked dev-lang/lua-5.2
  - respect LINGUAS, bug #403037
  
  (Portage version: 2.2.8/cvs/Linux x86_64, signed Manifest commit with key 072AD062)

Revision  Changes    Path
1.14                 media-gfx/darktable/metadata.xml

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-gfx/darktable/metadata.xml?rev=1.14&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-gfx/darktable/metadata.xml?rev=1.14&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-gfx/darktable/metadata.xml?r1=1.13&r2=1.14

Index: metadata.xml
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-gfx/darktable/metadata.xml,v
retrieving revision 1.13
retrieving revision 1.14
diff -u -r1.13 -r1.14
--- metadata.xml	27 Sep 2013 05:26:44 -0000	1.13
+++ metadata.xml	21 Jan 2014 20:35:00 -0000	1.14
@@ -18,6 +18,7 @@
 		<flag name="slideshow">Build the opengl slideshow viewer</flag>
 		<flag name="squish">Enable thumbnail compression via libsquish</flag>
 		<flag name="web-services">Add support for uploading photos to facebook and picasa</flag>
+		<flag name="webp">Enable WebP export support</flag>
 	</use>
 	<upstream>
 		<remote-id type="github">darktable-org/darktable</remote-id>



1.53                 media-gfx/darktable/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-gfx/darktable/ChangeLog?rev=1.53&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-gfx/darktable/ChangeLog?rev=1.53&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-gfx/darktable/ChangeLog?r1=1.52&r2=1.53

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-gfx/darktable/ChangeLog,v
retrieving revision 1.52
retrieving revision 1.53
diff -u -r1.52 -r1.53
--- ChangeLog	12 Jan 2014 11:25:14 -0000	1.52
+++ ChangeLog	21 Jan 2014 20:35:00 -0000	1.53
@@ -1,6 +1,15 @@
 # ChangeLog for media-gfx/darktable
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-gfx/darktable/ChangeLog,v 1.52 2014/01/12 11:25:14 maekke Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-gfx/darktable/ChangeLog,v 1.53 2014/01/21 20:35:00 maekke Exp $
+
+*darktable-1.4 (21 Jan 2014)
+
+  21 Jan 2014; Markus Meier <maekke@g.o> +darktable-1.4.ebuild,
+  darktable-9999.ebuild, metadata.xml:
+  version bump, bug #496138
+  - add webp support
+  - lua support disabled, as it requires masked dev-lang/lua-5.2
+  - respect LINGUAS, bug #403037
 
   12 Jan 2014; Markus Meier <maekke@g.o> darktable-1.2.3.ebuild,
   darktable-9999.ebuild:



1.12                 media-gfx/darktable/darktable-9999.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-gfx/darktable/darktable-9999.ebuild?rev=1.12&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-gfx/darktable/darktable-9999.ebuild?rev=1.12&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-gfx/darktable/darktable-9999.ebuild?r1=1.11&r2=1.12

Index: darktable-9999.ebuild
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-gfx/darktable/darktable-9999.ebuild,v
retrieving revision 1.11
retrieving revision 1.12
diff -u -r1.11 -r1.12
--- darktable-9999.ebuild	12 Jan 2014 11:25:14 -0000	1.11
+++ darktable-9999.ebuild	21 Jan 2014 20:35:00 -0000	1.12
@@ -1,6 +1,6 @@
 # Copyright 1999-2014 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/media-gfx/darktable/darktable-9999.ebuild,v 1.11 2014/01/12 11:25:14 maekke Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-gfx/darktable/darktable-9999.ebuild,v 1.12 2014/01/21 20:35:00 maekke Exp $
 
 EAPI=5
 
@@ -10,43 +10,49 @@
 
 DESCRIPTION="A virtual lighttable and darkroom for photographers"
 HOMEPAGE="http://www.darktable.org/"
+SRC_URI=""
 
-LICENSE="GPL-3"
+LICENSE="GPL-3 CC-BY-3.0"
 SLOT="0"
-IUSE="colord flickr geo gnome-keyring gphoto2 graphicsmagick jpeg2k kde
-nls opencl openmp pax_kernel +rawspeed +slideshow +squish web-services"
+KEYWORDS=""
+LANGS=" cs da de el es fr it ja nl pl pt_BR pt_PT ru sq sv uk"
+# TODO add lua once dev-lang/lua-5.2 is unmasked
+IUSE="colord doc flickr geo gnome-keyring gphoto2 graphicsmagick jpeg2k kde
+nls opencl openmp pax_kernel +rawspeed +slideshow +squish web-services webp
+${LANGS// / linguas_}"
 
 CDEPEND="
 	dev-db/sqlite:3
 	>=dev-libs/glib-2.28:2
 	dev-libs/libxml2:2
-	colord? ( x11-misc/colord )
-	flickr? ( media-libs/flickcurl )
-	geo? ( net-libs/libsoup:2.4 )
-	gnome-keyring? ( gnome-base/gnome-keyring )
 	gnome-base/librsvg:2
-	gphoto2? ( media-libs/libgphoto2:= )
-	graphicsmagick? ( media-gfx/graphicsmagick )
-	jpeg2k? ( media-libs/openjpeg:0 )
-	media-gfx/exiv2[xmp]
+	media-gfx/exiv2:0=[xmp]
 	media-libs/lcms:2
 	>=media-libs/lensfun-0.2.3
 	media-libs/libpng:0=
-	media-libs/openexr
+	media-libs/openexr:0=
 	media-libs/tiff:0
 	net-misc/curl
+	virtual/jpeg
+	x11-libs/cairo
+	x11-libs/gdk-pixbuf:2
+	x11-libs/gtk+:2
+	x11-libs/pango
+	colord? ( x11-misc/colord:0= )
+	flickr? ( media-libs/flickcurl )
+	geo? ( net-libs/libsoup:2.4 )
+	gnome-keyring? ( gnome-base/gnome-keyring )
+	gphoto2? ( media-libs/libgphoto2:= )
+	graphicsmagick? ( media-gfx/graphicsmagick )
+	jpeg2k? ( media-libs/openjpeg:0 )
 	opencl? ( virtual/opencl )
 	slideshow? (
 		media-libs/libsdl
 		virtual/glu
 		virtual/opengl
 	)
-	virtual/jpeg
 	web-services? ( dev-libs/json-glib )
-	x11-libs/cairo
-	x11-libs/gdk-pixbuf:2
-	x11-libs/gtk+:2
-	x11-libs/pango"
+	webp? ( media-libs/libwebp:0= )"
 RDEPEND="${CDEPEND}
 	kde? ( kde-base/kwalletd )"
 DEPEND="${CDEPEND}
@@ -83,6 +89,8 @@
 		$(cmake-utils_use_use squish SQUISH)
 		$(cmake-utils_use_build slideshow SLIDESHOW)
 		$(cmake-utils_use_use web-services GLIBJSON)
+		$(cmake-utils_use_use webp WEBP)
+		-DUSE_LUA=OFF
 		-DCUSTOM_CFLAGS=ON
 		-DINSTALL_IOP_EXPERIMENTAL=ON
 		-DINSTALL_IOP_LEGACY=ON
@@ -93,6 +101,10 @@
 src_install() {
 	cmake-utils_src_install
 
+	for lang in ${LANGS} ; do
+		use linguas_${lang} || rm -r "${ED}"/usr/share/locale/${lang}
+	done
+
 	if use pax_kernel && use opencl ; then
 		pax-mark Cm "${ED}"/usr/bin/${PN} || die
 		eqawarn "USE=pax_kernel is set meaning that ${PN} will be run"



1.1                  media-gfx/darktable/darktable-1.4.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-gfx/darktable/darktable-1.4.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-gfx/darktable/darktable-1.4.ebuild?rev=1.1&content-type=text/plain

Index: darktable-1.4.ebuild
===================================================================
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-gfx/darktable/darktable-1.4.ebuild,v 1.1 2014/01/21 20:35:00 maekke Exp $

EAPI=5

inherit cmake-utils toolchain-funcs gnome2-utils fdo-mime pax-utils eutils

DESCRIPTION="A virtual lighttable and darkroom for photographers"
HOMEPAGE="http://www.darktable.org/"
SRC_URI="mirror://sourceforge/${PN}/${P}.tar.xz
	doc? ( mirror://sourceforge/${PN}/${PV}/${PN}-usermanual.pdf -> ${PN}-usermanual-${PV}.pdf )"

LICENSE="GPL-3 CC-BY-3.0"
SLOT="0"
KEYWORDS="~amd64 ~x86"
LANGS=" cs da de el es fr it ja nl pl pt_BR pt_PT ru sq sv uk"
# TODO add lua once dev-lang/lua-5.2 is unmasked
IUSE="colord doc flickr geo gnome-keyring gphoto2 graphicsmagick jpeg2k kde
nls opencl openmp pax_kernel +rawspeed +slideshow +squish web-services webp
${LANGS// / linguas_}"

CDEPEND="
	dev-db/sqlite:3
	>=dev-libs/glib-2.28:2
	dev-libs/libxml2:2
	gnome-base/librsvg:2
	media-gfx/exiv2:0=[xmp]
	media-libs/lcms:2
	>=media-libs/lensfun-0.2.3
	media-libs/libpng:0=
	media-libs/openexr:0=
	media-libs/tiff:0
	net-misc/curl
	virtual/jpeg
	x11-libs/cairo
	x11-libs/gdk-pixbuf:2
	x11-libs/gtk+:2
	x11-libs/pango
	colord? ( x11-misc/colord:0= )
	flickr? ( media-libs/flickcurl )
	geo? ( net-libs/libsoup:2.4 )
	gnome-keyring? ( gnome-base/gnome-keyring )
	gphoto2? ( media-libs/libgphoto2:= )
	graphicsmagick? ( media-gfx/graphicsmagick )
	jpeg2k? ( media-libs/openjpeg:0 )
	opencl? ( virtual/opencl )
	slideshow? (
		media-libs/libsdl
		virtual/glu
		virtual/opengl
	)
	web-services? ( dev-libs/json-glib )
	webp? ( media-libs/libwebp:0= )"
RDEPEND="${CDEPEND}
	kde? ( kde-base/kwalletd )"
DEPEND="${CDEPEND}
	virtual/pkgconfig
	nls? ( sys-devel/gettext )"

pkg_pretend() {
	if use openmp ; then
		tc-has-openmp || die "Please switch to an openmp compatible compiler"
	fi
}

src_prepare() {
	sed -e "s:\(/share/doc/\)darktable:\1${PF}:" \
		-e "s:LICENSE::" \
		-i doc/CMakeLists.txt || die

	epatch_user
}

src_configure() {
	local mycmakeargs=(
		$(cmake-utils_use_use colord COLORD)
		$(cmake-utils_use_use flickr FLICKR)
		$(cmake-utils_use_use geo GEO)
		$(cmake-utils_use_use gnome-keyring GNOME_KEYRING)
		$(cmake-utils_use_use gphoto2 CAMERA_SUPPORT)
		$(cmake-utils_use_use graphicsmagick GRAPHICSMAGICK)
		$(cmake-utils_use_use jpeg2k OPENJPEG)
		$(cmake-utils_use_use nls NLS)
		$(cmake-utils_use_use opencl OPENCL)
		$(cmake-utils_use_use openmp OPENMP)
		$(cmake-utils_use !rawspeed DONT_USE_RAWSPEED)
		$(cmake-utils_use_use squish SQUISH)
		$(cmake-utils_use_build slideshow SLIDESHOW)
		$(cmake-utils_use_use web-services GLIBJSON)
		$(cmake-utils_use_use webp WEBP)
		-DUSE_LUA=OFF
		-DCUSTOM_CFLAGS=ON
		-DINSTALL_IOP_EXPERIMENTAL=ON
		-DINSTALL_IOP_LEGACY=ON
	)
	cmake-utils_src_configure
}

src_install() {
	cmake-utils_src_install
	use doc && dodoc "${DISTDIR}"/${PN}-usermanual-${PV}.pdf

	for lang in ${LANGS} ; do
		use linguas_${lang} || rm -r "${ED}"/usr/share/locale/${lang}
	done

	if use pax_kernel && use opencl ; then
		pax-mark Cm "${ED}"/usr/bin/${PN} || die
		eqawarn "USE=pax_kernel is set meaning that ${PN} will be run"
		eqawarn "under a PaX enabled kernel. To do so, the ${PN} binary"
		eqawarn "must be modified and this *may* lead to breakage! If"
		eqawarn "you suspect that ${PN} is broken by this modification,"
		eqawarn "please open a bug."
	fi
}

pkg_preinst() {
	gnome2_icon_savelist
}

pkg_postinst() {
	gnome2_icon_cache_update
	fdo-mime_desktop_database_update
}

pkg_postrm() {
	gnome2_icon_cache_update
	fdo-mime_desktop_database_update
}