[gentoo-commits] repo/gentoo:master commit in: gnome-base/gnome-desktop/

[Matt Turner]

commit:     9e3d693231cf31d839dcec8b9109033312b826b9
Author:     Pascal Jäger <pascal.jaeger <AT> leimstift <DOT> de>
AuthorDate: Sun Sep 18 14:48:08 2022 +0000
Commit:     Matt Turner <mattst88 <AT> gentoo <DOT> org>
CommitDate: Fri Sep 30 17:18:53 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=9e3d6932

gnome-base/gnome-desktop: Version bump to 43.0

Closes: https://github.com/gentoo/gentoo/pull/27326
Signed-off-by: Pascal Jäger <pascal.jaeger <AT> leimstift.de>
Signed-off-by: Matt Turner <mattst88 <AT> gentoo.org>

 gnome-base/gnome-desktop/Manifest                  |  1 +
 .../gnome-desktop/gnome-desktop-43-r300.ebuild     | 75 ++++++++++++++++++++++
 .../gnome-desktop/gnome-desktop-43-r400.ebuild     | 67 +++++++++++++++++++
 3 files changed, 143 insertions(+)

diff --git a/gnome-base/gnome-desktop/Manifest b/gnome-base/gnome-desktop/Manifest
index 2b124ee84ebd..f6882cb3cc30 100644
--- a/gnome-base/gnome-desktop/Manifest
+++ b/gnome-base/gnome-desktop/Manifest
@@ -1,2 +1,3 @@
 DIST gnome-desktop-42.3.tar.xz 743196 BLAKE2B bd2c8fc49bec5b40f48f5f85311a1566fd996b2f330dcd8d3b00c2331f4800ec58b7d0281be79d29e859c8731664c6953a9ee27af92ee091d621964ac4eb51b0 SHA512 aa8e492fc09bc409619747ad53dbfd13b80251dc849db9a82fcf15c2373582af9a89f769302c8ae12330580f4a7d068f22f7fce4c42983e7848acbcd9be09d15
 DIST gnome-desktop-42.4.tar.xz 743212 BLAKE2B d0e5ce93aa476b2e2c4252480fb315ce8c1802622857c7fb0af90804a621c3c358772b70957f902941b0fd75c58aa575e36ee7d960ade1409caa1f06df9e958d SHA512 6e2648aee7e7b7800276ba1f6b32a0918f6dfbd35a60a5fd22239efe75b3bd4cbed14458ab2d1b0ad0ad295428feae5342a64f2cf83505196eccb17720a26756
+DIST gnome-desktop-43.tar.xz 764256 BLAKE2B 68e13477034bb16d1c8dbe22ae940bb6711c53f93230b93ac4b6be3e61a1b60f223c9177ab004d6cd0876feecb1a71d922779f9901f914359e7aac1650a55363 SHA512 01244bf397d8ef4d9424ef9289789efde148c38f4588fe3a9094cbdd4612c56fbbff079182d6c85083462d2f3ae9771e463c5cb86995a1aef29b2f5cfd023713

