[gentoo-commits] repo/gentoo:master commit in: dev-libs/libmirage/

[Michał Górny]

commit:     73755018f46cd57a4947e1dec6741298f8f2e6af
Author:     Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Tue Jan  7 05:39:05 2020 +0000
Commit:     Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Tue Jan  7 06:02:05 2020 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=73755018

dev-libs/libmirage: Bump to 3.2.4

Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>

 dev-libs/libmirage/Manifest               |  1 +
 dev-libs/libmirage/libmirage-3.2.4.ebuild | 50 +++++++++++++++++++++++++++++++
 2 files changed, 51 insertions(+)

diff --git a/dev-libs/libmirage/Manifest b/dev-libs/libmirage/Manifest
index 573822dd1e2..7e855a79e55 100644
--- a/dev-libs/libmirage/Manifest
+++ b/dev-libs/libmirage/Manifest
@@ -1 +1,2 @@
 DIST libmirage-3.2.3.tar.bz2 234761 BLAKE2B f3fc24dae81643c4fea99d12e4f7f1d600586a7c5e546e854d4391ecb11f39a6d1108ac86c79b917fb96cc53424975ff548522a0f0e035ffd4b99638fc18608a SHA512 25cc3ccfac9332d06edff7e73d992e9d74b7464f61b857c3fb40ec9e2584a8f61b8aaef96a6d6f4b8f3a7c871b6b7b7803502d5e1ef771fc239021a827b90f09
+DIST libmirage-3.2.4.tar.bz2 234530 BLAKE2B 72329350a9e2a197ff52d396a011d3cf0178731909066ee1dab75f0d870fd751d50e2cacb69c849aa8045e94fa492732c21d201bdd4cbe3a9048f5c3f90ea881 SHA512 6fe718ad7beaf457ef0a7cc037b3bcf268574606ea9cbc1ba9abb5088c734fe9a100a35320d393a47625bbdde5515cded02e767618f2fc0801cf755af1414091

diff --git a/dev-libs/libmirage/libmirage-3.2.4.ebuild b/dev-libs/libmirage/libmirage-3.2.4.ebuild
new file mode 100644
index 00000000000..d7e0e688065
--- /dev/null
+++ b/dev-libs/libmirage/libmirage-3.2.4.ebuild
@@ -0,0 +1,50 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit cmake-utils xdg-utils
+
+DESCRIPTION="CD and DVD image access library"
+HOMEPAGE="https://cdemu.sourceforge.io"
+SRC_URI="https://download.sourceforge.net/cdemu/libmirage/${P}.tar.bz2"
+
+LICENSE="GPL-2+"
+SLOT="0/11" # subslot = libmirage soname version
+KEYWORDS="~amd64 ~x86"
+IUSE="doc +introspection"
+
+RDEPEND=">=app-arch/bzip2-1:=
+	>=app-arch/xz-utils-5:=
+	>=dev-libs/glib-2.38:2
+	>=media-libs/libsamplerate-0.1:=
+	>=media-libs/libsndfile-1.0:=
+	sys-libs/zlib:=
+	introspection? ( >=dev-libs/gobject-introspection-1.30 )"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	dev-util/desktop-file-utils
+	dev-util/intltool
+	sys-devel/gettext
+	virtual/pkgconfig
+	doc? ( dev-util/gtk-doc )
+	introspection? ( >=dev-libs/gobject-introspection-1.30 )"
+
+DOCS=( AUTHORS README )
+
+src_configure() {
+	local mycmakeargs=(
+		-DGTKDOC_ENABLED="$(usex doc)"
+		-DINTROSPECTION_ENABLED="$(usex introspection)"
+		-DPOST_INSTALL_HOOKS=OFF # avoid sandbox violation, #487304
+	)
+	cmake-utils_src_configure
+}
+
+pkg_postinst() {
+	xdg_mimeinfo_database_update
+}
+
+pkg_postrm() {
+	xdg_mimeinfo_database_update
+}