[gentoo-commits] gentoo-x86 commit in x11-misc/xaos: xaos-3.5-r1.ebuild xaos-3.6.ebuild metadata.xml ChangeLog xaos-3.5-r2.ebuild

[Sebastien Fabbro (bicatali)]

bicatali    14/06/09 18:43:33

  Modified:             xaos-3.5-r1.ebuild metadata.xml ChangeLog
  Added:                xaos-3.6.ebuild
  Removed:              xaos-3.5-r2.ebuild
  Log:
  Version bump. Backport patch to stable 3.5-r1 version (bug #497852, thanks Patrice Levesque) and for gettext-0.19 (bug #512748, thanks zimous), add internationalization options, switch to autotools-utils, EAPI5
  
  (Portage version: HEAD/cvs/Linux x86_64, signed Manifest commit with key 0x13CB1360)

Revision  Changes    Path
1.11                 x11-misc/xaos/xaos-3.5-r1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-misc/xaos/xaos-3.5-r1.ebuild?rev=1.11&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-misc/xaos/xaos-3.5-r1.ebuild?rev=1.11&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-misc/xaos/xaos-3.5-r1.ebuild?r1=1.10&r2=1.11

Index: xaos-3.5-r1.ebuild
===================================================================
RCS file: /var/cvsroot/gentoo-x86/x11-misc/xaos/xaos-3.5-r1.ebuild,v
retrieving revision 1.10
retrieving revision 1.11
diff -u -r1.10 -r1.11
--- xaos-3.5-r1.ebuild	25 Jun 2013 17:27:41 -0000	1.10
+++ xaos-3.5-r1.ebuild	9 Jun 2014 18:43:33 -0000	1.11
@@ -1,6 +1,6 @@
-# Copyright 1999-2013 Gentoo Foundation
+# Copyright 1999-2014 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/x11-misc/xaos/xaos-3.5-r1.ebuild,v 1.10 2013/06/25 17:27:41 aballier Exp $
+# $Header: /var/cvsroot/gentoo-x86/x11-misc/xaos/xaos-3.5-r1.ebuild,v 1.11 2014/06/09 18:43:33 bicatali Exp $
 
 EAPI=4
 
@@ -39,7 +39,9 @@
 	epatch \
 		"${FILESDIR}"/${PN}-3.4-png.patch \
 		"${FILESDIR}"/${PN}-3.4-include.patch \
-		"${FILESDIR}"/${PN}-3.5-libpng15.patch
+		"${FILESDIR}"/${PN}-3.5-libpng15.patch \
+		"${FILESDIR}"/${PN}-3.5-build-fix-i686.patch \
+		"${FILESDIR}"/${PN}-3.5-gettext.patch
 	sed -i -e 's/-s//' Makefile.in
 	eautoreconf
 }



1.4                  x11-misc/xaos/metadata.xml

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-misc/xaos/metadata.xml?rev=1.4&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-misc/xaos/metadata.xml?rev=1.4&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-misc/xaos/metadata.xml?r1=1.3&r2=1.4

Index: metadata.xml
===================================================================
RCS file: /var/cvsroot/gentoo-x86/x11-misc/xaos/metadata.xml,v
retrieving revision 1.3
retrieving revision 1.4
diff -u -r1.3 -r1.4
--- metadata.xml	3 Dec 2012 09:50:41 -0000	1.3
+++ metadata.xml	9 Jun 2014 18:43:33 -0000	1.4
@@ -1,8 +1,8 @@
 <?xml version="1.0" encoding="UTF-8"?>
 <!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
 <pkgmetadata>
-	<herd>sci</herd>
-	<longdescription lang="en">
+<herd>sci</herd>
+<longdescription lang="en">
   XaoS is a fast, portable real-time interactive fractal zoomer. It
   displays the Mandelbrot set (among other escape time fractals) and
   allows you zoom smoothly into the fractal. Various coloring modes are



1.45                 x11-misc/xaos/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-misc/xaos/ChangeLog?rev=1.45&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-misc/xaos/ChangeLog?rev=1.45&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-misc/xaos/ChangeLog?r1=1.44&r2=1.45

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/x11-misc/xaos/ChangeLog,v
retrieving revision 1.44
retrieving revision 1.45
diff -u -r1.44 -r1.45
--- ChangeLog	25 Jun 2013 17:27:41 -0000	1.44
+++ ChangeLog	9 Jun 2014 18:43:33 -0000	1.45
@@ -1,6 +1,16 @@
 # ChangeLog for x11-misc/xaos
-# Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/x11-misc/xaos/ChangeLog,v 1.44 2013/06/25 17:27:41 aballier Exp $
+# Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/x11-misc/xaos/ChangeLog,v 1.45 2014/06/09 18:43:33 bicatali Exp $
+
+*xaos-3.6 (09 Jun 2014)
+
+  09 Jun 2014; Sébastien Fabbro <bicatali@g.o>
+  +files/xaos-3.5-gettext.patch, +files/xaos-3.6-locale-dir.patch,
+  +files/xaos-3.6-no-auto-strip.patch, +xaos-3.6.ebuild, -xaos-3.5-r2.ebuild,
+  metadata.xml, xaos-3.5-r1.ebuild:
+  Version bump. Backport patch to stable 3.5-r1 version (bug #497852, thanks
+  Patrice Levesque) and for gettext-0.19 (bug #512748, thanks zimous), add
+  internationalization options, switch to autotools-utils, EAPI5
 
   25 Jun 2013; Alexis Ballier <aballier@g.o> xaos-3.5-r1.ebuild,
   xaos-3.5-r2.ebuild:



1.1                  x11-misc/xaos/xaos-3.6.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-misc/xaos/xaos-3.6.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-misc/xaos/xaos-3.6.ebuild?rev=1.1&content-type=text/plain

Index: xaos-3.6.ebuild
===================================================================
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/x11-misc/xaos/xaos-3.6.ebuild,v 1.1 2014/06/09 18:43:33 bicatali Exp $

EAPI=5

AUTOTOOLS_AUTORECONF=1
AUTOTOOLS_IN_SOURCE_BUILD=1

inherit autotools-utils eutils

DESCRIPTION="Very fast real-time fractal zoomer"
HOMEPAGE="http://matek.hu/xaos/doku.php"
SRC_URI="mirror://sourceforge/${PN}/${P}.tar.gz
	http://dev.gentoo.org/~jlec/distfiles/${PN}.png.tar"

SLOT="0"
LICENSE="GPL-2"
KEYWORDS="~amd64 ~ppc ~sparc ~x86 ~amd64-linux ~x86-linux"
IUSE="aalib doc -gtk nls png svga threads X"

RDEPEND="
	sci-libs/gsl:0=
	sys-libs/zlib:0=
	aalib? ( media-libs/aalib:0= )
	gtk? ( x11-libs/gtk+:2= )
	nls? ( sys-devel/gettext )
	png? ( media-libs/libpng:0= )
	X? ( x11-libs/libX11:0=
		 x11-libs/libXext:0=
		 x11-libs/libXxf86vm:0= )"

DEPEND="${RDEPEND}
	virtual/pkgconfig
	doc? ( virtual/texi2dvi )
	X? (
		x11-proto/xf86vidmodeproto
		x11-proto/xextproto
		x11-proto/xproto )"

PATCHES=(
	"${FILESDIR}"/${PN}-3.4-png.patch
	"${FILESDIR}"/${PN}-3.4-include.patch
	"${FILESDIR}"/${PN}-3.5-build-fix-i686.patch
	"${FILESDIR}"/${PN}-3.6-locale-dir.patch
	"${FILESDIR}"/${PN}-3.6-no-auto-strip.patch
)

src_prepare() {
	autotools-utils_src_prepare
	if use nls; then
		if [[ "${LINGUAS+set}" == "set" ]]; then
			strip-linguas -i src/i18n
			sed -i -e '/^ALL_LINGUAS=/d' configure || die
			export ALL_LINGUAS="${LINGUAS}"
		fi
	else
		sed -i -e '/^ALL_LINGUAS=/d' configure || die
	fi
}

src_configure() {
	local myeconfargs=(
		--with-sffe=yes
		--with-gsl=yes
		$(use_enable nls)
		$(use_with png)
		$(use_with aalib aa-driver)
		$(use_with gtk gtk-driver)
		$(use_with threads pthread)
		$(use_with X x11-driver)
		$(use_with X x)
	)
	autotools-utils_src_configure
}

src_compile() {
	autotools-utils_src_compile
	if use doc; then
		cd "${BUILD_DIR}"/doc
		emake xaos.dvi
		dvipdf xaos.dvi || die
		cd "${BUILD_DIR}"/help
		emake html
	fi
}

src_install() {
	autotools-utils_src_install
	if use doc; then
		insinto /usr/share/doc/${PF}
		doins doc/xaos.pdf
		dohtml -r help/*
	fi
	local driver="x11"
	use gtk && driver="\"GTK+ Driver\""
	make_desktop_entry "xaos -driver ${driver}" "XaoS Fractal Zoomer" \
		xaos "Application;Education;Math;Graphics;"
	doicon "${WORKDIR}"/${PN}.png
}