[gentoo-commits] gentoo-x86 commit in net-dns/nsd: nsd-3.2.17.ebuild nsd-4.0.3.ebuild ChangeLog

[Wolfram Schlich (wschlich)]

wschlich    14/03/25 22:29:20

  Modified:             ChangeLog
  Added:                nsd-3.2.17.ebuild nsd-4.0.3.ebuild
  Log:
  version bump by tom@×××××××××.net
  
  (Portage version: 2.2.8-r1/cvs/Linux x86_64, unsigned Manifest commit)

Revision  Changes    Path
1.9                  net-dns/nsd/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-dns/nsd/ChangeLog?rev=1.9&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-dns/nsd/ChangeLog?rev=1.9&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-dns/nsd/ChangeLog?r1=1.8&r2=1.9

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-dns/nsd/ChangeLog,v
retrieving revision 1.8
retrieving revision 1.9
diff -u -r1.8 -r1.9
--- ChangeLog	30 Oct 2013 10:51:57 -0000	1.8
+++ ChangeLog	25 Mar 2014 22:29:20 -0000	1.9
@@ -1,6 +1,13 @@
 # ChangeLog for net-dns/nsd
-# Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-dns/nsd/ChangeLog,v 1.8 2013/10/30 10:51:57 wschlich Exp $
+# Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/net-dns/nsd/ChangeLog,v 1.9 2014/03/25 22:29:20 wschlich Exp $
+
+*nsd-4.0.3 (25 Mar 2014)
+*nsd-3.2.17 (25 Mar 2014)
+
+  25 Mar 2014; Wolfram Schlich <wschlich@g.o> +nsd-3.2.17.ebuild,
+  +nsd-4.0.3.ebuild:
+  version bump by tom@×××××××××.net
 
 *nsd-4.0.0 (30 Oct 2013)
 



1.1                  net-dns/nsd/nsd-3.2.17.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-dns/nsd/nsd-3.2.17.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-dns/nsd/nsd-3.2.17.ebuild?rev=1.1&content-type=text/plain

Index: nsd-3.2.17.ebuild
===================================================================
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-dns/nsd/nsd-3.2.17.ebuild,v 1.1 2014/03/25 22:29:20 wschlich Exp $

EAPI=4

inherit user

DESCRIPTION="An authoritative only, high performance, open source name server"
HOMEPAGE="http://www.nlnetlabs.nl/projects/nsd"
SRC_URI="http://www.nlnetlabs.nl/downloads/${PN}/${P}.tar.gz"

LICENSE="BSD"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="bind8-stats ipv6 minimal-responses mmap +nsec3 ratelimit root-server runtime-checks zone-stats"

RDEPEND="
	dev-libs/openssl
	virtual/yacc
"
DEPEND="
	${RDEPEND}
	sys-devel/flex
"

pkg_setup() {
	enewgroup nsd
	enewuser nsd -1 -1 -1 nsd
}

src_configure() {
	# ebuild.sh sets localstatedir to /var/lib, but nsd expects /var in several locations
	# some of these cannot be changed by arguments to econf/configure, f.i. logfile
	econf \
		--localstatedir="${EPREFIX}/var" \
		--with-pidfile="${EPREFIX}/var/run/nsd/nsd.pid" \
		--with-zonesdir="${EPREFIX}/var/lib/nsd" \
		--enable-largefile \
		$(use_enable bind8-stats) \
		$(use_enable ipv6) \
		$(use_enable minimal-responses) \
		$(use_enable mmap) \
		$(use_enable nsec3) \
		$(use_enable ratelimit) \
		$(use_enable root-server) \
		$(use_enable runtime-checks checking) \
		$(use_enable zone-stats)
}

src_install() {
	emake DESTDIR="${D}" install

	dodoc doc/{ChangeLog,CREDITS,NSD-FOR-BIND-USERS,README,RELNOTES,REQUIREMENTS}

	insinto /usr/share/nsd
	doins contrib/nsd.zones2nsd.conf

	exeinto /etc/cron.daily
	newexe "${FILESDIR}"/nsd3-patch.cron nsd-patch.cron

	newinitd "${FILESDIR}"/nsd3.initd-r1 nsd

	# database directory, writable by nsd for database updates and zone transfers
	dodir /var/db/nsd
	fowners nsd:nsd /var/db/nsd
	fperms 750 /var/db/nsd

	# zones directory, writable by root for 'nsdc patch'
	dodir /var/lib/nsd
	fowners root:nsd /var/lib/nsd
	fperms 750 /var/lib/nsd

	# remove /var/run data created by Makefile, handled by initd script
	rm -r "${D}"/var/run || die "could not remove /var/run/ directory"

}



