[gentoo-commits] gentoo-x86 commit in app-cdr/cdrkit: ChangeLog cdrkit-1.1.11-r1.ebuild

[Samuli Suominen (ssuominen)]

ssuominen    12/08/02 13:05:38

  Modified:             ChangeLog
  Added:                cdrkit-1.1.11-r1.ebuild
  Log:
  Use system media-sound/cdparanoia instead of internal copy wrt #206939 by Diego Elio Pettenò
  
  (Portage version: 2.2.0_alpha116/cvs/Linux x86_64)

Revision  Changes    Path
1.96                 app-cdr/cdrkit/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-cdr/cdrkit/ChangeLog?rev=1.96&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-cdr/cdrkit/ChangeLog?rev=1.96&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-cdr/cdrkit/ChangeLog?r1=1.95&r2=1.96

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-cdr/cdrkit/ChangeLog,v
retrieving revision 1.95
retrieving revision 1.96
diff -u -r1.95 -r1.96
--- ChangeLog	12 Mar 2012 10:49:08 -0000	1.95
+++ ChangeLog	2 Aug 2012 13:05:38 -0000	1.96
@@ -1,6 +1,14 @@
 # ChangeLog for app-cdr/cdrkit
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-cdr/cdrkit/ChangeLog,v 1.95 2012/03/12 10:49:08 ssuominen Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-cdr/cdrkit/ChangeLog,v 1.96 2012/08/02 13:05:38 ssuominen Exp $
+
+*cdrkit-1.1.11-r1 (02 Aug 2012)
+
+  02 Aug 2012; Samuli Suominen <ssuominen@g.o> +cdrkit-1.1.11-r1.ebuild,
+  +files/cdrkit-1.1.11-cmakewarn.patch,
+  +files/cdrkit-1.1.11-paranoiacdda.patch:
+  Use system media-sound/cdparanoia instead of internal copy wrt #206939 by
+  Diego Elio Pettenò
 
   12 Mar 2012; Samuli Suominen <ssuominen@g.o> cdrkit-1.1.11.ebuild:
   Missing dependencies of app-arch/bzip2, sys-apps/file, and sys-libs/zlib for



1.1                  app-cdr/cdrkit/cdrkit-1.1.11-r1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-cdr/cdrkit/cdrkit-1.1.11-r1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-cdr/cdrkit/cdrkit-1.1.11-r1.ebuild?rev=1.1&content-type=text/plain

Index: cdrkit-1.1.11-r1.ebuild
===================================================================
# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-cdr/cdrkit/cdrkit-1.1.11-r1.ebuild,v 1.1 2012/08/02 13:05:38 ssuominen Exp $

EAPI=4
inherit cmake-utils eutils

DESCRIPTION="A set of tools for CD/DVD reading and recording, including cdrecord"
HOMEPAGE="http://cdrkit.org"
SRC_URI="mirror://debian/pool/main/c/${PN}/${PN}_${PV}.orig.tar.gz"

LICENSE="GPL-2 LGPL-2.1"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~hppa ~ia64 ~ppc ~ppc64 ~s390 ~sparc ~x86 ~x86-fbsd"
IUSE="debug hfs unicode"

RDEPEND="app-arch/bzip2
	!app-cdr/cdrtools
	media-sound/cdparanoia
	sys-apps/file
	sys-libs/zlib
	unicode? ( virtual/libiconv )
	kernel_linux? ( sys-libs/libcap )"
DEPEND="${RDEPEND}
	hfs? ( sys-apps/file )"

src_prepare() {
	epatch \
		"${FILESDIR}"/${P}-paranoiacdda.patch \
		"${FILESDIR}"/${P}-cmakewarn.patch

	echo '.so wodim.1' > ${T}/cdrecord.1
	echo '.so genisoimage.1' > ${T}/mkisofs.1
	echo '.so icedax.1' > ${T}/cdda2wav.1
	echo '.so readom.1' > ${T}/readcd.1
}

src_install() {
	cmake-utils_src_install

	dosym wodim /usr/bin/cdrecord
	dosym genisoimage /usr/bin/mkisofs
	dosym icedax /usr/bin/cdda2wav
	dosym readom /usr/bin/readcd

	dodoc ABOUT Changelog FAQ FORK TODO doc/{PORTABILITY,WHY}

	local x
	for x in genisoimage plattforms wodim icedax; do
		docinto ${x}
		dodoc doc/${x}/*
	done

	insinto /etc
	newins wodim/wodim.dfl wodim.conf
	newins netscsid/netscsid.dfl netscsid.conf

	insinto /usr/include/scsilib
	doins include/*.h
	insinto /usr/include/scsilib/usal
	doins include/usal/*.h
	dosym usal /usr/include/scsilib/scg

	doman "${T}"/*.1
}