[gentoo-commits] gentoo-x86 commit in net-wireless/aircrack-ng: ChangeLog aircrack-ng-1.0_rc3.ebuild

[Patrick Lauer (patrick)]

patrick     09/03/29 12:15:36

  Modified:             ChangeLog
  Added:                aircrack-ng-1.0_rc3.ebuild
  Log:
  Bump to 1.0_rc3.
  (Portage version: 2.2_rc28/cvs/Linux x86_64)

Revision  Changes    Path
1.41                 net-wireless/aircrack-ng/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-wireless/aircrack-ng/ChangeLog?rev=1.41&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-wireless/aircrack-ng/ChangeLog?rev=1.41&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-wireless/aircrack-ng/ChangeLog?r1=1.40&r2=1.41

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-wireless/aircrack-ng/ChangeLog,v
retrieving revision 1.40
retrieving revision 1.41
diff -u -r1.40 -r1.41
--- ChangeLog	19 Mar 2009 17:14:23 -0000	1.40
+++ ChangeLog	29 Mar 2009 12:15:36 -0000	1.41
@@ -1,6 +1,12 @@
 # ChangeLog for net-wireless/aircrack-ng
 # Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-wireless/aircrack-ng/ChangeLog,v 1.40 2009/03/19 17:14:23 josejx Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-wireless/aircrack-ng/ChangeLog,v 1.41 2009/03/29 12:15:36 patrick Exp $
+
+*aircrack-ng-1.0_rc3 (29 Mar 2009)
+
+  29 Mar 2009; Patrick Lauer <patrick@g.o>
+  +aircrack-ng-1.0_rc3.ebuild:
+  Bump to 1.0_rc3.
 
   19 Mar 2009; Joseph Jezak <josejx@g.o>
   aircrack-ng-1.0_rc2-r1.ebuild:



1.1                  net-wireless/aircrack-ng/aircrack-ng-1.0_rc3.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-wireless/aircrack-ng/aircrack-ng-1.0_rc3.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-wireless/aircrack-ng/aircrack-ng-1.0_rc3.ebuild?rev=1.1&content-type=text/plain

Index: aircrack-ng-1.0_rc3.ebuild
===================================================================
# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-wireless/aircrack-ng/aircrack-ng-1.0_rc3.ebuild,v 1.1 2009/03/29 12:15:36 patrick Exp $

EAPI=2
inherit versionator eutils toolchain-funcs

MY_PV=$(replace_version_separator 2 '-')

DESCRIPTION="WLAN tools for breaking 802.11 WEP/WPA keys"
HOMEPAGE="http://www.aircrack-ng.org"
SRC_URI="http://download.aircrack-ng.org/${PN}-${MY_PV}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~arm ~ppc ~x86"
IUSE="+sqlite kernel_linux kernel_FreeBSD"

DEPEND="dev-libs/openssl
	sqlite? ( >=dev-db/sqlite-3.4 )"
RDEPEND="${DEPEND}
	kernel_linux? ( net-wireless/iw )"

S="${WORKDIR}/${PN}-${MY_PV}"

have_sqlite() {
	use sqlite && echo "true" || echo "false"
}

src_prepare() {
	if use kernel_FreeBSD ; then
		epatch "${FILESDIR}/${P}-freebsd.patch"
		sed -i -e "s:^\(SCRIPTS.*\)airmon-ng:\1:g" Makefile
		sed -i -e "s:airmon-ng.1::g" manpages/Makefile
	fi
}

src_compile() {
	emake CC="$(tc-getCC)" LD="$(tc-getLD)" sqlite=$(have_sqlite) || die "emake failed"
}

src_install() {
	emake \
		prefix="/usr" \
		mandir="/usr/share/man/man1" \
		DESTDIR="${D}" \
		sqlite=$(have_sqlite) \
		install \
		|| die "emake install failed"

	dodoc AUTHORS ChangeLog README
}

pkg_postinst() {
	# Message is (c) FreeBSD
	# http://www.freebsd.org/cgi/cvsweb.cgi/ports/net-mgmt/aircrack-ng/files/pkg-message.in?rev=1.5
	if use kernel_FreeBSD ; then
		einfo "Contrary to Linux, it is not necessary to use airmon-ng to enable the monitor"
		einfo "mode of your wireless card.  So do not care about what the manpages say about"
		einfo "airmon-ng, airodump-ng sets monitor mode automatically."
		echo
		einfo "To return from monitor mode, issue the following command:"
		einfo "    ifconfig \${INTERFACE} -mediaopt monitor"
		einfo
		einfo "For aireplay-ng you need FreeBSD >= 7.0."
	fi
}