[gentoo-commits] gentoo-x86 commit in sys-apps/pmount: pmount-0.9.23.ebuild ChangeLog pmount-0.9.22.ebuild

[Samuli Suominen (ssuominen)]

ssuominen    10/06/25 13:47:39

  Modified:             ChangeLog
  Added:                pmount-0.9.23.ebuild
  Removed:              pmount-0.9.22.ebuild
  Log:
  Version bump.
  (Portage version: 2.2_rc67/cvs/Linux x86_64)

Revision  Changes    Path
1.81                 sys-apps/pmount/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/pmount/ChangeLog?rev=1.81&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/pmount/ChangeLog?rev=1.81&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/pmount/ChangeLog?r1=1.80&r2=1.81

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sys-apps/pmount/ChangeLog,v
retrieving revision 1.80
retrieving revision 1.81
diff -u -r1.80 -r1.81
--- ChangeLog	14 May 2010 21:15:17 -0000	1.80
+++ ChangeLog	25 Jun 2010 13:47:39 -0000	1.81
@@ -1,6 +1,11 @@
 # ChangeLog for sys-apps/pmount
 # Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sys-apps/pmount/ChangeLog,v 1.80 2010/05/14 21:15:17 ssuominen Exp $
+# $Header: /var/cvsroot/gentoo-x86/sys-apps/pmount/ChangeLog,v 1.81 2010/06/25 13:47:39 ssuominen Exp $
+
+*pmount-0.9.23 (25 Jun 2010)
+
+  25 Jun 2010; Samuli Suominen <ssuominen@g.o> +pmount-0.9.23.ebuild:
+  Version bump.
 
 *pmount-0.9.22 (14 May 2010)
 



1.1                  sys-apps/pmount/pmount-0.9.23.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/pmount/pmount-0.9.23.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/pmount/pmount-0.9.23.ebuild?rev=1.1&content-type=text/plain

Index: pmount-0.9.23.ebuild
===================================================================
# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sys-apps/pmount/pmount-0.9.23.ebuild,v 1.1 2010/06/25 13:47:39 ssuominen Exp $

EAPI=2
inherit base eutils

DESCRIPTION="Policy based mounter that gives the ability to mount removable devices as a user"
HOMEPAGE="http://pmount.alioth.debian.org/"
SRC_URI="http://dev.gentoo.org/~ssuominen/${P}.tar.bz2"
#SRC_URI="https://alioth.debian.org/frs/download.php/3310/${P}.tar.bz2"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~ppc ~ppc64 ~sh ~sparc ~x86"
IUSE="crypt"

RDEPEND=">=sys-apps/util-linux-2.16
	crypt? ( >=sys-fs/cryptsetup-1.0.5 )"
DEPEND="${RDEPEND}
	dev-util/intltool
	sys-devel/gettext"

PATCHES=( "${FILESDIR}/${PN}-0.9.19-testsuite-missing-dir.patch" )

pkg_setup() {
	enewgroup plugdev
}

src_configure() {
	econf \
		--disable-dependency-tracking \
		--disable-hal
}

src_test() {
	local testdir=${S}/tests/check_fstab

	ln -s $testdir/a $testdir/b && ln -s $testdir/d $testdir/c && \
		ln -s $testdir/c $testdir/e \
		|| die "Unable to create fake symlinks required for testsuite"
	emake check || die
}

src_install () {
	# Must be run SETUID+SETGID, bug #250106
	exeinto /usr/bin
	exeopts -m 6710 -g plugdev
	doexe src/pmount src/pumount || die

	dodoc AUTHORS ChangeLog TODO || die
	doman man/pmount.1 man/pumount.1 || die

	insinto /etc
	doins etc/pmount.allow || die
}

pkg_postinst() {
	elog
	elog "This package has been installed setuid and setgid."

	elog "The permissions are as such that only users that belong to the plugdev"
	elog "group are allowed to run this. But if a script run by root mounts a"
	elog "device, members of the plugdev group will have access to it."
	elog
	elog "Please add your user to the plugdev group to be able to mount USB drives"
}