[gentoo-commits] repo/gentoo:master commit in: dev-python/flake8/

[Matt Turner]

commit:     912dff6951e30f72317094ab66d90d870ff23ed0
Author:     Andrew Ammerlaan <andrewammerlaan <AT> riseup <DOT> net>
AuthorDate: Thu May 14 12:26:06 2020 +0000
Commit:     Matt Turner <mattst88 <AT> gentoo <DOT> org>
CommitDate: Tue May 26 20:41:46 2020 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=912dff69

dev-python/flake8: version bump

Package-Manager: Portage-2.3.99, Repoman-2.3.22
Signed-off-by: Andrew Ammerlaan <andrewammerlaan <AT> riseup.net>
Closes: https://github.com/gentoo/gentoo/pull/15790
Signed-off-by: Matt Turner <mattst88 <AT> gentoo.org>

 dev-python/flake8/Manifest            |  1 +
 dev-python/flake8/flake8-3.8.1.ebuild | 47 +++++++++++++++++++++++++++++++++++
 2 files changed, 48 insertions(+)

diff --git a/dev-python/flake8/Manifest b/dev-python/flake8/Manifest
index eb339487dbf..89eb07174c2 100644
--- a/dev-python/flake8/Manifest
+++ b/dev-python/flake8/Manifest
@@ -1 +1,2 @@
 DIST flake8-3.7.9.tar.gz 150123 BLAKE2B fd46710c0dcce7d3dcb3d5fc8ff7a83a35315679fa838e68abafd5bdc342c13218706fec0dac3fc9a6d919971f1f846c855f00cbd60c925e979378e431dace0b SHA512 c3c753ad050d8a8f87f7c28c8a1c953ed9bd04f08b09512d9323152b4eebb57d67fbfb0f5317d629174fa12fa234e1a86d6a633dd951fff6a45330b1c4f62850
+DIST flake8-3.8.1.tar.gz 157166 BLAKE2B cc8b2dc11f78a6b9c62662086cc190a29a0a4e5a228d4823de8e2f3f327cea3e5df4db220faf9cc14fa34e3825b7d1e4fc4ccf9d1205b437903f327f3ebfa7bb SHA512 f73a306be7d8e5bc48dd9d6d8f8cdee07a90c6c38ee7bd37a21f4be23f1812e4a1e214cc75ca1a324f40e750312b5d7ed573ff49d673f9a1f33aad188b108add

diff --git a/dev-python/flake8/flake8-3.8.1.ebuild b/dev-python/flake8/flake8-3.8.1.ebuild
new file mode 100644
index 00000000000..806a6b8f638
--- /dev/null
+++ b/dev-python/flake8/flake8-3.8.1.ebuild
@@ -0,0 +1,47 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{6,7,8} pypy3 )
+DISTUTILS_USE_SETUPTOOLS=rdepend
+
+inherit distutils-r1
+
+DESCRIPTION="A wrapper around PyFlakes, pep8 & mccabe"
+HOMEPAGE="https://gitlab.com/pycqa/flake8 https://pypi.org/project/flake8/"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86"
+
+# requires.txt inc. mccabe however that creates a circular dep
+RDEPEND="
+	>=dev-python/pyflakes-2.2.0[${PYTHON_USEDEP}]
+	<dev-python/pyflakes-2.3.0[${PYTHON_USEDEP}]
+	>=dev-python/pycodestyle-2.6.0[${PYTHON_USEDEP}]
+	<dev-python/pycodestyle-2.7.0[${PYTHON_USEDEP}]
+	dev-python/importlib_metadata[${PYTHON_USEDEP}]
+"
+PDEPEND="
+	>=dev-python/mccabe-0.6.0[${PYTHON_USEDEP}]
+	<dev-python/mccabe-0.7.0[${PYTHON_USEDEP}]
+"
+BDEPEND="${RDEPEND}
+	test? (
+		${PDEPEND}
+		>=dev-python/mock-2.0.0[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+# Sphinx and friends are not keyworded for all arches, repoman complains
+#distutils_enable_sphinx docs/source dev-python/sphinx-prompt dev-python/sphinx_rtd_theme
+
+python_prepare_all() {
+	# don't treat warnings as errors when running tests
+	sed -r -i '/^[[:space:]]*error[[:space:]]*$/ d' pytest.ini || die
+
+	distutils-r1_python_prepare_all
+}