diff --git a/gnome-base/gnome-desktop/gnome-desktop-43-r300.ebuild b/gnome-base/gnome-desktop/gnome-desktop-43-r300.ebuild
new file mode 100644
index 000000000000..ec790d83b0c9
--- /dev/null
+++ b/gnome-base/gnome-desktop/gnome-desktop-43-r300.ebuild
@@ -0,0 +1,75 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+inherit gnome.org meson xdg
+
+DESCRIPTION="Library with common API for various GNOME modules"
+HOMEPAGE="https://gitlab.gnome.org/GNOME/gnome-desktop/"
+
+LICENSE="GPL-2+ LGPL-2+ FDL-1.1+"
+SLOT="3/20" # subslot = libgnome-desktop-3 soname version
+IUSE="debug gtk-doc +introspection seccomp systemd udev"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~ia64 ~ppc ~ppc64 ~riscv ~sparc ~x86 ~amd64-linux ~x86-linux ~x86-solaris"
+
+COMMON_DEPEND="
+	>=x11-libs/gdk-pixbuf-2.36.5:2[introspection?]
+	>=x11-libs/gtk+-3.3.6:3[introspection?]
+	>=dev-libs/glib-2.53.0:2
+	>=gnome-base/gsettings-desktop-schemas-3.27.0[introspection?]
+	x11-misc/xkeyboard-config
+	x11-libs/libxkbcommon
+	app-text/iso-codes
+	systemd? ( sys-apps/systemd:= )
+	udev? ( virtual/libudev:= )
+	seccomp? ( sys-libs/libseccomp )
+
+	x11-libs/cairo:=
+	introspection? ( >=dev-libs/gobject-introspection-1.54:= )
+"
+DEPEND="${COMMON_DEPEND}
+	media-libs/fontconfig
+"
+RDEPEND="${COMMON_DEPEND}
+	seccomp? ( sys-apps/bubblewrap )
+	!<gnome-base/gnome-desktop-${PV}:4
+"
+BDEPEND="
+	app-text/docbook-xml-dtd:4.1.2
+	dev-util/gdbus-codegen
+	gtk-doc? ( >=dev-util/gtk-doc-1.14 )
+	dev-util/itstool
+	>=sys-devel/gettext-0.19.8
+	virtual/pkgconfig
+"
+
+src_prepare() {
+	default
+	xdg_environment_reset
+
+	# Don't build manual test programs that will never get run
+	sed -i -e "/'test-.*'/d" libgnome-desktop/meson.build || die
+}
+
+src_configure() {
+	local emesonargs=(
+		-Ddesktop_docs=false
+		$(meson_use debug debug_tools)
+		$(meson_use introspection)
+		$(meson_feature udev)
+		$(meson_feature systemd)
+		$(meson_use gtk-doc gtk_doc)
+		-Dinstalled_tests=false
+		-Dbuild_gtk4=false
+		-Dlegacy_library=true
+	)
+	meson_src_configure
+}
+
+src_install() {
+	meson_src_install
+
+	rm -r \
+		"${ED}"/usr/share/locale \
+		|| die
+}

diff --git a/gnome-base/gnome-desktop/gnome-desktop-43-r400.ebuild b/gnome-base/gnome-desktop/gnome-desktop-43-r400.ebuild
new file mode 100644
index 000000000000..796d2c17c893
--- /dev/null
+++ b/gnome-base/gnome-desktop/gnome-desktop-43-r400.ebuild
@@ -0,0 +1,67 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+inherit gnome.org meson xdg
+
+DESCRIPTION="Library with common API for various GNOME modules"
+HOMEPAGE="https://gitlab.gnome.org/GNOME/gnome-desktop/"
+
+LICENSE="GPL-2+ LGPL-2+ FDL-1.1+"
+SLOT="4/2" # subslot = libgnome-desktop-4 soname version
+IUSE="debug gtk-doc seccomp systemd udev"
+KEYWORDS="~amd64 ~arm ~arm64 ~ia64 ~loong ~ppc ~ppc64 ~riscv ~sparc ~x86 ~amd64-linux ~x86-linux ~x86-solaris"
+
+COMMON_DEPEND="
+	>=x11-libs/gdk-pixbuf-2.36.5:2[introspection]
+	>=gui-libs/gtk-4.4.0:4[introspection]
+	>=dev-libs/glib-2.53.0:2
+	>=gnome-base/gsettings-desktop-schemas-3.27.0[introspection]
+	x11-misc/xkeyboard-config
+	x11-libs/libxkbcommon
+	app-text/iso-codes
+	systemd? ( sys-apps/systemd:= )
+	udev? ( virtual/libudev:= )
+	seccomp? ( sys-libs/libseccomp )
+
+	x11-libs/cairo:=
+	>=dev-libs/gobject-introspection-1.54:=
+"
+DEPEND="${COMMON_DEPEND}
+	media-libs/fontconfig
+"
+RDEPEND="${COMMON_DEPEND}
+	seccomp? ( sys-apps/bubblewrap )
+	!<gnome-base/gnome-desktop-${PV}:3
+"
+BDEPEND="
+	app-text/docbook-xml-dtd:4.1.2
+	dev-util/gdbus-codegen
+	gtk-doc? ( >=dev-util/gtk-doc-1.14 )
+	dev-util/itstool
+	>=sys-devel/gettext-0.19.8
+	virtual/pkgconfig
+"
+
+src_prepare() {
+	default
+	xdg_environment_reset
+
+	# Don't build manual test programs that will never get run
+	sed -i -e "/'test-.*'/d" libgnome-desktop/meson.build || die
+}
+
+src_configure() {
+	local emesonargs=(
+		-Ddesktop_docs=true
+		$(meson_use debug debug_tools)
+		$(meson_feature udev)
+		$(meson_feature systemd)
+		$(meson_use gtk-doc gtk_doc)
+		-Dinstalled_tests=false
+		-Dbuild_gtk4=true
+		-Dlegacy_library=false
+		-Dintrospection=true
+	)
+	meson_src_configure
+}