[gentoo-commits] gentoo-x86 commit in x11-wm/razorqt: razorqt-0.4.1-r2.ebuild ChangeLog

[Johannes Huber (johu)]

johu        12/04/04 10:37:14

  Modified:             ChangeLog
  Added:                razorqt-0.4.1-r2.ebuild
  Log:
  Revision bump unbundles xdg-utils by Alec Moskvin <alecm@×××.com> wrt bug #409025.
  
  (Portage version: 2.2.0_alpha98/cvs/Linux i686)

Revision  Changes    Path
1.3                  x11-wm/razorqt/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-wm/razorqt/ChangeLog?rev=1.3&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-wm/razorqt/ChangeLog?rev=1.3&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-wm/razorqt/ChangeLog?r1=1.2&r2=1.3

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/x11-wm/razorqt/ChangeLog,v
retrieving revision 1.2
retrieving revision 1.3
diff -u -r1.2 -r1.3
--- ChangeLog	27 Mar 2012 17:04:03 -0000	1.2
+++ ChangeLog	4 Apr 2012 10:37:13 -0000	1.3
@@ -1,6 +1,13 @@
 # ChangeLog for x11-wm/razorqt
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/x11-wm/razorqt/ChangeLog,v 1.2 2012/03/27 17:04:03 johu Exp $
+# $Header: /var/cvsroot/gentoo-x86/x11-wm/razorqt/ChangeLog,v 1.3 2012/04/04 10:37:13 johu Exp $
+
+*razorqt-0.4.1-r2 (04 Apr 2012)
+
+  04 Apr 2012; Johannes Huber <johu@g.o>
+  +files/razorqt-0.4.1-unbundle-xdg-utils.patch, +razorqt-0.4.1-r2.ebuild:
+  Revision bump unbundles xdg-utils by Alec Moskvin <alecm@×××.com> wrt bug
+  #409025.
 
 *razorqt-0.4.1-r1 (27 Mar 2012)
 



1.1                  x11-wm/razorqt/razorqt-0.4.1-r2.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-wm/razorqt/razorqt-0.4.1-r2.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-wm/razorqt/razorqt-0.4.1-r2.ebuild?rev=1.1&content-type=text/plain

Index: razorqt-0.4.1-r2.ebuild
===================================================================
# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/x11-wm/razorqt/razorqt-0.4.1-r2.ebuild,v 1.1 2012/04/04 10:37:13 johu Exp $

EAPI=4

inherit cmake-utils

DESCRIPTION="An advanced, easy-to-use, and fast desktop environment based on Qt"
HOMEPAGE="http://razor-qt.org"

if [[ ${PV} = *9999* ]]; then
	inherit git-2
	EGIT_REPO_URI="git://github.com/Razor-qt/razor-qt.git"
	EGIT_BRANCH="0.4.1"
	KEYWORDS=""
else
	SRC_URI="https://github.com/downloads/Razor-qt/razor-qt/${P}.tar.bz2"
	KEYWORDS="~amd64 ~x86"
fi

LICENSE="GPL-2"
SLOT="0"
IUSE="doc policykit"

COMMON_DEPEND="sys-apps/file
	policykit? (
		dev-libs/glib:2
		sys-auth/polkit-qt
	)
	sys-libs/zlib
	x11-libs/libX11
	x11-libs/libXcomposite
	x11-libs/libXcursor
	x11-libs/libXdamage
	x11-libs/libXfixes
	x11-libs/libXrender
	x11-libs/qt-core:4
	x11-libs/qt-dbus:4
	x11-libs/qt-gui:4
	x11-libs/qt-script:4"

DEPEND="${COMMON_DEPEND}
	doc? ( app-doc/doxygen )
	dev-util/cmake"

RDEPEND="${COMMON_DEPEND}
	>=x11-misc/xdg-utils-1.1.0_rc1_p20120319
	|| (
		x11-wm/openbox
		kde-base/kwin
		x11-wm/metacity
		xfce-base/xfwm4
		x11-wm/enlightenment
		x11-wm/fvwm
		x11-wm/sawfish
		x11-wm/windowmaker
		)"

PATCHES=(
	"${FILESDIR}/${P}-automagic.patch"
	"${FILESDIR}/${P}-unbundle-xdg-utils.patch"
)

src_configure() {
	local mycmakeargs=(
		-DBUNDLE_XDG_UTILS=NO
		$(cmake-utils_use_enable policykit)
	)
	cmake-utils_src_configure
}

src_compile() {
	cmake-utils_src_make

	# build developer documentation using Doxygen
	use doc && emake -C "${CMAKE_BUILD_DIR}" docs
}

src_install() {
	cmake-utils_src_install

	# install developer documentation
	use doc && dodoc -r "${CMAKE_BUILD_DIR}/docs"
}

pkg_postinst() {
	einfo "To be able to Shutdown/Reboot from Razor,"
	einfo "make sure sys-power/upower is installed."
	einfo "For the Removable Media plugin to work,"
	einfo "make sure sys-fs/udisks is installed."
}