[gentoo-commits] gentoo-x86 commit in dev-util/pkgconfig: pkgconfig-0.28-r1.ebuild pkgconfig-9999.ebuild ChangeLog

[Samuli Suominen (ssuominen)]

ssuominen    14/03/27 06:57:57

  Modified:             pkgconfig-9999.ebuild ChangeLog
  Added:                pkgconfig-0.28-r1.ebuild
  Log:
  Build eg. i686-pc-linux-gnu-pkg-config with ABI_X86="32" to support searching from /usr/lib32 without passing anything to the environment wrt #494748 by "kramlat"
  
  (Portage version: 2.2.8-r1/cvs/Linux x86_64, signed Manifest commit with key 4868F14D)

Revision  Changes    Path
1.11                 dev-util/pkgconfig/pkgconfig-9999.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-util/pkgconfig/pkgconfig-9999.ebuild?rev=1.11&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-util/pkgconfig/pkgconfig-9999.ebuild?rev=1.11&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-util/pkgconfig/pkgconfig-9999.ebuild?r1=1.10&r2=1.11

Index: pkgconfig-9999.ebuild
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-util/pkgconfig/pkgconfig-9999.ebuild,v
retrieving revision 1.10
retrieving revision 1.11
diff -u -r1.10 -r1.11
--- pkgconfig-9999.ebuild	1 Feb 2014 16:18:05 -0000	1.10
+++ pkgconfig-9999.ebuild	27 Mar 2014 06:57:57 -0000	1.11
@@ -1,10 +1,10 @@
 # Copyright 1999-2014 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/dev-util/pkgconfig/pkgconfig-9999.ebuild,v 1.10 2014/02/01 16:18:05 grobian Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-util/pkgconfig/pkgconfig-9999.ebuild,v 1.11 2014/03/27 06:57:57 ssuominen Exp $
 
 EAPI=5
 
-inherit flag-o-matic libtool multilib
+inherit flag-o-matic libtool multilib multilib-minimal
 
 MY_P=pkg-config-${PV}
 
@@ -23,7 +23,7 @@
 SLOT="0"
 IUSE="elibc_FreeBSD elibc_glibc hardened internal-glib"
 
-RDEPEND="!internal-glib? ( >=dev-libs/glib-2.30 )
+RDEPEND="!internal-glib? ( >=dev-libs/glib-2.30[${MULTILIB_USEDEP}] )
 	!dev-util/pkgconf[pkg-config]
 	!dev-util/pkg-config-lite
 	!dev-util/pkgconfig-openbsd[pkg-config]"
@@ -43,7 +43,7 @@
 	fi
 }
 
