[gentoo-commits] gentoo-x86 commit in mail-client/evolution: ChangeLog evolution-2.30.2-r1.ebuild evolution-2.30.3.ebuild

[Gilles Dartiguelongue (eva)]

eva         10/09/08 18:57:54

  Modified:             ChangeLog evolution-2.30.2-r1.ebuild
  Added:                evolution-2.30.3.ebuild
  Log:
  Version bump. Loads of fixes and translation updates.
  
  (Portage version: 2.2_rc74/cvs/Linux x86_64)

Revision  Changes    Path
1.305                mail-client/evolution/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/mail-client/evolution/ChangeLog?rev=1.305&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/mail-client/evolution/ChangeLog?rev=1.305&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/mail-client/evolution/ChangeLog?r1=1.304&r2=1.305

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/mail-client/evolution/ChangeLog,v
retrieving revision 1.304
retrieving revision 1.305
diff -u -r1.304 -r1.305
--- ChangeLog	24 Aug 2010 08:19:58 -0000	1.304
+++ ChangeLog	8 Sep 2010 18:57:54 -0000	1.305
@@ -1,6 +1,13 @@
 # ChangeLog for mail-client/evolution
 # Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/mail-client/evolution/ChangeLog,v 1.304 2010/08/24 08:19:58 eva Exp $
+# $Header: /var/cvsroot/gentoo-x86/mail-client/evolution/ChangeLog,v 1.305 2010/09/08 18:57:54 eva Exp $
+
+*evolution-2.30.3 (08 Sep 2010)
+
+  08 Sep 2010; Gilles Dartiguelongue <eva@g.o>
+  evolution-2.30.2-r1.ebuild, +evolution-2.30.3.ebuild,
+  +files/evolution-2.30.3-fix-linking-issues-in-libeshell.patch:
+  Version bump. Loads of fixes and translation updates.
 
   24 Aug 2010; Gilles Dartiguelongue <eva@g.o>
   evolution-2.30.2-r1.ebuild, metadata.xml:



1.7                  mail-client/evolution/evolution-2.30.2-r1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/mail-client/evolution/evolution-2.30.2-r1.ebuild?rev=1.7&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/mail-client/evolution/evolution-2.30.2-r1.ebuild?rev=1.7&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/mail-client/evolution/evolution-2.30.2-r1.ebuild?r1=1.6&r2=1.7

Index: evolution-2.30.2-r1.ebuild
===================================================================
RCS file: /var/cvsroot/gentoo-x86/mail-client/evolution/evolution-2.30.2-r1.ebuild,v
retrieving revision 1.6
retrieving revision 1.7
diff -u -r1.6 -r1.7
--- evolution-2.30.2-r1.ebuild	24 Aug 2010 08:19:58 -0000	1.6
+++ evolution-2.30.2-r1.ebuild	8 Sep 2010 18:57:54 -0000	1.7
@@ -1,6 +1,6 @@
 # Copyright 1999-2010 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/mail-client/evolution/evolution-2.30.2-r1.ebuild,v 1.6 2010/08/24 08:19:58 eva Exp $
+# $Header: /var/cvsroot/gentoo-x86/mail-client/evolution/evolution-2.30.2-r1.ebuild,v 1.7 2010/09/08 18:57:54 eva Exp $
 
 EAPI="2"
 GCONF_DEBUG="no"
@@ -10,7 +10,7 @@
 DESCRIPTION="Integrated mail, addressbook and calendaring functionality"
 HOMEPAGE="http://www.gnome.org/projects/evolution/"
 SRC_URI="${SRC_URI}
-	mirror://gentoo/${P}-patches.tar.bz2"
+	mirror://gentoo/${PN}-2.30.2-patches.tar.bz2"
 
 LICENSE="GPL-2 LGPL-2 OPENLDAP"
 SLOT="2.0"



1.1                  mail-client/evolution/evolution-2.30.3.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/mail-client/evolution/evolution-2.30.3.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/mail-client/evolution/evolution-2.30.3.ebuild?rev=1.1&content-type=text/plain

Index: evolution-2.30.3.ebuild
===================================================================
# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/mail-client/evolution/evolution-2.30.3.ebuild,v 1.1 2010/09/08 18:57:54 eva Exp $

EAPI="2"
GCONF_DEBUG="no"

inherit autotools eutils flag-o-matic gnome2 python versionator

DESCRIPTION="Integrated mail, addressbook and calendaring functionality"
HOMEPAGE="http://www.gnome.org/projects/evolution/"

LICENSE="GPL-2 LGPL-2 OPENLDAP"
SLOT="2.0"
KEYWORDS="~alpha ~amd64 ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd"
IUSE="crypt doc gstreamer kerberos ldap networkmanager nntp pda profile python ssl"
# pst
# mono - disabled because it just crashes on startup :S

