[gentoo-commits] gentoo-x86 commit in dev-util/geany: ChangeLog geany-1.23.1.ebuild

[Lars Wendler (polynomial-c)]

polynomial-c    13/05/28 15:09:07

  Modified:             ChangeLog
  Added:                geany-1.23.1.ebuild
  Log:
  Version bump (bug #471494)
  
  (Portage version: 2.2.0_alpha177/cvs/Linux x86_64, signed Manifest commit with key 0x981CA6FC)

Revision  Changes    Path
1.68                 dev-util/geany/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-util/geany/ChangeLog?rev=1.68&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-util/geany/ChangeLog?rev=1.68&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-util/geany/ChangeLog?r1=1.67&r2=1.68

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-util/geany/ChangeLog,v
retrieving revision 1.67
retrieving revision 1.68
diff -u -r1.67 -r1.68
--- ChangeLog	11 Mar 2013 12:57:48 -0000	1.67
+++ ChangeLog	28 May 2013 15:09:06 -0000	1.68
@@ -1,6 +1,11 @@
 # ChangeLog for dev-util/geany
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-util/geany/ChangeLog,v 1.67 2013/03/11 12:57:48 polynomial-c Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-util/geany/ChangeLog,v 1.68 2013/05/28 15:09:06 polynomial-c Exp $
+
+*geany-1.23.1 (28 May 2013)
+
+  28 May 2013; Lars Wendler <polynomial-c@g.o> +geany-1.23.1.ebuild:
+  Version bump (bug #471494)
 
   11 Mar 2013; Lars Wendler <polynomial-c@g.o> geany-1.23.ebuild:
   Updatet list of locales.



1.1                  dev-util/geany/geany-1.23.1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-util/geany/geany-1.23.1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-util/geany/geany-1.23.1.ebuild?rev=1.1&content-type=text/plain

Index: geany-1.23.1.ebuild
===================================================================
# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-util/geany/geany-1.23.1.ebuild,v 1.1 2013/05/28 15:09:07 polynomial-c Exp $

EAPI=5
inherit eutils fdo-mime gnome2-utils

LANGS="ar ast be bg ca cs de el en_GB es et eu fa fi fr gl he hi hu id it ja kk ko lb lt mn nl nn pl pt pt_BR ro ru sk sl sr sv tr uk vi zh_CN ZH_TW"
NOSHORTLANGS="en_GB zh_CN zh_TW"

DESCRIPTION="GTK+ based fast and lightweight IDE"
HOMEPAGE="http://www.geany.org"
SRC_URI="http://download.geany.org/${P}.tar.bz2"

LICENSE="GPL-2+ HPND"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd ~amd64-linux ~x86-linux"
IUSE="+vte"

RDEPEND=">=x11-libs/gtk+-2.16:2
	>=dev-libs/glib-2.20:2
	vte? ( x11-libs/vte:0 )"
DEPEND="${RDEPEND}
	virtual/pkgconfig
	dev-util/intltool
	sys-devel/gettext"

pkg_setup() {
	strip-linguas ${LANGS}
}

src_prepare() {
	# Syntax highlighting for Portage
	sed -i -e "s:*.sh;:*.sh;*.ebuild;*.eclass;:" \
		data/filetype_extensions.conf || die
}

src_configure() {
	econf \
		--disable-dependency-tracking \
		--docdir="/usr/share/doc/${PF}" \
		$(use_enable vte)
}

src_install() {
	emake DESTDIR="${D}" DOCDIR="${ED}/usr/share/doc/${PF}" install || die
	rm -f "${ED}"/usr/share/doc/${PF}/{COPYING,GPL-2,ScintillaLicense.txt}
	prune_libtool_files --all
}

pkg_preinst() { gnome2_icon_savelist; }

pkg_postinst() {
	fdo-mime_desktop_database_update
	gnome2_icon_cache_update
}

pkg_postrm() {
	fdo-mime_desktop_database_update
	gnome2_icon_cache_update
}