[gentoo-commits] gentoo-x86 commit in x11-terms/mrxvt: ChangeLog mrxvt-0.5.3-r3.ebuild

[Krzysiek Pawlik (nelchael)]

nelchael    08/06/26 09:13:01

  Modified:             ChangeLog
  Added:                mrxvt-0.5.3-r3.ebuild
  Log:
  Add patch from upstream to fix behaviour when mrxvt window is completely obscured, bug #229469.
  (Portage version: 2.2_rc1/cvs/Linux 2.6.25-tuxonice-r5 x86_64)

Revision  Changes    Path
1.67                 x11-terms/mrxvt/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/x11-terms/mrxvt/ChangeLog?rev=1.67&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/x11-terms/mrxvt/ChangeLog?rev=1.67&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/x11-terms/mrxvt/ChangeLog?r1=1.66&r2=1.67

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/x11-terms/mrxvt/ChangeLog,v
retrieving revision 1.66
retrieving revision 1.67
diff -u -r1.66 -r1.67
--- ChangeLog	10 Jun 2008 22:05:42 -0000	1.66
+++ ChangeLog	26 Jun 2008 09:13:01 -0000	1.67
@@ -1,6 +1,14 @@
 # ChangeLog for x11-terms/mrxvt
 # Copyright 1999-2008 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/x11-terms/mrxvt/ChangeLog,v 1.66 2008/06/10 22:05:42 nelchael Exp $
+# $Header: /var/cvsroot/gentoo-x86/x11-terms/mrxvt/ChangeLog,v 1.67 2008/06/26 09:13:01 nelchael Exp $
+
+*mrxvt-0.5.3-r3 (26 Jun 2008)
+
+  26 Jun 2008; Krzysiek Pawlik <nelchael@g.o>
+  +files/mrxvt-0.5.3-stop-polling-when-obscured.patch,
+  +mrxvt-0.5.3-r3.ebuild:
+  Add patch from upstream to fix behaviour when mrxvt window is completely
+  obscured, bug #229469.
 
   10 Jun 2008; Krzysiek Pawlik <nelchael@g.o>
   -files/mrxvt-0.5.2-no_debug_x.patch, -mrxvt-0.5.1.ebuild,



1.1                  x11-terms/mrxvt/mrxvt-0.5.3-r3.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/x11-terms/mrxvt/mrxvt-0.5.3-r3.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/x11-terms/mrxvt/mrxvt-0.5.3-r3.ebuild?rev=1.1&content-type=text/plain

Index: mrxvt-0.5.3-r3.ebuild
===================================================================
# Copyright 1999-2008 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/x11-terms/mrxvt/mrxvt-0.5.3-r3.ebuild,v 1.1 2008/06/26 09:13:01 nelchael Exp $

inherit eutils

DESCRIPTION="Multi-tabbed rxvt clone with XFT, transparent background and CJK support"
HOMEPAGE="http://materm.sourceforge.net/"
SRC_URI="mirror://sourceforge/materm/${P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~mips ~ppc ~x86"

LINGUAS_IUSE="linguas_el linguas_ja linguas_ko linguas_th linguas_zh_CN linguas_zh_TW"
IUSE="debug png jpeg session truetype menubar utempter xpm ${LINGUAS_IUSE}"

RDEPEND="png? ( media-libs/libpng )
	utempter? ( sys-libs/libutempter )
	jpeg? ( media-libs/jpeg )
	truetype? ( virtual/xft
		media-libs/fontconfig
		media-libs/freetype )
	x11-libs/libX11
	x11-libs/libXt
	xpm? ( x11-libs/libXpm )
	x11-libs/libXrender"

DEPEND="${RDEPEND}
	x11-proto/xproto"

src_unpack() {

	unpack ${A}
	cd "${S}"
	epatch "${FILESDIR}/${P}-no-scroll-with-buffer.patch"
	epatch "${FILESDIR}/${P}-display-security.patch"
	epatch "${FILESDIR}/${P}-stop-polling-when-obscured.patch"

}

src_compile() {

	local myconf

	# if you want to pass any other flags, use EXTRA_ECONF.
	if use linguas_el ; then
		myconf="${myconf} --enable-greek"
	fi
	if use linguas_ja ; then
		# --with-encoding=sjis
		myconf="${myconf} --enable-kanji --with-encoding=eucj"
	fi
	if use linguas_ko ; then
		myconf="${myconf} --enable-kr --with-encoding=kr"
	fi
	if use linguas_th ; then
		myconf="${myconf} --enable-thai"
	fi
	if use linguas_zh_CN ; then
		# --with-encoding=gbk
		myconf="${myconf} --enable-gb --with-encoding=gb"
	fi
	if use linguas_zh_TW ; then
		myconf="${myconf} --enable-big5 --with-encoding=big5"
	fi

	# 2006-03-13 gi1242: mrxvt works best with TERM=rxvt AND correctly set
	# termcap / terminfo entries. If the rxvt termcap / terminfo entries are
	# messed up then then it's better to set TERM=xterm.
	#
	# Provide support for this by setting the or RXVT_TERM environment variables
	# before emerging, as done in the rxvt ebuild.

	if [[ -n ${RXVT_TERM} ]]; then
		myconf="${myconf} --with-term=${RXVT_TERM}"
	fi

	econf \
		--enable-everything \
		--with-atab-extra=25 \
		$(use_enable debug) \
		$(use_enable jpeg) \
		$(use_enable png) \
		$(use_enable xpm) \
		$(use_enable session sessionmgr) \
		$(use_enable truetype xft) \
		$(use_enable utempter) \
		$(use_enable menubar) \
		${myconf} || die

	emake || die

}

src_install() {

	make DESTDIR="${D}" docdir=/usr/share/doc/${PF} install || die
	# Give mrxvt perms to update utmp
	fowners root:utmp /usr/bin/mrxvt
	fperms g+s /usr/bin/mrxvt
	dodoc AUTHORS CREDITS ChangeLog FAQ NEWS README* TODO

}

pkg_postinst() {

	if [[ -z $RXVT_TERM ]]; then
		einfo
		einfo "If you experience problems with curses programs, then this is"
		einfo "most likely because of incorrectly set termcap / terminfo"
		einfo "entries. To fix this you can dry and run (as user)"
		einfo "	tic /usr/share/doc/${P}/etc/mrxvt.terminfo"
		einfo "Alternately, run the offending programs with TERM=xterm."
		einfo
		einfo "To emerge mrxvt with TERM=xterm by default, set the RXVT_TERM"
		einfo "environment variable to 'xterm', or your desired default"
		einfo "terminal name. Alternately you can put 'Mrxvt.termName: xterm'"
		einfo "in your ~/.mrxvtrc, or /etc/mrxvt/mrxvtrc."
		einfo
	fi

}



-- 
gentoo-commits@l.g.o mailing list