# Pango dependency required to avoid font rendering problems
# We need a graphical pinentry frontend to be able to ask for the GPG
# password from inside evolution, bug 160302
RDEPEND=">=dev-libs/glib-2.22
	>=x11-libs/gtk+-2.18
	>=gnome-extra/evolution-data-server-$(get_version_component_range 1-2)
	>=gnome-base/gnome-desktop-2.26
	>=gnome-extra/gtkhtml-3.29.6
	>=gnome-base/gconf-2
	>=gnome-base/libgnomecanvas-2
	dev-libs/atk
	>=dev-libs/dbus-glib-0.74
	>=dev-libs/libunique-1.1.2
	>=dev-libs/libxml2-2.7.3
	>=dev-libs/libgweather-2.25.3
	>=net-libs/libsoup-2.4
	>=media-gfx/gtkimageview-1.6
	media-libs/libcanberra[gtk]
	x11-libs/libnotify
	>=x11-misc/shared-mime-info-0.22
	>=x11-themes/gnome-icon-theme-2.20

	crypt? ( || (
				  ( >=app-crypt/gnupg-2.0.1-r2
					|| ( app-crypt/pinentry[gtk] app-crypt/pinentry[qt3] ) )
				  =app-crypt/gnupg-1.4* ) )
	gstreamer? (
		>=media-libs/gstreamer-0.10
		>=media-libs/gst-plugins-base-0.10 )
	kerberos? ( virtual/krb5 )
	ldap? ( >=net-nds/openldap-2 )
	networkmanager? ( >=net-misc/networkmanager-0.7 )
	pda? (
		>=app-pda/gnome-pilot-2.0.16
		>=app-pda/gnome-pilot-conduits-2 )
	python? ( >=dev-lang/python-2.4 )
	ssl? (
		>=dev-libs/nspr-4.6.1
		>=dev-libs/nss-3.11 )

	!<gnome-extra/evolution-exchange-2.30"
# champlain, geoclue, clutter, gtkimageview
#	mono? ( >=dev-lang/mono-1 )

DEPEND="${RDEPEND}
	>=dev-util/pkgconfig-0.16
	>=dev-util/intltool-0.35.5
	sys-devel/gettext
	sys-devel/bison
	app-text/scrollkeeper
	>=app-text/gnome-doc-utils-0.9.1
	app-text/docbook-xml-dtd:4.1.2
	>=gnome-base/gnome-common-2.12
	>=dev-util/gtk-doc-am-1.9
	doc? ( >=dev-util/gtk-doc-1.9 )"

DOCS="AUTHORS ChangeLog* HACKING MAINTAINERS NEWS* README"
ELTCONF="--reverse-deps"

pkg_setup() {
	G2CONF="${G2CONF}
		--without-kde-applnk-path
		--enable-plugins=experimental
		--enable-image-inline
		--enable-canberra
		--enable-weather
		$(use_enable ssl nss)
		$(use_enable ssl smime)
		$(use_enable networkmanager nm)
		$(use_enable nntp)
		$(use_enable gstreamer audio-inline)
		--disable-pst-import
		$(use_enable pda pilot-conduits)
		$(use_enable profile profiling)
		$(use_enable python)
		$(use_with ldap openldap)
		$(use_with kerberos krb5 /usr)
		--disable-contacts-map"

#		$(use_enable mono)

	# dang - I've changed this to do --enable-plugins=experimental.  This will
	# autodetect new-mail-notify and exchange, but that cannot be helped for the
	# moment.  They should be changed to depend on a --enable-<foo> like mono
	# is.  This cleans up a ton of crap from this ebuild.

	# Use NSS/NSPR only if 'ssl' is enabled.
	if use ssl ; then
		G2CONF="${G2CONF} --enable-nss=yes"
	else
		G2CONF="${G2CONF}
			--without-nspr-libs
			--without-nspr-includes
			--without-nss-libs
			--without-nss-includes"
	fi
}

src_prepare() {
	gnome2_src_prepare

	# Fix linking issues with libeshell, upstream #629098
	epatch "${FILESDIR}/${PN}-2.30.3-fix-linking-issues-in-libeshell.patch"

	# FIXME: Fix compilation flags crazyness
	sed -e 's/CFLAGS="$CFLAGS $WARNING_FLAGS"//' \
		-i configure.ac configure || die "sed 1 failed"
	sed -e 's/-DG.*_DISABLE_DEPRECATED//' \
		-e 's/-DPANGO_DISABLE_DEPRECATED//' \
		-i configure.ac configure || die "sed 2 failed"

	# Use NSS/NSPR only if 'ssl' is enabled.
	if use ssl ; then
		sed -e 's|mozilla-nss|nss|' \
			-e 's|mozilla-nspr|nspr|' \
			-i configure.ac configure || die "sed 3 failed"
	fi

	intltoolize --force --copy --automake || die "intltoolize failed"
	eautoreconf
}

pkg_postinst() {
	gnome2_pkg_postinst

	elog "To change the default browser if you are not using GNOME, do:"
	elog "gconftool-2 --set /desktop/gnome/url-handlers/http/command -t string 'mozilla %s'"
	elog "gconftool-2 --set /desktop/gnome/url-handlers/https/command -t string 'mozilla %s'"
	elog ""
	elog "Replace 'mozilla %s' with which ever browser you use."
	elog ""
	elog "Junk filters are now a run-time choice. You will get a choice of"
	elog "bogofilter or spamassassin based on which you have installed"
	elog ""
	elog "You have to install one of these for the spam filtering to actually work"
}