[gentoo-commits] repo/gentoo:master commit in: dev-ruby/duktape-rb/

[Hans de Graaff]

commit:     8ddeec216967311f14ef3cedc5920b64f6df2799
Author:     Hans de Graaff <graaff <AT> gentoo <DOT> org>
AuthorDate: Sun Oct 31 05:11:56 2021 +0000
Commit:     Hans de Graaff <graaff <AT> gentoo <DOT> org>
CommitDate: Sun Oct 31 05:57:10 2021 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=8ddeec21

dev-ruby/duktape-rb: fix extension install

Package-Manager: Portage-3.0.28, Repoman-3.0.3
Signed-off-by: Hans de Graaff <graaff <AT> gentoo.org>

 dev-ruby/duktape-rb/duktape-rb-2.3.0.0-r3.ebuild | 49 ++++++++++++++++++++++++
 1 file changed, 49 insertions(+)

diff --git a/dev-ruby/duktape-rb/duktape-rb-2.3.0.0-r3.ebuild b/dev-ruby/duktape-rb/duktape-rb-2.3.0.0-r3.ebuild
new file mode 100644
index 00000000000..e3a343028a3
--- /dev/null
+++ b/dev-ruby/duktape-rb/duktape-rb-2.3.0.0-r3.ebuild
@@ -0,0 +1,49 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+USE_RUBY="ruby26 ruby27"
+
+RUBY_FAKEGEM_GEMSPEC="duktape.gemspec"
+RUBY_FAKEGEM_NAME="duktape"
+
+RUBY_FAKEGEM_EXTENSIONS=(ext/duktape/extconf.rb)
+
+inherit ruby-fakegem
+
+MY_PN=${PN/-/\.}
+MY_P=${MY_PN}-${PV}
+
+DESCRIPTION="Ruby bindings to the Duktape JavaScript interpeter"
+HOMEPAGE="https://github.com/judofyr/duktape.rb"
+SRC_URI="https://github.com/judofyr/${MY_PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~riscv"
+
+COMMON_DEPEND="dev-lang/duktape:="
+DEPEND+="${COMMON_DEPEND}"
+RDEPEND+="${COMMON_DEPEND}"
+
+ruby_add_bdepend "
+	dev-ruby/pkg-config
+	dev-ruby/rake-compiler
+	dev-ruby/sdoc
+"
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-2.3.0.0_duktape-2.5.0-tests.patch
+	"${FILESDIR}"/${PN}-2.3.0.0_use-system-duktape.patch
+)
+
+RUBY_S=${MY_P}
+
+all_ruby_prepare() {
+	rm ext/duktape/duktape.{c,h} ext/duktape/duk_config.h || die "Failed to remove bundled duktape"
+}
+
+each_ruby_test() {
+	${RUBY} test/test_duktape.rb || die
+}