[gentoo-commits] repo/gentoo:master commit in: dev-embedded/avrdude/

[Jakov Smolić]

commit:     97601a724cce28c0dddfb32588c43e90086761d3
Author:     Jakov Smolić <jsmolic <AT> gentoo <DOT> org>
AuthorDate: Thu Oct  7 18:48:13 2021 +0000
Commit:     Jakov Smolić <jsmolic <AT> gentoo <DOT> org>
CommitDate: Thu Oct  7 18:54:03 2021 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=97601a72

dev-embedded/avrdude: Port to EAPI-8, add missing virtual/libelf dependency

Closes: https://bugs.gentoo.org/565512
Signed-off-by: Jakov Smolić <jsmolic <AT> gentoo.org>

 dev-embedded/avrdude/avrdude-6.3-r1.ebuild | 56 ++++++++++++++++++++++++++++++
 1 file changed, 56 insertions(+)

diff --git a/dev-embedded/avrdude/avrdude-6.3-r1.ebuild b/dev-embedded/avrdude/avrdude-6.3-r1.ebuild
new file mode 100644
index 00000000000..eedc4b7b506
--- /dev/null
+++ b/dev-embedded/avrdude/avrdude-6.3-r1.ebuild
@@ -0,0 +1,56 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit toolchain-funcs
+
+DESCRIPTION="AVR Downloader/UploaDEr"
+HOMEPAGE="https://savannah.nongnu.org/projects/avrdude"
+SRC_URI="mirror://nongnu/${PN}/${P}.tar.gz
+	doc? (
+		mirror://nongnu/${PN}/${PN}-doc-${PV}.tar.gz
+		mirror://nongnu/${PN}/${PN}-doc-${PV}.pdf
+	)"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~ppc ~ppc64 ~x86"
+IUSE="doc ftdi ncurses readline"
+
+RDEPEND="
+	virtual/libelf
+	virtual/libusb:1
+	virtual/libusb:0
+	ftdi? ( dev-embedded/libftdi:= )
+	ncurses? ( sys-libs/ncurses:0= )
+	readline? ( sys-libs/readline:0= )
+"
+DEPEND="${RDEPEND}"
+
+src_configure() {
+	# somehow this doesnt get set when cross-compiling and breaks build
+	tc-export AR
+	export ac_cv_lib_ftdi_ftdi_usb_get_strings=$(usex ftdi)
+	export ac_cv_lib_ncurses_tputs=$(usex ncurses)
+	export ac_cv_lib_readline_readline=$(usex readline)
+	econf --disable-static
+}
+
+src_compile() {
+	# The automake target for these files does not use tempfiles or create
+	# these atomically, confusing a parallel build. So we force them first.
+	emake lexer.c config_gram.c config_gram.h
+	emake
+}
+
+src_install() {
+	default
+
+	if use doc ; then
+		newdoc "${DISTDIR}/${PN}-doc-${PV}.pdf" avrdude.pdf
+		dodoc -r "${WORKDIR}/avrdude-html/"
+	fi
+
+	find "${ED}" -name '*.la' -delete || die
+}