[gentoo-commits] gentoo-x86 commit in sci-chemistry/pymol: ChangeLog pymol-1.2.1.ebuild pymol-1.2.2.ebuild

[Diego Petteno (flameeyes)]

flameeyes    09/12/30 19:36:34

  Modified:             ChangeLog pymol-1.2.1.ebuild
  Added:                pymol-1.2.2.ebuild
  Log:
  Make 1.2.1 not use live subversion, bump to version 1.2.2. Thanks to Justin Lecher who provided the updated ebuilds. Closes bug #282503.
  (Portage version: 2.2_rc61/cvs/Linux x86_64)

Revision  Changes    Path
1.47                 sci-chemistry/pymol/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/sci-chemistry/pymol/ChangeLog?rev=1.47&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/sci-chemistry/pymol/ChangeLog?rev=1.47&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/sci-chemistry/pymol/ChangeLog?r1=1.46&r2=1.47

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sci-chemistry/pymol/ChangeLog,v
retrieving revision 1.46
retrieving revision 1.47
diff -u -r1.46 -r1.47
--- ChangeLog	3 Oct 2009 11:28:03 -0000	1.46
+++ ChangeLog	30 Dec 2009 19:36:34 -0000	1.47
@@ -1,6 +1,13 @@
 # ChangeLog for sci-chemistry/pymol
 # Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sci-chemistry/pymol/ChangeLog,v 1.46 2009/10/03 11:28:03 betelgeuse Exp $
+# $Header: /var/cvsroot/gentoo-x86/sci-chemistry/pymol/ChangeLog,v 1.47 2009/12/30 19:36:34 flameeyes Exp $
+
+*pymol-1.2.2 (30 Dec 2009)
+
+  30 Dec 2009; Diego E. Pettenò <flameeyes@g.o> pymol-1.2.1.ebuild,
+  +pymol-1.2.2.ebuild, +files/pymol-1.2.2-shaders.patch:
+  Make 1.2.1 not use live subversion, bump to version 1.2.2. Thanks to
+  Justin Lecher who provided the updated ebuilds. Closes bug #282503.
 
   03 Oct 2009; Petteri Räty <betelgeuse@g.o> -pymol-1.1-r2.ebuild:
   Remove old version with built_with_use. Fixes bug #285463.



1.5                  sci-chemistry/pymol/pymol-1.2.1.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/sci-chemistry/pymol/pymol-1.2.1.ebuild?rev=1.5&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/sci-chemistry/pymol/pymol-1.2.1.ebuild?rev=1.5&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/sci-chemistry/pymol/pymol-1.2.1.ebuild?r1=1.4&r2=1.5

Index: pymol-1.2.1.ebuild
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sci-chemistry/pymol/pymol-1.2.1.ebuild,v
retrieving revision 1.4
retrieving revision 1.5
diff -u -r1.4 -r1.5
--- pymol-1.2.1.ebuild	9 Sep 2009 21:51:57 -0000	1.4
+++ pymol-1.2.1.ebuild	30 Dec 2009 19:36:34 -0000	1.5
@@ -1,10 +1,10 @@
 # Copyright 1999-2009 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/sci-chemistry/pymol/pymol-1.2.1.ebuild,v 1.4 2009/09/09 21:51:57 maekke Exp $
+# $Header: /var/cvsroot/gentoo-x86/sci-chemistry/pymol/pymol-1.2.1.ebuild,v 1.5 2009/12/30 19:36:34 flameeyes Exp $
 
 EAPI="2"
 
-inherit distutils subversion
+inherit distutils
 
 PYTHON_MODNAME="chempy pmg_tk pymol"
 APBS_PATCH="090618"
@@ -12,8 +12,8 @@
 
 DESCRIPTION="A Python-extensible molecular graphics system."
 HOMEPAGE="http://pymol.sourceforge.net/"
-SRC_URI="apbs? ( mirror://gentoo/apbs_tools.py.${APBS_PATCH}.bz2 )"
-ESVN_REPO_URI="https://pymol.svn.sourceforge.net/svnroot/pymol/trunk/pymol@${REV}"
+SRC_URI="apbs? ( mirror://gentoo/apbs_tools.py.${APBS_PATCH}.bz2 )
+	http://pymol.svn.sourceforge.net/viewvc/pymol/trunk/pymol.tar.gz?view=tar&pathrev=${REV} -> ${P}.tar.gz"
 
 LICENSE="PSF-2.2"
 SLOT="0"
@@ -33,15 +33,12 @@
 		)"
 RDEPEND="${DEPEND}"
 
