[gentoo-commits] gentoo-x86 commit in kde-base/kde-l10n: ChangeLog kde-l10n-4.4.1.ebuild

[Theo Chatzimichos (tampakrap)]

tampakrap    10/03/02 16:28:57

  Modified:             ChangeLog
  Added:                kde-l10n-4.4.1.ebuild
  Log:
  Version bump KDE 4.4.1
  (Portage version: 2.2_rc63/cvs/Linux x86_64, RepoMan options: --force)

Revision  Changes    Path
1.56                 kde-base/kde-l10n/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/kde-base/kde-l10n/ChangeLog?rev=1.56&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/kde-base/kde-l10n/ChangeLog?rev=1.56&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/kde-base/kde-l10n/ChangeLog?r1=1.55&r2=1.56

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/kde-base/kde-l10n/ChangeLog,v
retrieving revision 1.55
retrieving revision 1.56
diff -u -r1.55 -r1.56
--- ChangeLog	20 Feb 2010 10:30:55 -0000	1.55
+++ ChangeLog	2 Mar 2010 16:28:57 -0000	1.56
@@ -1,6 +1,12 @@
 # ChangeLog for kde-base/kde-l10n
 # Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/kde-base/kde-l10n/ChangeLog,v 1.55 2010/02/20 10:30:55 ssuominen Exp $
+# $Header: /var/cvsroot/gentoo-x86/kde-base/kde-l10n/ChangeLog,v 1.56 2010/03/02 16:28:57 tampakrap Exp $
+
+*kde-l10n-4.4.1 (02 Mar 2010)
+
+  02 Mar 2010; Theo Chatzimichos <tampakrap@g.o>
+  +kde-l10n-4.4.1.ebuild:
+  Version bump
 
   20 Feb 2010; Samuli Suominen <ssuominen@g.o> kde-l10n-4.3.5.ebuild:
   amd64/x86 stable wrt #300393



1.1                  kde-base/kde-l10n/kde-l10n-4.4.1.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/kde-base/kde-l10n/kde-l10n-4.4.1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/kde-base/kde-l10n/kde-l10n-4.4.1.ebuild?rev=1.1&content-type=text/plain

Index: kde-l10n-4.4.1.ebuild
===================================================================
# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/kde-base/kde-l10n/kde-l10n-4.4.1.ebuild,v 1.1 2010/03/02 16:28:57 tampakrap Exp $

EAPI="2"

inherit kde4-base

DESCRIPTION="KDE internationalization package"
HOMEPAGE="http://www.kde.org/"
LICENSE="GPL-2"

DEPEND="
	sys-devel/gettext
"
RDEPEND=""

KEYWORDS="~alpha ~amd64 ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~amd64-linux ~x86-linux"
IUSE="+handbook"

MY_LANGS="ar bg ca ca@valencia cs csb da de el en_GB eo es et eu
		fi fr fy ga gl gu he hi hr hu id is it ja kk km kn ko lt lv
		mai mk ml nb nds nl nn pa pl pt pt_BR ro ru si sk sl sr sv tg
		tr uk wa zh_CN zh_TW"

URI_BASE="${SRC_URI/-${PV}.tar.bz2/}"
SRC_URI=""

for MY_LANG in ${MY_LANGS} ; do
	IUSE="${IUSE} linguas_${MY_LANG}"
	SRC_URI="${SRC_URI} linguas_${MY_LANG}? ( ${URI_BASE}/${PN}-${MY_LANG}-${PV}.tar.bz2 )"
done

S="${WORKDIR}"

src_unpack() {
	local LNG DIR
	if [[ -z ${A} ]]; then
		elog
		elog "You either have the LINGUAS variable unset, or it only"
		elog "contains languages not supported by ${P}."
		elog "You won't have any additional language support."
		elog
		elog "${P} supports these language codes:"
		elog "${MY_LANGS}"
		elog
	fi

	# For EAPI >= 3, or if not using .tar.xz archives:
	[[ -n ${A} ]] && unpack ${A}
	cd "${S}"

	# add all linguas to cmake
	if [[ -n ${A} ]]; then
		for LNG in ${LINGUAS}; do
			DIR="${PN}-${LNG}-${PV}"
			if [[ -d "${DIR}" ]] ; then
				echo "add_subdirectory( ${DIR} )" >> "${S}"/CMakeLists.txt
			fi
		done
	fi
}

src_configure() {
	mycmakeargs="${mycmakeargs}
		$(cmake-utils_use_build handbook docs)"
	[[ -n ${A} ]] && kde4-base_src_configure
}

src_compile() {
	[[ -n ${A} ]] && kde4-base_src_compile
}

src_install() {
	[[ -n ${A} ]] && kde4-base_src_install
}