[gentoo-commits] repo/gentoo:master commit in: app-portage/flaggie/

[Michał Górny]

commit:     27dc861550a706df120c87f91d3d0a93338d3f69
Author:     Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Wed May 18 07:06:16 2022 +0000
Commit:     Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Wed May 18 07:36:07 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=27dc8615

app-portage/flaggie: Use PEP517 build

Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>

 app-portage/flaggie/flaggie-0.2.1-r2.ebuild | 38 +++++++++++++++++++++++++++++
 1 file changed, 38 insertions(+)

diff --git a/app-portage/flaggie/flaggie-0.2.1-r2.ebuild b/app-portage/flaggie/flaggie-0.2.1-r2.ebuild
new file mode 100644
index 000000000000..5ced01008064
--- /dev/null
+++ b/app-portage/flaggie/flaggie-0.2.1-r2.ebuild
@@ -0,0 +1,38 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{8..9} )
+
+inherit bash-completion-r1 distutils-r1
+
+DESCRIPTION="A smart CLI mangler for package.* files"
+HOMEPAGE="https://github.com/mgorny/flaggie/"
+SRC_URI="https://github.com/mgorny/flaggie/releases/download/${P}/${P}.tar.bz2"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~mips ~ppc64 ~riscv ~x86 ~amd64-linux ~x86-linux"
+
+RDEPEND="
+	sys-apps/portage[${PYTHON_USEDEP}]
+"
+
+python_install_all() {
+	newbashcomp contrib/bash-completion/${PN}.bash-completion ${PN}
+	distutils-r1_python_install_all
+}
+
+pkg_postinst() {
+	ewarn "Please note that flaggie creates backups of your package.* files"
+	ewarn "before performing each change through appending a single '~'."
+	ewarn "If you'd like to keep your own backup of them, please use another"
+	ewarn "naming scheme (or even better some VCS)."
+	if ! has_version app-shells/gentoo-bashcomp; then
+		elog
+		elog "If you want to use bash-completion, you need to install:"
+		elog "	app-shells/gentoo-bashcomp"
+	fi
+}