1.1                  net-dns/nsd/nsd-4.0.3.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-dns/nsd/nsd-4.0.3.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-dns/nsd/nsd-4.0.3.ebuild?rev=1.1&content-type=text/plain

Index: nsd-4.0.3.ebuild
===================================================================
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-dns/nsd/nsd-4.0.3.ebuild,v 1.1 2014/03/25 22:29:20 wschlich Exp $

EAPI=4

inherit user eutils

DESCRIPTION="An authoritative only, high performance, open source name server"
HOMEPAGE="http://www.nlnetlabs.nl/projects/nsd"
# version voodoo needed only for non-release tarballs: 4.0.0_rc1 => 4.0.0rc1
MY_PV=${PV/_rc/rc}
MY_PV=${MY_PV/_beta/b}
MY_P=${PN}-${MY_PV}
S="${WORKDIR}/${MY_P}"
SRC_URI="http://www.nlnetlabs.nl/downloads/${PN}/${MY_P}.tar.gz"

LICENSE="BSD"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="bind8-stats ipv6 libevent minimal-responses mmap munin +nsec3 ratelimit root-server runtime-checks ssl"

RDEPEND="
	dev-libs/openssl
	virtual/yacc
	libevent? ( dev-libs/libevent )
	ssl? ( dev-libs/openssl )
	munin? ( net-analyzer/munin )
"
DEPEND="
	${RDEPEND}
	sys-devel/flex
"

pkg_setup() {
	enewgroup nsd
	enewuser nsd -1 -1 -1 nsd
}

src_prepare() {
	# Fix the paths in the munin plugin to match our install
	epatch "${FILESDIR}"/nsd_munin_.patch
}

src_configure() {
	econf \
		--enable-largefile \
		--with-logfile="${EPREFIX}"/var/log/nsd.log \
		--with-pidfile="${EPREFIX}"/run/nsd/nsd.pid \
		--with-dbfile="${EPREFIX}"/var/db/nsd/nsd.db \
		--with-xfrdir="${EPREFIX}"/var/db/nsd \
		--with-xfrdfile="${EPREFIX}"/var/db/nsd/xfrd.state \
		--with-zonelistfile="${EPREFIX}"/var/db/nsd/zone.list \
		--with-zonesdir="${EPREFIX}"/var/lib/nsd \
		$(use_enable bind8-stats) \
		$(use_enable ipv6) \
		$(use_enable minimal-responses) \
		$(use_enable mmap) \
		$(use_enable nsec3) \
		$(use_enable ratelimit) \
		$(use_enable root-server) \
		$(use_enable runtime-checks checking) \
		$(use_with libevent) \
		$(use_with ssl)
}

src_install() {
	emake DESTDIR="${D}" install

	dodoc doc/{ChangeLog,CREDITS,NSD-4-features,NSD-FOR-BIND-USERS,README,RELNOTES,REQUIREMENTS}

	newinitd "${FILESDIR}"/nsd.initd nsd

	# database directory, writable by nsd for database updates and zone transfers
	dodir /var/db/nsd
	fowners nsd:nsd /var/db/nsd
	fperms 750 /var/db/nsd

	# zones directory, writable by nsd for zone file updates (nsd-control write)
	dodir /var/lib/nsd
	fowners nsd:nsd /var/lib/nsd
	fperms 750 /var/lib/nsd

	# install munin plugin and config
	if use munin; then
		exeinto /usr/libexec/munin/plugins
		doexe contrib/nsd_munin_
		insinto /etc/munin/plugin-conf.d
		newins "${FILESDIR}"/nsd.munin-conf nsd_munin
	fi

	# remove the /run directory that usually resides on tmpfs and is
	# being taken care of by the nsd init script anyway (checkpath)
	rm -rf "${D}"/run || die "Failed to remove /run"
}