[gentoo-commits] repo/gentoo:master commit in: x11-misc/gtkdialog/

[Jeroen Roovers]

commit:     1af51fa380eec5b1e845c26eb9475ca0b73bb9dd
Author:     Jeroen Roovers <jer <AT> gentoo <DOT> org>
AuthorDate: Sat Jul 28 12:07:59 2018 +0000
Commit:     Jeroen Roovers <jer <AT> gentoo <DOT> org>
CommitDate: Sat Jul 28 12:13:15 2018 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=1af51fa3

x11-misc/gtkdialog: Add live ebuild.

Package-Manager: Portage-2.3.43, Repoman-2.3.10

 x11-misc/gtkdialog/gtkdialog-99999.ebuild | 53 +++++++++++++++++++++++++++++++
 x11-misc/gtkdialog/metadata.xml           |  1 +
 2 files changed, 54 insertions(+)

diff --git a/x11-misc/gtkdialog/gtkdialog-99999.ebuild b/x11-misc/gtkdialog/gtkdialog-99999.ebuild
new file mode 100644
index 00000000000..b9843533462
--- /dev/null
+++ b/x11-misc/gtkdialog/gtkdialog-99999.ebuild
@@ -0,0 +1,53 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+inherit autotools git-r3
+
+DESCRIPTION="A small utility for fast and easy GUI building"
+HOMEPAGE="https://github.com/oshazard/gtkdialog"
+EGIT_REPO_URI="${HOMEPAGE}"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS=""
+IUSE="gtk3"
+
+RDEPEND="
+	!gtk3? (
+		x11-libs/gtk+:2
+		x11-libs/vte:0=
+	)
+	gtk3? (
+		x11-libs/gtk+:3
+		x11-libs/vte:2.91=
+	)
+"
+DEPEND="
+	${RDEPEND}
+	sys-apps/texinfo
+	sys-devel/flex
+	virtual/pkgconfig
+	virtual/yacc
+"
+
+src_prepare() {
+	default
+	eautoreconf
+}
+
+src_configure() {
+	econf \
+		$(use_enable gtk3)
+}
+
+src_compile() {
+	emake -C doc stamp-vti
+	default
+}
+
+src_install() {
+	# Stop make install from running gtk-update-icon-cache
+	emake DESTDIR="${D}" UPDATE_ICON_CACHE=true install
+	einstalldocs
+}

diff --git a/x11-misc/gtkdialog/metadata.xml b/x11-misc/gtkdialog/metadata.xml
index 635a9b6bda8..2de333f9467 100644
--- a/x11-misc/gtkdialog/metadata.xml
+++ b/x11-misc/gtkdialog/metadata.xml
@@ -19,6 +19,7 @@ provided.
 </upstream>
 <use>
 <flag name="glade">Enable support for <pkg>gnome-base/libglade</pkg></flag>
+<flag name="gtk3">Build with GTK+3 instead of GTK+2</flag>
 <flag name="vte">Enable support for <pkg>x11-libs/vte</pkg></flag>
 </use>
 </pkgmetadata>