[gentoo-commits] gentoo-x86 commit in app-text/namazu: namazu-2.0.22_p1.ebuild ChangeLog

[Naohiro Aota (naota)]

naota       13/03/01 09:47:15

  Modified:             ChangeLog
  Added:                namazu-2.0.22_p1.ebuild
  Log:
  Add pre released ebuild
  
  (Portage version: 2.1.11.52/cvs/Linux x86_64, signed Manifest commit with key F8551514)

Revision  Changes    Path
1.42                 app-text/namazu/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-text/namazu/ChangeLog?rev=1.42&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-text/namazu/ChangeLog?rev=1.42&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-text/namazu/ChangeLog?r1=1.41&r2=1.42

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-text/namazu/ChangeLog,v
retrieving revision 1.41
retrieving revision 1.42
diff -u -r1.41 -r1.42
--- ChangeLog	14 Jul 2012 06:39:25 -0000	1.41
+++ ChangeLog	1 Mar 2013 09:47:14 -0000	1.42
@@ -1,6 +1,11 @@
 # ChangeLog for app-text/namazu
-# Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-text/namazu/ChangeLog,v 1.41 2012/07/14 06:39:25 hattya Exp $
+# Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/app-text/namazu/ChangeLog,v 1.42 2013/03/01 09:47:14 naota Exp $
+
+*namazu-2.0.22_p1 (01 Mar 2013)
+
+  01 Mar 2013; Naohiro Aota <naota@g.o> +namazu-2.0.22_p1.ebuild:
+  Add pre released ebuild
 
   14 Jul 2012; Akinori Hattori <hattya@g.o> metadata.xml:
   format metadata.xml
@@ -156,4 +161,3 @@
   ChangeLog,Manifest,files/digest-namazu-2.0.12:
 
   Initial import. Ebuild submitted by naoto @ GentooJP
-



1.1                  app-text/namazu/namazu-2.0.22_p1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-text/namazu/namazu-2.0.22_p1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-text/namazu/namazu-2.0.22_p1.ebuild?rev=1.1&content-type=text/plain

Index: namazu-2.0.22_p1.ebuild
===================================================================
# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-text/namazu/namazu-2.0.22_p1.ebuild,v 1.1 2013/03/01 09:47:14 naota Exp $

EAPI=5

inherit autotools-utils eutils elisp-common

IUSE="emacs nls tk linguas_ja"

DESCRIPTION="Namazu is a full-text search engine"
HOMEPAGE="http://www.namazu.org/"
SRC_URI="http://www.namazu.org/test/${P/_p/pre}.tar.gz"

LICENSE="GPL-2"
KEYWORDS=""
SLOT="0"

RDEPEND=">=dev-perl/File-MMagic-1.20
	emacs? ( virtual/emacs )
	linguas_ja? (
		app-i18n/nkf
		|| (
			dev-perl/Text-Kakasi
			app-i18n/kakasi
			app-text/chasen
			app-text/mecab
		)
	)
	nls? ( virtual/libintl )
	tk? (
		dev-lang/tk
		www-client/lynx
	)"

DEPEND="${RDEPEND}
	nls? ( sys-devel/gettext )"

PATCHES=(
	"${FILESDIR}/${PN}-2.0.19-gentoo.patch"
)
DOCS=(AUTHORS CREDITS NEWS THANKS TODO)

S="${WORKDIR}"/${P/_p/pre}

src_configure() {
	local myeconfargs=(
		$(use_enable nls)
		$(use_enable tk tknamazu)
	)

	use tk && myeconfargs+=(
		--with-namazu=/usr/bin/namazu
		--with-mknmz=/usr/bin/mknmz
		--with-indexdir=/var/lib/namazu/index
	)
	autotools-utils_src_configure
}

src_compile() {
	autotools-utils_src_compile

	if use emacs; then
		cd lisp
		elisp-compile gnus-nmz-1.el namazu.el || die
	fi
}

src_install () {
	autotools-utils_src_install
	dodoc ChangeLog* HACKING* README* etc/*.png
	dohtml -r doc/*
	rm -r "${ED}"/usr/share/namazu/doc || die
	if use emacs; then
		elisp-install ${PN} lisp/gnus-nmz-1.el* lisp/namazu.el* || die
		elisp-site-file-install "${FILESDIR}"/50${PN}-gentoo.el || die

		docinto lisp
		dodoc lisp/ChangeLog*
	fi
}

pkg_postinst() {
	use emacs && elisp-site-regen
}

pkg_postrm() {
	use emacs && elisp-site-regen
}