Get Gentoo!
gentoo.org sites
gentoo.org Wiki Bugs Forums Packages
Planet Archives Sources
Infra Status

Gentoo Archives: gentoo-commits

From: "Ben de Groot (yngwin)" <yngwin@g.o>
To: gentoo-commits@l.g.o
Subject: [gentoo-commits] gentoo-x86 commit in x11-libs/qt-gui: qt-gui-4.4.2-r2.ebuild ChangeLog
Date: Fri, 30 Jan 2009 22:15:35
Message-Id: E1LT1e9-000485-3o@stork.gentoo.org
1 yngwin 09/01/30 22:15:33
2
3 Modified: ChangeLog
4 Added: qt-gui-4.4.2-r2.ebuild
5 Log:
6 Add bugfix patches from qt-copy
7 (Portage version: 2.2_rc23/cvs/Linux i686)
8
9 Revision Changes Path
10 1.22 x11-libs/qt-gui/ChangeLog
11
12 file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/x11-libs/qt-gui/ChangeLog?rev=1.22&view=markup
13 plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/x11-libs/qt-gui/ChangeLog?rev=1.22&content-type=text/plain
14 diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/x11-libs/qt-gui/ChangeLog?r1=1.21&r2=1.22
15
16 Index: ChangeLog
17 ===================================================================
18 RCS file: /var/cvsroot/gentoo-x86/x11-libs/qt-gui/ChangeLog,v
19 retrieving revision 1.21
20 retrieving revision 1.22
21 diff -u -r1.21 -r1.22
22 --- ChangeLog 29 Jan 2009 18:51:06 -0000 1.21
23 +++ ChangeLog 30 Jan 2009 22:15:33 -0000 1.22
24 @@ -1,6 +1,16 @@
25 # ChangeLog for x11-libs/qt-gui
26 # Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
27 -# $Header: /var/cvsroot/gentoo-x86/x11-libs/qt-gui/ChangeLog,v 1.21 2009/01/29 18:51:06 aballier Exp $
28 +# $Header: /var/cvsroot/gentoo-x86/x11-libs/qt-gui/ChangeLog,v 1.22 2009/01/30 22:15:33 yngwin Exp $
29 +
30 +*qt-gui-4.4.2-r2 (30 Jan 2009)
31 +
32 + 30 Jan 2009; Ben de Groot <yngwin@g.o>
33 + +files/0248-fix-qwidget-scroll-slowness.diff,
34 + +files/0256-fix-recursive-backingstore-sync-crash.diff,
35 + +files/0262-fix-treeview-animation-crash.diff,
36 + +files/0263-fix-fontconfig-handling.diff,
37 + +files/0265-fix-formlayoutcrash.diff, +qt-gui-4.4.2-r2.ebuild:
38 + Add bugfix patches from KDE's qt-copy
39
40 29 Jan 2009; Alexis Ballier <aballier@g.o> qt-gui-4.4.2-r1.ebuild:
41 keyword ~x86-fbsd
42
43
44
45 1.1 x11-libs/qt-gui/qt-gui-4.4.2-r2.ebuild
46
47 file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/x11-libs/qt-gui/qt-gui-4.4.2-r2.ebuild?rev=1.1&view=markup
48 plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/x11-libs/qt-gui/qt-gui-4.4.2-r2.ebuild?rev=1.1&content-type=text/plain
49
50 Index: qt-gui-4.4.2-r2.ebuild
51 ===================================================================
52 # Copyright 1999-2009 Gentoo Foundation
53 # Distributed under the terms of the GNU General Public License v2
54 # $Header: /var/cvsroot/gentoo-x86/x11-libs/qt-gui/qt-gui-4.4.2-r2.ebuild,v 1.1 2009/01/30 22:15:33 yngwin Exp $
55
56 EAPI="1"
57 inherit eutils qt4-build
58
59 DESCRIPTION="The GUI module for the Qt toolkit"
60 HOMEPAGE="http://www.trolltech.com/"
61
62 LICENSE="|| ( GPL-3 GPL-2 )"
63 SLOT="4"
64 KEYWORDS="~alpha ~amd64 ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd"
65
66 IUSE_INPUT_DEVICES="input_devices_wacom"
67 IUSE="+accessibility cups +dbus debug +glib mng nas nis tiff +qt3support xinerama ${IUSE_INPUT_DEVICES}"
68
69 RDEPEND="media-libs/fontconfig
70 >=media-libs/freetype-2
71 media-libs/jpeg
72 media-libs/libpng
73 sys-libs/zlib
74 x11-libs/libXrandr
75 x11-libs/libXcursor
76 x11-libs/libXfont
77 x11-libs/libSM
78 ~x11-libs/qt-core-${PV}
79 ~x11-libs/qt-script-${PV}
80 cups? ( net-print/cups )
81 dbus? ( ~x11-libs/qt-dbus-${PV} )
82 input_devices_wacom? ( x11-libs/libXi x11-drivers/linuxwacom )
83 mng? ( >=media-libs/libmng-1.0.9 )
84 nas? ( >=media-libs/nas-1.5 )
85 tiff? ( media-libs/tiff )
86 xinerama? ( x11-libs/libXinerama )"
87 DEPEND="${RDEPEND}
88 xinerama? ( x11-proto/xineramaproto )
89 x11-proto/xextproto
90 x11-proto/inputproto"
91 PDEPEND="qt3support? ( ~x11-libs/qt-qt3support-${PV} )"
92
93 QT4_TARGET_DIRECTORIES="
94 src/gui
95 tools/designer
96 tools/linguist
97 src/plugins/imageformats/gif
98 src/plugins/imageformats/ico
99 src/plugins/imageformats/jpeg"
100 QT4_EXTRACT_DIRECTORIES="
101 src/tools/rcc/
102 tools/shared/"
103
104 pkg_setup() {
105 use glib && QT4_BUILT_WITH_USE_CHECK="${QT4_BUILT_WITH_USE_CHECK}
106 ~x11-libs/qt-core-${PV} glib"
107 use qt3support && QT4_BUILT_WITH_USE_CHECK="${QT4_BUILT_WITH_USE_CHECK}
108 ~x11-libs/qt-core-${PV} qt3support"
109
110 qt4-build_pkg_setup
111 }
112
113 src_unpack() {
114 use dbus && QT4_TARGET_DIRECTORIES="${QT4_TARGET_DIRECTORIES} tools/qdbus/qdbusviewer"
115 use mng && QT4_TARGET_DIRECTORIES="${QT4_TARGET_DIRECTORIES} src/plugins/imageformats/mng"
116 use tiff && QT4_TARGET_DIRECTORIES="${QT4_TARGET_DIRECTORIES} src/plugins/imageformats/tiff"
117 QT4_EXTRACT_DIRECTORIES="${QT4_TARGET_DIRECTORIES}
118 ${QT4_EXTRACT_DIRECTORIES}"
119
120 qt4-build_src_unpack
121
122 # Apply bugfix patches from qt-copy
123 epatch "${FILESDIR}"/0248-fix-qwidget-scroll-slowness.diff
124 epatch "${FILESDIR}"/0254-fix-qgraphicsproxywidget-deletion-crash.diff
125 epatch "${FILESDIR}"/0256-fix-recursive-backingstore-sync-crash.diff
126 epatch "${FILESDIR}"/0262-fix-treeview-animation-crash.diff
127 epatch "${FILESDIR}"/0263-fix-fontconfig-handling.diff
128 epatch "${FILESDIR}"/0265-fix-formlayoutcrash.diff
129
130 # Don't build plugins this go around, because they depend on qt3support lib
131 sed -i -e "s:CONFIG(shared:# &:g" "${S}"/tools/designer/src/src.pro
132 }
133
134 src_compile() {
135 export PATH="${S}/bin:${PATH}"
136 export LD_LIBRARY_PATH="${S}/lib:${LD_LIBRARY_PATH}"
137
138 local myconf
139 myconf="$(qt_use accessibility)
140 $(qt_use cups)
141 $(qt_use glib)
142 $(qt_use input_devices_wacom tablet)
143 $(qt_use mng libmng system)
144 $(qt_use nis)
145 $(qt_use tiff libtiff system)
146 $(qt_use dbus qdbus)
147 $(qt_use qt3support)
148 $(qt_use xinerama)"
149
150 use nas && myconf="${myconf} -system-nas-sound"
151
152 myconf="${myconf} -qt-gif -system-libpng -system-libjpeg
153 -no-sql-mysql -no-sql-psql -no-sql-ibase -no-sql-sqlite -no-sql-sqlite2 -no-sql-odbc
154 -xrender -xrandr -xkb -xshape -sm -no-svg"
155
156 # Explictly don't compile these packages.
157 # Emerge "qt-webkit", "qt-phonon", etc for their functionality.
158 myconf="${myconf} -no-webkit -no-phonon -no-dbus -no-opengl"
159
160 qt4-build_src_compile
161 }
162
163 src_install() {
164 QCONFIG_ADD="x11sm xshape xcursor xfixes xrandr xrender xkb fontconfig
165 $(use input_devices_wacom && echo tablet) $(usev accessibility)
166 $(usev xinerama) $(usev cups) $(usev nas) gif png system-png system-jpeg
167 $(use mng && echo system-mng) $(use tiff && echo system-tiff)"
168 QCONFIG_REMOVE="no-gif no-png"
169 QCONFIG_DEFINE="$(use accessibility && echo QT_ACCESSIBILITY)
170 $(use cups && echo QT_CUPS) QT_FONTCONFIG QT_IMAGEFORMAT_JPEG
171 $(use mng && echo QT_IMAGEFORMAT_MNG) $(use nas && echo QT_NAS)
172 $(use nis && echo QT_NIS) QT_IMAGEFORMAT_PNG QT_SESSIONMANAGER QT_SHAPE
173 $(use tiff && echo QT_IMAGEFORMAT_TIFF) QT_XCURSOR
174 $(use xinerama && echo QT_XINERAMA) QT_XFIXES QT_XKB QT_XRANDR QT_XRENDER"
175 qt4-build_src_install
176
177 # install correct designer and linguist icons, bug 241208
178 dodir /usr/share/pixmaps/ || die "dodir failed"
179 insinto /usr/share/pixmaps/ || die "insinto failed"
180 doins tools/linguist/linguist/images/icons/linguist-128-32.png \
181 tools/designer/src/designer/images/designer.png || die "doins failed"
182 # Note: absolute image path required here!
183 make_desktop_entry /usr/bin/linguist Linguist \
184 /usr/share/pixmaps/linguist-128-32.png 'Qt;Development;GUIDesigner' \
185 || die "make_desktop_entry failed"
186 make_desktop_entry /usr/bin/designer Designer \
187 /usr/share/pixmaps/designer.png 'Qt;Development;GUIDesigner' \
188 || die "make_desktop_entry failed"
189 }
Report Message
Find on MARC Find on Google Groups