[gentoo-commits] repo/gentoo:master commit in: dev-python/blessed/

[Louis Sautier]

commit:     95f29329f3bfd69a8190247f5da1fab77737f050
Author:     Louis Sautier <sbraz <AT> gentoo <DOT> org>
AuthorDate: Mon Apr 27 17:17:43 2020 +0000
Commit:     Louis Sautier <sbraz <AT> gentoo <DOT> org>
CommitDate: Mon Apr 27 18:34:44 2020 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=95f29329

dev-python/blessed: new pkg, better and maintained fork of blessings

Package-Manager: Portage-2.3.99, Repoman-2.3.22
Signed-off-by: Louis Sautier <sbraz <AT> gentoo.org>

 dev-python/blessed/Manifest              |  1 +
 dev-python/blessed/blessed-1.17.5.ebuild | 53 ++++++++++++++++++++++++++++++++
 dev-python/blessed/metadata.xml          | 13 ++++++++
 3 files changed, 67 insertions(+)

diff --git a/dev-python/blessed/Manifest b/dev-python/blessed/Manifest
new file mode 100644
index 00000000000..16bfcda031f
--- /dev/null
+++ b/dev-python/blessed/Manifest
@@ -0,0 +1 @@
+DIST blessed-1.17.5.tar.gz 14030669 BLAKE2B e2692c6863599462914f1cee36bd487d42fb1e44e15f841d81ee622619da22a34cda4d78523b07bbd94a9a70e41c9b8342d0da650389d0fbe4ef7a46868535cc SHA512 5973070199d16a71d70c6b25b783a92d72f9dd8d27ca5cdb25b18e07e4b351e1cba751b96113665230c3c01bd1916adafe89d4689e2b341a88640535b7f91317

diff --git a/dev-python/blessed/blessed-1.17.5.ebuild b/dev-python/blessed/blessed-1.17.5.ebuild
new file mode 100644
index 00000000000..907f9aebfe7
--- /dev/null
+++ b/dev-python/blessed/blessed-1.17.5.ebuild
@@ -0,0 +1,53 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( pypy3 python3_{6,7,8} )
+
+inherit distutils-r1
+
+DESCRIPTION="Library for making terminal apps using colors, keyboard input and positioning"
+HOMEPAGE="https://github.com/jquast/blessed"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+SLOT="0"
+LICENSE="MIT"
+KEYWORDS="~amd64"
+IUSE="test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	dev-python/six[${PYTHON_USEDEP}]
+	dev-python/wcwidth[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		${RDEPEND}
+		dev-python/mock[${PYTHON_USEDEP}]
+		dev-python/pytest[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_sphinx docs
+
+python_prepare_all() {
+	# Skip those extensions as they don't have a Gentoo package
+	# Remove calls to scripts that generate rst files because they
+	# are not present in the tarball
+	sed -e '/sphinxcontrib.manpage/d' -e '/sphinx_paramlinks/d' \
+		-e '/^for script in/,/runpy.run_path/d' \
+		-i docs/conf.py || die
+	distutils-r1_python_prepare_all
+}
+
+python_test() {
+	# COLORTERM must not be truecolor
+	# See https://github.com/jquast/blessed/issues/162
+	# Ignore coverage options
+	# Skip two failing tests
+	COLORTERM= pytest -vv --override-ini="addopts=" \
+		--deselect tests/test_core.py::test_number_of_colors_without_tty \
+		--deselect tests/test_core.py::test_number_of_colors_with_tty \
+		|| die "tests failed with ${EPYTHON}"
+}

diff --git a/dev-python/blessed/metadata.xml b/dev-python/blessed/metadata.xml
new file mode 100644
index 00000000000..9bbec69c0c4
--- /dev/null
+++ b/dev-python/blessed/metadata.xml
@@ -0,0 +1,13 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+	<maintainer type="person">
+		<email>sbraz@g.o</email>
+		<name>Louis Sautier</name>
+	</maintainer>
+	<upstream>
+		<remote-id type="pypi">blessed</remote-id>
+		<remote-id type="github">jquast/blessed</remote-id>
+		<bugs-to>https://github.com/jquast/blessed/issues</bugs-to>
+	</upstream>
+</pkgmetadata>