-src_configure() {
+multilib_src_configure() {
 	local myconf
 
 	if use internal-glib; then
@@ -72,6 +72,7 @@
 
 	[[ ${PV} == *9999* ]] && myconf+=' --enable-maintainer-mode'
 
+	ECONF_SOURCE=${S} \
 	econf \
 		--docdir="${EPREFIX}"/usr/share/doc/${PF}/html \
 		--with-system-include-path="${EPREFIX}"/usr/include \
@@ -79,8 +80,8 @@
 		${myconf}
 }
 
-src_install() {
-	default
+multilib_src_install() {
+	emake DESTDIR="${D}" install
 
 	if use prefix; then
 		# Add an explicit reference to $EPREFIX to PKG_CONFIG_PATH to



1.143                dev-util/pkgconfig/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-util/pkgconfig/ChangeLog?rev=1.143&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-util/pkgconfig/ChangeLog?rev=1.143&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-util/pkgconfig/ChangeLog?r1=1.142&r2=1.143

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-util/pkgconfig/ChangeLog,v
retrieving revision 1.142
retrieving revision 1.143
diff -u -r1.142 -r1.143
--- ChangeLog	1 Feb 2014 16:18:05 -0000	1.142
+++ ChangeLog	27 Mar 2014 06:57:57 -0000	1.143
@@ -1,6 +1,14 @@
 # ChangeLog for dev-util/pkgconfig
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-util/pkgconfig/ChangeLog,v 1.142 2014/02/01 16:18:05 grobian Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-util/pkgconfig/ChangeLog,v 1.143 2014/03/27 06:57:57 ssuominen Exp $
+
+*pkgconfig-0.28-r1 (27 Mar 2014)
+
+  27 Mar 2014; Samuli Suominen <ssuominen@g.o> +pkgconfig-0.28-r1.ebuild,
+  pkgconfig-9999.ebuild:
+  Build eg. i686-pc-linux-gnu-pkg-config with ABI_X86="32" to support searching
+  from /usr/lib32 without passing anything to the environment wrt #494748 by
+  "kramlat"
 
   01 Feb 2014; Fabian Groffen <grobian@g.o> pkgconfig-0.28.ebuild,
   pkgconfig-9999.ebuild:



1.1                  dev-util/pkgconfig/pkgconfig-0.28-r1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-util/pkgconfig/pkgconfig-0.28-r1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-util/pkgconfig/pkgconfig-0.28-r1.ebuild?rev=1.1&content-type=text/plain

Index: pkgconfig-0.28-r1.ebuild
===================================================================
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-util/pkgconfig/pkgconfig-0.28-r1.ebuild,v 1.1 2014/03/27 06:57:57 ssuominen Exp $

EAPI=5

inherit flag-o-matic libtool multilib multilib-minimal

MY_P=pkg-config-${PV}

if [[ ${PV} == *9999* ]]; then
	EGIT_REPO_URI="git://anongit.freedesktop.org/pkg-config"
	inherit autotools git-2
else
	KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~ppc-aix ~amd64-fbsd ~sparc-fbsd ~x86-fbsd ~x64-freebsd ~x86-freebsd ~hppa-hpux ~ia64-hpux ~x86-interix ~amd64-linux ~arm-linux ~ia64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~m68k-mint ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
	SRC_URI="http://pkgconfig.freedesktop.org/releases/${MY_P}.tar.gz"
fi

DESCRIPTION="Package config system that manages compile/link flags"
HOMEPAGE="http://pkgconfig.freedesktop.org/wiki/"

LICENSE="GPL-2"
SLOT="0"
IUSE="elibc_FreeBSD elibc_glibc hardened internal-glib"

RDEPEND="!internal-glib? ( >=dev-libs/glib-2.30[${MULTILIB_USEDEP}] )
	!dev-util/pkgconf[pkg-config]
	!dev-util/pkg-config-lite
	!dev-util/pkgconfig-openbsd[pkg-config]"
DEPEND="${RDEPEND}"

S=${WORKDIR}/${MY_P}

DOCS=( AUTHORS NEWS README )

src_prepare() {
	sed -i -e "s|^prefix=/usr\$|prefix=${EPREFIX}/usr|" check/simple.pc || die #434320

	if [[ ${PV} == *9999* ]]; then
		eautoreconf
	else
		elibtoolize # Required for FreeMiNT wrt #333429
	fi
}

multilib_src_configure() {
	local myconf

	if use internal-glib; then
		myconf+=' --with-internal-glib'
		# non-glibc platforms use GNU libiconv, but configure needs to
		# know about that not to get confused when it finds something
		# outside the prefix too
		if use prefix && use !elibc_glibc ; then
			myconf+=" --with-libiconv=gnu"
			# add the libdir for libtool, otherwise it'll make love with system
			# installed libiconv
			append-ldflags "-L${EPREFIX}/usr/$(get_libdir)"
		fi
	else
		if ! has_version dev-util/pkgconfig; then
			export GLIB_CFLAGS="-I${EPREFIX}/usr/include/glib-2.0 -I${EPREFIX}/usr/$(get_libdir)/glib-2.0/include"
			export GLIB_LIBS="-lglib-2.0"
		fi
	fi

	use ppc64 && use hardened && replace-flags -O[2-3] -O1

	# Force using all the requirements when linking, so that needed -pthread
	# lines are inherited between libraries
	use elibc_FreeBSD && myconf+=' --enable-indirect-deps'

	[[ ${PV} == *9999* ]] && myconf+=' --enable-maintainer-mode'

	ECONF_SOURCE=${S} \
	econf \
		--docdir="${EPREFIX}"/usr/share/doc/${PF}/html \
		--with-system-include-path="${EPREFIX}"/usr/include \
		--with-system-library-path="${EPREFIX}"/usr/$(get_libdir) \
		${myconf}
}

multilib_src_install() {
	emake DESTDIR="${D}" install

	if use prefix; then
		# Add an explicit reference to $EPREFIX to PKG_CONFIG_PATH to
		# simplify cross-prefix builds
		echo "PKG_CONFIG_PATH=${EPREFIX}/usr/$(get_libdir)/pkgconfig:${EPREFIX}/usr/share/pkgconfig" >> "${T}"/99${PN}
		doenvd "${T}"/99${PN}
	fi
}