[gentoo-commits] gentoo-x86 commit in x11-wm/qtile: ChangeLog qtile-0.9.1.ebuild qtile-9999.ebuild

[Tim Harder (radhermit)]

radhermit    15/02/25 18:14:43

  Modified:             ChangeLog qtile-9999.ebuild
  Added:                qtile-0.9.1.ebuild
  Log:
  Version bump, disable docs until required sphinx extensions are in the tree.
  
  (Portage version: 2.2.15/cvs/Linux x86_64, signed Manifest commit with key 4AB3E85B4F064CA3)

Revision  Changes    Path
1.15                 x11-wm/qtile/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-wm/qtile/ChangeLog?rev=1.15&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-wm/qtile/ChangeLog?rev=1.15&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-wm/qtile/ChangeLog?r1=1.14&r2=1.15

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/x11-wm/qtile/ChangeLog,v
retrieving revision 1.14
retrieving revision 1.15
diff -u -r1.14 -r1.15
--- ChangeLog	20 Jan 2015 15:53:12 -0000	1.14
+++ ChangeLog	25 Feb 2015 18:14:43 -0000	1.15
@@ -1,6 +1,12 @@
 # ChangeLog for x11-wm/qtile
 # Copyright 1999-2015 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/x11-wm/qtile/ChangeLog,v 1.14 2015/01/20 15:53:12 radhermit Exp $
+# $Header: /var/cvsroot/gentoo-x86/x11-wm/qtile/ChangeLog,v 1.15 2015/02/25 18:14:43 radhermit Exp $
+
+*qtile-0.9.1 (25 Feb 2015)
+
+  25 Feb 2015; Tim Harder <radhermit@g.o> +qtile-0.9.1.ebuild,
+  qtile-9999.ebuild:
+  Version bump, disable docs until required sphinx extensions are in the tree.
 
   20 Jan 2015; Tim Harder <radhermit@g.o> qtile-9999.ebuild:
   Use https git repo URL.



1.12                 x11-wm/qtile/qtile-9999.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-wm/qtile/qtile-9999.ebuild?rev=1.12&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-wm/qtile/qtile-9999.ebuild?rev=1.12&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-wm/qtile/qtile-9999.ebuild?r1=1.11&r2=1.12

Index: qtile-9999.ebuild
===================================================================
RCS file: /var/cvsroot/gentoo-x86/x11-wm/qtile/qtile-9999.ebuild,v
retrieving revision 1.11
retrieving revision 1.12
diff -u -r1.11 -r1.12
--- qtile-9999.ebuild	20 Jan 2015 15:53:12 -0000	1.11
+++ qtile-9999.ebuild	25 Feb 2015 18:14:43 -0000	1.12
@@ -1,9 +1,9 @@
 # Copyright 1999-2015 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/x11-wm/qtile/qtile-9999.ebuild,v 1.11 2015/01/20 15:53:12 radhermit Exp $
+# $Header: /var/cvsroot/gentoo-x86/x11-wm/qtile/qtile-9999.ebuild,v 1.12 2015/02/25 18:14:43 radhermit Exp $
 
 EAPI=5
-PYTHON_COMPAT=( python{2_6,2_7} )
+PYTHON_COMPAT=( python{2_7,3_4} )
 
 inherit distutils-r1 virtualx
 
@@ -20,40 +20,32 @@
 
 LICENSE="MIT"
 SLOT="0"
-IUSE="doc test"
+IUSE="test"
+# docs require sphinxcontrib-blockdiag and sphinxcontrib-seqdiag
 
 RDEPEND="
-	dev-python/pygtk:2[${PYTHON_USEDEP}]
 	>=dev-python/cairocffi-0.6[${PYTHON_USEDEP}]
 	>=dev-python/cffi-0.8.2[${PYTHON_USEDEP}]
 	>=dev-python/six-1.4.1[${PYTHON_USEDEP}]
-	>=dev-python/xcffib-0.1.10[${PYTHON_USEDEP}]
+	>=dev-python/xcffib-0.1.11[${PYTHON_USEDEP}]
+	$(python_gen_cond_dep 'dev-python/trollius[${PYTHON_USEDEP}]' 'python2*')
 "
-DEPEND="
+DEPEND="${RDEPEND}
 	dev-python/setuptools[${PYTHON_USEDEP}]
-	doc? ( dev-python/sphinx[${PYTHON_USEDEP}] )
 	test? (
-		${RDEPEND}
 		dev-python/nose[${PYTHON_USEDEP}]
-		dev-python/python-xlib[${PYTHON_USEDEP}]
 		x11-base/xorg-server[kdrive]
 	)
 "
 
-# tests fail due to xauth errors from python-xlib
 RESTRICT="test"
 
-python_compile_all() {
-	use doc && emake -C docs html
-}
-
 python_test() {
 	VIRTUALX_COMMAND="nosetests" virtualmake
 }
 
 python_install_all() {
 	local DOCS=( CHANGELOG README.rst )
-	use doc && local HTML_DOCS=( docs/_build/html/. )
 	distutils-r1_python_install_all
 
 	insinto /usr/share/xsessions



1.1                  x11-wm/qtile/qtile-0.9.1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-wm/qtile/qtile-0.9.1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-wm/qtile/qtile-0.9.1.ebuild?rev=1.1&content-type=text/plain

Index: qtile-0.9.1.ebuild
===================================================================
# Copyright 1999-2015 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/x11-wm/qtile/qtile-0.9.1.ebuild,v 1.1 2015/02/25 18:14:43 radhermit Exp $

EAPI=5
PYTHON_COMPAT=( python{2_7,3_4} )

inherit distutils-r1 virtualx

if [[ ${PV} == 9999* ]] ; then
	EGIT_REPO_URI="https://github.com/qtile/qtile.git"
	inherit git-r3
else
	SRC_URI="https://github.com/qtile/qtile/archive/v${PV}.tar.gz -> ${P}.tar.gz"
	KEYWORDS="~amd64 ~x86"
fi

DESCRIPTION="A full-featured, hackable tiling window manager written in Python"
HOMEPAGE="http://qtile.org/"

LICENSE="MIT"
SLOT="0"
IUSE="test"
# docs require sphinxcontrib-blockdiag and sphinxcontrib-seqdiag

RDEPEND="
	>=dev-python/cairocffi-0.6[${PYTHON_USEDEP}]
	>=dev-python/cffi-0.8.2[${PYTHON_USEDEP}]
	>=dev-python/six-1.4.1[${PYTHON_USEDEP}]
	>=dev-python/xcffib-0.1.11[${PYTHON_USEDEP}]
	$(python_gen_cond_dep 'dev-python/trollius[${PYTHON_USEDEP}]' 'python2*')
"
DEPEND="${RDEPEND}
	dev-python/setuptools[${PYTHON_USEDEP}]
	test? (
		dev-python/nose[${PYTHON_USEDEP}]
		x11-base/xorg-server[kdrive]
	)
"

RESTRICT="test"

python_test() {
	VIRTUALX_COMMAND="nosetests" virtualmake
}

python_install_all() {
	local DOCS=( CHANGELOG README.rst )
	distutils-r1_python_install_all

	insinto /usr/share/xsessions
	doins resources/qtile.desktop

	exeinto /etc/X11/Sessions
	newexe "${FILESDIR}"/${PN}-session ${PN}
}