Gentoo Archives: gentoo-commits

From: "Alexis Ballier (aballier)" <aballier@g.o>
To: gentoo-commits@l.g.o
Subject: [gentoo-commits] gentoo-x86 commit in media-sound/mpg123: mpg123-1.7.2.ebuild ChangeLog
Date: Wed, 08 Apr 2009 08:11:56
Message-Id: E1LrSt0-0001j1-0j@stork.gentoo.org
aballier    09/04/08 08:11:54

  Modified:             ChangeLog
  Added:                mpg123-1.7.2.ebuild
  Log:
  version bump, bug #264829 and bug #265342
  (Portage version: 2.2_rc28/cvs/Linux x86_64)

Revision  Changes    Path
1.173                media-sound/mpg123/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-sound/mpg123/ChangeLog?rev=1.173&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-sound/mpg123/ChangeLog?rev=1.173&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-sound/mpg123/ChangeLog?r1=1.172&r2=1.173

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-sound/mpg123/ChangeLog,v
retrieving revision 1.172
retrieving revision 1.173
diff -u -r1.172 -r1.173
--- ChangeLog	30 Mar 2009 15:34:00 -0000	1.172
+++ ChangeLog	8 Apr 2009 08:11:53 -0000	1.173
@@ -1,6 +1,11 @@
 # ChangeLog for media-sound/mpg123
 # Copyright 2002-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-sound/mpg123/ChangeLog,v 1.172 2009/03/30 15:34:00 armin76 Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-sound/mpg123/ChangeLog,v 1.173 2009/04/08 08:11:53 aballier Exp $
+
+*mpg123-1.7.2 (08 Apr 2009)
+
+  08 Apr 2009; Alexis Ballier <aballier@g.o> +mpg123-1.7.2.ebuild:
+  version bump, bug #264829 and bug #265342
 
   30 Mar 2009; Raúl Porcel <armin76@g.o> mpg123-1.3.1.ebuild,
   mpg123-1.6.2.ebuild, mpg123-1.6.4.ebuild:



1.1                  media-sound/mpg123/mpg123-1.7.2.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-sound/mpg123/mpg123-1.7.2.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-sound/mpg123/mpg123-1.7.2.ebuild?rev=1.1&content-type=text/plain

Index: mpg123-1.7.2.ebuild
===================================================================
# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-sound/mpg123/mpg123-1.7.2.ebuild,v 1.1 2009/04/08 08:11:53 aballier Exp $

DESCRIPTION="a realtime MPEG 1.0/2.0/2.5 audio player for layers 1, 2 and 3."
HOMEPAGE="http://www.mpg123.org"
SRC_URI="mirror://sourceforge/${PN}/${P}.tar.bz2"

LICENSE="GPL-2 LGPL-2.1"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd"
IUSE="3dnow 3dnowext alsa altivec arts esd ipv6 jack mmx nas network oss portaudio pulseaudio sdl sse"

RDEPEND="alsa? ( media-libs/alsa-lib )
	esd? ( media-sound/esound )
	jack? ( media-sound/jack-audio-connection-kit )
	nas? ( media-libs/nas )
	portaudio? ( media-libs/portaudio )
	pulseaudio? ( media-sound/pulseaudio )
	sdl? ( media-libs/libsdl )
	arts? ( kde-base/arts )"
DEPEND="${RDEPEND}
	dev-util/pkgconfig"

src_unpack() {
	unpack ${A}
	sed -i -e 's:-faltivec::' "${S}"/configure || die "sed failed."
}

src_compile() {
	local myaudio

	use alsa && myaudio="${myaudio} alsa"
	use esd && myaudio="${myaudio} esd"
	use jack && myaudio="${myaudio} jack"
	use nas && myaudio="${myaudio} nas"
	use oss && myaudio="${myaudio} oss"
	use portaudio && myaudio="${myaudio} portaudio"
	use pulseaudio && myaudio="${myaudio} pulse"
	use sdl && myaudio="${myaudio} sdl"
	use arts && myaudio="${myaudio} arts"

	local mycpu

	if use altivec; then
		mycpu="--with-cpu=altivec"
	elif use 3dnowext; then
		mycpu="--with-cpu=3dnowext"
	elif use 3dnow; then
		mycpu="--with-cpu=3dnow"
	elif use sse; then
		mycpu="--with-cpu=sse"
	elif use mmx; then
		mycpu="--with-cpu=mmx"
	fi

	econf --disable-dependency-tracking \
		--with-optimization=0 ${mycpu} \
		--with-audio="${myaudio}" \
		$(use_enable network) \
		$(use_enable ipv6)

	emake || die "emake failed."
}

src_install() {
	emake DESTDIR="${D}" install || die "emake install failed."
	dodoc AUTHORS ChangeLog NEWS* README
}