+S="${WORKDIR}"/${PN}
+
 pkg_setup(){
 	python_version
 }
 
-src_unpack() {
-	use apbs && unpack ${A}
-	subversion_src_unpack
-}
-
 src_prepare() {
 	epatch "${FILESDIR}"/${PV}/${P}-data-path.patch \
 		|| die "Failed to apply data-path.patch"



1.1                  sci-chemistry/pymol/pymol-1.2.2.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/sci-chemistry/pymol/pymol-1.2.2.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/sci-chemistry/pymol/pymol-1.2.2.ebuild?rev=1.1&content-type=text/plain

Index: pymol-1.2.2.ebuild
===================================================================
# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sci-chemistry/pymol/pymol-1.2.2.ebuild,v 1.1 2009/12/30 19:36:34 flameeyes Exp $

EAPI="2"

inherit distutils

PYTHON_MODNAME="chempy pmg_tk pymol"
APBS_PATCH="090618"
REV="3859"

DESCRIPTION="A Python-extensible molecular graphics system."
HOMEPAGE="http://pymol.sourceforge.net/"
SRC_URI="apbs? ( mirror://gentoo/apbs_tools.py.${APBS_PATCH}.bz2 )
	http://pymol.svn.sourceforge.net/viewvc/pymol/trunk/pymol.tar.gz?view=tar&pathrev=${REV} -> ${P}.tar.gz"

LICENSE="PSF-2.2"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="apbs shaders"

DEPEND="dev-python/pmw
		dev-python/numpy
		>=dev-lang/python-2.4[tk]
		media-libs/libpng
		sys-libs/zlib
		virtual/glut
		media-video/mpeg-tools
		apbs? ( dev-libs/maloc
			sci-chemistry/apbs
			sci-chemistry/pdb2pqr
		)"
RDEPEND="${DEPEND}"

S="${WORKDIR}"/${PN}

pkg_setup(){
	python_version
}

src_prepare() {
	epatch "${FILESDIR}"/1.2.1/${PN}-1.2.1-data-path.patch \
		|| die "Failed to apply data-path.patch"

	# Turn off splash screen.  Please do make a project contribution
	# if you are able though.
	[[ -n ${WANT_SPLASH} ]] || epatch "${FILESDIR}"/1.2.1/nosplash-gentoo.patch

	# Respect CFLAGS
	sed -i \
		-e "s:\(ext_comp_args=\).*:\1[]:g" \
		"${S}"/setup.py || die "Failed running sed on setup.py"

	use shaders && epatch "${FILESDIR}"/${PV}/${P}-shaders.patch

	if use apbs; then
		cp -f "${WORKDIR}"/apbs_tools.py.${APBS_PATCH} modules/pmg_tk/startup/apbs_tools.py \
			|| die "Failed to copy apbs_tools.py"

		sed "s:LIBANDPYTHON:$(python_get_libdir):g" \
			-i modules/pmg_tk/startup/apbs_tools.py \
				|| die "Failed running sed on apbs_tools.py"
	fi
}

src_configure() {
	:
}

src_install() {
	distutils_src_install

	# These environment variables should not go in the wrapper script, or else
	# it will be impossible to use the PyMOL libraries from Python.
	cat >> "${T}"/20pymol <<- EOF
		PYMOL_PATH=$(python_get_sitedir)/${PN}
		PYMOL_DATA="/usr/share/pymol/data"
		PYMOL_SCRIPTS="/usr/share/pymol/scripts"
	EOF

	if use apbs; then
		echo "APBS_PSIZE=$(python_get_sitedir)/pdb2pqr/src/psize.py" >> "${T}"/20pymol
	fi

	doenvd "${T}"/20pymol || die "Failed to install env.d file."

	cat >> "${T}"/pymol <<- EOF
	#!/bin/sh
	${python} -O \${PYMOL_PATH}/__init__.py \$*
	EOF

	dobin "${T}"/pymol || die "Failed to install wrapper."

	insinto /usr/share/pymol
	doins -r test data scripts || die "no shared data"

	insinto /usr/share/pymol/examples
	doins -r examples || die "Failed to install docs."

	dodoc DEVELOPERS README || die "Failed to install docs."

	if ! use apbs; then
		rm "${D}"$(python_get_sitedir)/pmg_tk/startup/apbs_tools.py
	fi
}

pkg_postinst(){
	distutils_pkg_postinst

	# The apbs ebuild was just corrected and not bumped #213616
	if use apbs; then
		[ -e /usr/share/apbs-0.5* ] && \
		ewarn "You need to reemerge sci-chemistry/apbs!"
	fi
}