[gentoo-commits] gentoo-x86 commit in net-misc/libreswan: libreswan-3.9.ebuild libreswan-9999.ebuild ChangeLog

[Mike Gilbert (floppym)]

floppym     14/07/09 21:30:39

  Modified:             libreswan-9999.ebuild ChangeLog
  Added:                libreswan-3.9.ebuild
  Log:
  Version bump.
  
  (Portage version: 2.2.10/cvs/Linux x86_64, signed Manifest commit with key 0BBEEA1FEA4843A4)

Revision  Changes    Path
1.6                  net-misc/libreswan/libreswan-9999.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/libreswan/libreswan-9999.ebuild?rev=1.6&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/libreswan/libreswan-9999.ebuild?rev=1.6&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/libreswan/libreswan-9999.ebuild?r1=1.5&r2=1.6

Index: libreswan-9999.ebuild
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-misc/libreswan/libreswan-9999.ebuild,v
retrieving revision 1.5
retrieving revision 1.6
diff -u -r1.5 -r1.6
--- libreswan-9999.ebuild	17 Jan 2014 03:42:05 -0000	1.5
+++ libreswan-9999.ebuild	9 Jul 2014 21:30:39 -0000	1.6
@@ -1,6 +1,6 @@
 # Copyright 1999-2014 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/net-misc/libreswan/libreswan-9999.ebuild,v 1.5 2014/01/17 03:42:05 floppym Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-misc/libreswan/libreswan-9999.ebuild,v 1.6 2014/07/09 21:30:39 floppym Exp $
 
 EAPI=5
 
@@ -84,7 +84,7 @@
 
 	systemd_dounit "${FILESDIR}/ipsec.service"
 
-	dodoc BUGS CHANGES README
+	dodoc CHANGES README
 	dodoc -r docs
 
 	find "${D}" -type d -empty -delete || die



1.9                  net-misc/libreswan/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/libreswan/ChangeLog?rev=1.9&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/libreswan/ChangeLog?rev=1.9&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/libreswan/ChangeLog?r1=1.8&r2=1.9

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-misc/libreswan/ChangeLog,v
retrieving revision 1.8
retrieving revision 1.9
diff -u -r1.8 -r1.9
--- ChangeLog	4 Mar 2014 20:13:34 -0000	1.8
+++ ChangeLog	9 Jul 2014 21:30:39 -0000	1.9
@@ -1,6 +1,12 @@
 # ChangeLog for net-misc/libreswan
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-misc/libreswan/ChangeLog,v 1.8 2014/03/04 20:13:34 ago Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-misc/libreswan/ChangeLog,v 1.9 2014/07/09 21:30:39 floppym Exp $
+
+*libreswan-3.9 (09 Jul 2014)
+
+  09 Jul 2014; Mike Gilbert <floppym@g.o> +libreswan-3.9.ebuild,
+  libreswan-9999.ebuild:
+  Version bump.
 
   04 Mar 2014; Agostino Sarubbo <ago@g.o> libreswan-3.8.ebuild:
   Stable for x86, wrt bug #501914



1.1                  net-misc/libreswan/libreswan-3.9.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/libreswan/libreswan-3.9.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/libreswan/libreswan-3.9.ebuild?rev=1.1&content-type=text/plain

Index: libreswan-3.9.ebuild
===================================================================
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-misc/libreswan/libreswan-3.9.ebuild,v 1.1 2014/07/09 21:30:39 floppym Exp $

EAPI=5

inherit eutils systemd toolchain-funcs

if [[ ${PV} != 9999 ]]; then
	SRC_URI="https://download.libreswan.org/${P}.tar.gz"
	KEYWORDS="~amd64 ~ppc ~x86"
else
	inherit git-r3
	EGIT_REPO_URI="https://github.com/libreswan/libreswan.git"
fi

DESCRIPTION="IPsec implementation for Linux, fork of Openswan"
HOMEPAGE="https://libreswan.org/"

LICENSE="GPL-2 BSD-4 RSA DES"
SLOT="0"
IUSE="caps curl dnssec ldap pam"

COMMON_DEPEND="
	dev-libs/gmp
	dev-libs/nspr
	caps? ( sys-libs/libcap-ng )
	curl? ( net-misc/curl )
	dnssec? ( net-dns/unbound net-libs/ldns )
	ldap? ( net-nds/openldap )
	pam? ( sys-libs/pam )
"
DEPEND="${COMMON_DEPEND}
	app-text/docbook-xml-dtd:4.1.2
	app-text/xmlto
	dev-libs/nss
	sys-devel/bison
	sys-devel/flex
	virtual/pkgconfig
"
RDEPEND="${COMMON_DEPEND}
	dev-libs/nss[utils(+)]
	sys-apps/iproute2
	!net-misc/openswan
	!net-misc/strongswan
"

src_prepare() {
	epatch_user
}

usetf() {
	usex "$1" true false
}

src_configure() {
	tc-export AR CC
	export INC_USRLOCAL=/usr
	export INC_MANDIR=share/man
	export FINALEXAMPLECONFDIR=/usr/share/doc/${PF}
	export FINALDOCDIR=/usr/share/doc/${PF}/html
	export INITSYSTEM=openrc
	export INC_RCDIRS=
	export INC_RCDEFAULT=/etc/init.d
	export USERCOMPILE=
	export USERLINK=
	export USE_DNSSEC=$(usetf dnssec)
	export USE_LIBCAP_NG=$(usetf caps)
	export USE_LIBCURL=$(usetf curl)
	export USE_LDAP=$(usetf ldap)
	export USE_XAUTHPAM=$(usetf pam)
}

src_compile() {
	emake programs
}

src_install() {
	emake DESTDIR="${D}" install
	sed -i -e '1s:python$:python2:' "${D}"/usr/libexec/ipsec/verify || die

	echo "include /etc/ipsec.d/*.secrets" > "${D}"/etc/ipsec.secrets
	fperms 0600 /etc/ipsec.secrets

	systemd_dounit "${FILESDIR}/ipsec.service"

	dodoc CHANGES README
	dodoc -r docs

	find "${D}" -type d -empty -delete || die
}

pkg_postinst() {
	local IPSEC_CONFDIR=${ROOT%/}/etc/ipsec.d
	if [[ ! -f ${IPSEC_CONFDIR}/cert8.db ]]; then
		ebegin "Setting up NSS database in ${IPSEC_CONFDIR}"
		certutil -N -d "${IPSEC_CONFDIR}" -f <(echo)
		eend $?
	fi
}