[gentoo-commits] gentoo-x86 commit in net-proxy/tinyproxy: ChangeLog tinyproxy-1.8.2.ebuild

[Jeroen Roovers (jer)]

jer         11/01/25 02:03:40

  Modified:             ChangeLog
  Added:                tinyproxy-1.8.2.ebuild
  Log:
  Version bump by Christian Zuckschwerdt (bug #352617). Clean up patches.
  
  (Portage version: 2.2.0_alpha19/cvs/Linux i686)

Revision  Changes    Path
1.21                 net-proxy/tinyproxy/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-proxy/tinyproxy/ChangeLog?rev=1.21&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-proxy/tinyproxy/ChangeLog?rev=1.21&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-proxy/tinyproxy/ChangeLog?r1=1.20&r2=1.21

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-proxy/tinyproxy/ChangeLog,v
retrieving revision 1.20
retrieving revision 1.21
diff -u -r1.20 -r1.21
--- ChangeLog	4 Jun 2010 05:28:04 -0000	1.20
+++ ChangeLog	25 Jan 2011 02:03:40 -0000	1.21
@@ -1,6 +1,13 @@
 # ChangeLog for net-proxy/tinyproxy
-# Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-proxy/tinyproxy/ChangeLog,v 1.20 2010/06/04 05:28:04 jer Exp $
+# Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/net-proxy/tinyproxy/ChangeLog,v 1.21 2011/01/25 02:03:40 jer Exp $
+
+*tinyproxy-1.8.2 (25 Jan 2011)
+
+  25 Jan 2011; Jeroen Roovers <jer@g.o>
+  files/tinyproxy-1.8.1-ldflags.patch, +tinyproxy-1.8.2.ebuild,
+  files/tinyproxy-no-via.patch:
+  Version bump by Christian Zuckschwerdt (bug #352617). Clean up patches.
 
   04 Jun 2010; Jeroen Roovers <jer@g.o> tinyproxy-1.8.1-r1.ebuild:
   Invert USE=minimal logic thanks to Ben Kohler (bug #321753 again).



1.1                  net-proxy/tinyproxy/tinyproxy-1.8.2.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-proxy/tinyproxy/tinyproxy-1.8.2.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-proxy/tinyproxy/tinyproxy-1.8.2.ebuild?rev=1.1&content-type=text/plain

Index: tinyproxy-1.8.2.ebuild
===================================================================
# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-proxy/tinyproxy/tinyproxy-1.8.2.ebuild,v 1.1 2011/01/25 02:03:40 jer Exp $

EAPI="2"

inherit autotools eutils

DESCRIPTION="A lightweight HTTP/SSL proxy"
HOMEPAGE="http://www.banu.com/tinyproxy/"
SRC_URI="http://www.banu.com/pub/${PN}/1.8/${P}.tar.bz2"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~ia64 ~ppc ~sparc ~x86"
IUSE="debug +filter-proxy minimal reverse-proxy transparent-proxy
	+upstream-proxy +xtinyproxy-header"

DEPEND="!minimal? ( app-text/asciidoc )"
RDEPEND=""

pkg_setup() {
	enewgroup ${PN}
	enewuser ${PN} "" "" "" ${PN}
}

src_prepare() {
	epatch "${FILESDIR}"/${PN}-1.8.1-ldflags.patch
	use minimal && epatch "${FILESDIR}/${P}-minimal.patch"
	sed -i etc/${PN}.conf.in -e "s|nobody|${PN}|g" || die "sed failed"
	sed \
		-e "/CONFFILE/s:${PN}/::g" \
		"${FILESDIR}/${PN}.initd" \
		> "${WORKDIR}"/${PN}.initd \
		|| die "sed failed"
	eautoreconf
}

src_configure() {
	if use minimal; then
		ln -s /bin/true "${T}"/a2x
		export PATH="${T}:${PATH}"
	fi
	econf \
		--localstatedir=/var \
		$(use_enable filter-proxy filter) \
		$(use_enable reverse-proxy reverse) \
		$(use_enable transparent-proxy transparent) \
		$(use_enable upstream-proxy upstream) \
		$(use_enable xtinyproxy-header xtinyproxy) \
		$(use_enable debug)
}

src_install() {
	sed -i \
		-e 's:mkdir $(datadir)/tinyproxy:mkdir -p $(DESTDIR)$(datadir)/tinyproxy:' \
		Makefile
	emake DESTDIR="${D}" install || die "install failed"

	if ! use minimal; then
		dodoc AUTHORS ChangeLog NEWS README TODO || die "dodoc failed"
	fi

	diropts -m0775 -o ${PN} -g ${PN}
	keepdir /var/log/${PN}
	keepdir /var/run/${PN}

	newinitd "${WORKDIR}"/tinyproxy.initd tinyproxy
}

pkg_postinst() {
	einfo "For filtering domains and URLs, enable filter option in the configuration"
	einfo "file and add them to the filter file (one domain or URL per line)."
}