[gentoo-commits] repo/gentoo:master commit in: dev-java/oracle-jre-bin/

[Patrick McLean]

commit:     4d4e25b82f873b35cebf0774f347608237e15bc9
Author:     Patrick McLean <chutzpah <AT> gentoo <DOT> org>
AuthorDate: Wed Jul 26 21:16:01 2017 +0000
Commit:     Patrick McLean <chutzpah <AT> gentoo <DOT> org>
CommitDate: Wed Jul 26 21:18:26 2017 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=4d4e25b8

dev-java/oracle-jre-bin: Version bump to 1.8.0.144

The current 1.8.0.141 version requires an account to download the
distfiles. Non-maintainer bump was authorized by monsieurp on IRC.

Package-Manager: Portage-2.3.6, Repoman-2.3.3

 dev-java/oracle-jre-bin/Manifest                   |   2 +
 .../oracle-jre-bin/oracle-jre-bin-1.8.0.144.ebuild | 251 +++++++++++++++++++++
 2 files changed, 253 insertions(+)

diff --git a/dev-java/oracle-jre-bin/Manifest b/dev-java/oracle-jre-bin/Manifest
index ad8a7341944..fb3d6539bc5 100644
--- a/dev-java/oracle-jre-bin/Manifest
+++ b/dev-java/oracle-jre-bin/Manifest
@@ -3,3 +3,5 @@ DIST jre-8u131-linux-i586.tar.gz 78620957 SHA256 a773f2fe17061ef637ed2094b06313a
 DIST jre-8u131-linux-x64.tar.gz 75920010 SHA256 355e5cdb066d4cada1f9f16f358b6fa6280ff5caf7470cf0d5cdd43083408d35 SHA512 26e6515f8e8b4d1d72337e347810d57fcc99284c18260d9ebd67441c19b9f1f73a9570f58a103477f2642e880a79d6579a5e40d75d06e2f4a92a6d3e07ba59db WHIRLPOOL 9cccc44679ddf103c15d6d6797c97d40ccc3abc63f5b05f78c79650be92cfa5dec8c2c567c456556b6f2f6d9ec23fbfbdf2a936ff569ac1bf7e50ce74f57bcef
 DIST jre-8u141-linux-i586.tar.gz 78655948 SHA256 b1cf6a5161d68fcb16285e9dfdd664e6508287a80c351574327b0257baef3d1a SHA512 d14d48f8984fc1ce033971c222f8422c236e2f30cc46f89e01166222be48ace63b0ed7e877eefc44e8541adc6285ab6f83d135b0a0ffcbeb1c81fb37404beb76 WHIRLPOOL ac01fb6fc533d1f0389fdf2c9b89e785fd05bef37bacb7861a45f08b7bccd4cef4076e2be34a3706b925810e56eeddf065445547d9c7b8c83ba2d6059a69846c
 DIST jre-8u141-linux-x64.tar.gz 75922416 SHA256 f268b4d20577be86e1d98451a27b59fd0e99aacd7e9ad7eb35abc3ffa2370c4d SHA512 04a938e25ee22d2cc3fa986622b8fba4e166c399108b6a61aa2430f17e58ddbafd3650abdcd529630ebc84d21c424b71c924cbe9612f8e24e9484eaca00c1844 WHIRLPOOL a3a43326af5c0724a7517410c2d21469f73323b780e60d5737f6c411336e259636f8a8ce8ac3bd1037630e3fc47de8e709c845740ce6dd4f7eec9add01b2cd59
+DIST jre-8u144-linux-i586.tar.gz 78658631 SHA256 9ac5b0d6cda9279a4959a6eb635d849d745a37dafc24666539d1c8f7d76ab77a SHA512 038e367fb00007e6b0f70ed3e48f318cfcb4144ef88b3a33d6c152cb186ede43622bc5d2fb40b39c695fdbe1fa735ab97f501a6ad0ed0a6cf48b286cc08e9ceb WHIRLPOOL 0bac95fc572bb1466b3f69c7e3dd03a77611366bc7c8076eb2feac41ecfde9a4aea6bb60b52b9db1dc0ec2bffcf553abe4ac4b1ffd28f7f3e1b6b71cd8ffc2fb
+DIST jre-8u144-linux-x64.tar.gz 75922776 SHA256 4e6e11aad54ae3c716a5607ee88d81f3f1e8b5b23ee474b0272dba351ee9f28a SHA512 fba5a5f5959746cb76a71847f5c6e3142816940d18c0022c0baf59611d43b24fae1052eeb217f09e840b5c393118260fb99dd38d1db7e74bb07ab0c34c2e1d60 WHIRLPOOL ac1921780076ff7ab5be5b942d5be0bab7fe12c027f1564b91734086d14c5a0da6b66d137034d7ee0318c4f72cb843013488591d1066a5f55c66dd4f53561a6f

diff --git a/dev-java/oracle-jre-bin/oracle-jre-bin-1.8.0.144.ebuild b/dev-java/oracle-jre-bin/oracle-jre-bin-1.8.0.144.ebuild
new file mode 100644
index 00000000000..f5a75844297
--- /dev/null
+++ b/dev-java/oracle-jre-bin/oracle-jre-bin-1.8.0.144.ebuild
@@ -0,0 +1,251 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit eutils java-vm-2 prefix versionator
+
+# This URIs need updating when bumping!
+JRE_URI="http://www.oracle.com/technetwork/java/javase/downloads/jre8-downloads-2133155.html"
+JCE_URI="http://www.oracle.com/technetwork/java/javase/downloads/jce8-download-2133166.html"
+
+if [[ "$(get_version_component_range 4)" == 0 ]] ; then
+	S_PV="$(get_version_component_range 1-3)"
+else
+	MY_PV_EXT="u$(get_version_component_range 4)"
+	S_PV="$(get_version_component_range 1-4)"
+fi
+
+MY_PV="$(get_version_component_range 2)${MY_PV_EXT}"
+
+AT_amd64="jre-${MY_PV}-linux-x64.tar.gz"
+AT_x86="jre-${MY_PV}-linux-i586.tar.gz"
+
+JCE_DIR="UnlimitedJCEPolicyJDK8"
+JCE_FILE="jce_policy-8.zip"
+
+DESCRIPTION="Oracle's Java SE Runtime Environment"
+HOMEPAGE="http://www.oracle.com/technetwork/java/javase/"
+SRC_URI="
+	amd64? ( ${AT_amd64} )
+	x86? ( ${AT_x86} )
+	jce? ( ${JCE_FILE} )"
+
+LICENSE="Oracle-BCLA-JavaSE"
+SLOT="1.8"
+KEYWORDS="~amd64 ~x86"
+IUSE="alsa commercial cups +fontconfig headless-awt javafx jce nsplugin selinux"
+
+RESTRICT="fetch preserve-libs strip"
+QA_PREBUILT="*"
+
+# NOTES:
+#
+# * cups is dlopened.
+#
+# * libpng is also dlopened but only by libsplashscreen, which isn't
+#   important, so we can exclude that.
+#
+# * We still need to work out the exact AWT and JavaFX dependencies
+#   under MacOS. It doesn't appear to use many, if any, of the
+#   dependencies below.
+#
+RDEPEND="!x64-macos? (
+		!headless-awt? (
+			x11-libs/libX11
+			x11-libs/libXext
+			x11-libs/libXi
+			x11-libs/libXrender
+			x11-libs/libXtst
+		)
+		javafx? (
+			dev-libs/glib:2
+			dev-libs/libxml2:2
+			dev-libs/libxslt
+			media-libs/freetype:2
+			x11-libs/cairo
+			x11-libs/gtk+:2
+			x11-libs/libX11
+			x11-libs/libXtst
+			x11-libs/libXxf86vm
+			x11-libs/pango
+			virtual/opengl
+		)
+	)
+	alsa? ( media-libs/alsa-lib )
+	cups? ( net-print/cups )
+	fontconfig? ( media-libs/fontconfig:1.0 )
+	!prefix? ( sys-libs/glibc:* )
+	selinux? ( sec-policy/selinux-java )"
+
+DEPEND="app-arch/zip
+	jce? ( app-arch/unzip )"
+
+S="${WORKDIR}/jre"
+
+pkg_nofetch() {
+	local AT_ARCH="AT_${ARCH}"
+	local AT="${!AT_ARCH}"
+
+	einfo "Please download '${AT}' from:"
+	einfo "'${JRE_URI}'"
+	einfo "and move it to '${DISTDIR}'"
+
+	if use jce; then
+		einfo "Also download '${JCE_FILE}' from:"
+		einfo "'${JCE_URI}'"
+		einfo "and move it to '${DISTDIR}'"
+	fi
+
+	einfo
+	einfo "If the above mentioned urls do not point to the correct version anymore,"
+	einfo "please download the files from Oracle's java download archive:"
+	einfo
+	einfo "   http://www.oracle.com/technetwork/java/javase/downloads/java-archive-javase8-2177648.html#jre-${MY_PV}-oth-JPR"
+	einfo
+
+}
+
+src_unpack() {
+	default
+
+	# Upstream is changing their versioning scheme every release around 1.8.0.*;
+	# to stop having to change it over and over again, just wildcard match and
+	# live a happy life instead of trying to get this new jre1.8.0_05 to work.
+	mv "${WORKDIR}"/jre* "${S}" || die
+}
+
+src_prepare() {
+	if use jce ; then
+		mv "${WORKDIR}"/${JCE_DIR} lib/security/ || die
+	fi
+
+	default
+
+	# Remove the hook that calls Oracle's evil usage tracker. Not just
+	# because it's evil but because it breaks the sandbox during builds
+	# and we can't find any other feasible way to disable it or make it
+	# write somewhere else. See bug #559936 for details.
+	zip -d lib/rt.jar sun/misc/PostVMInitHook.class || die
+}
+
+src_install() {
+	local dest="/opt/${P}"
+	local ddest="${ED}${dest#/}"
+
+	# Create files used as storage for system preferences.
+	mkdir .systemPrefs || die
+	touch .systemPrefs/.system.lock || die
+	touch .systemPrefs/.systemRootModFile || die
+
+	if ! use alsa ; then
+		rm -vf lib/*/libjsoundalsa.* || die
+	fi
+
+	if ! use commercial; then
+		rm -vfr lib/jfr* || die
+	fi
+
+	if use headless-awt ; then
+		rm -vf lib/*/lib*{[jx]awt,splashscreen}* \
+		   bin/{javaws,policytool} || die
+	fi
+
+	if ! use javafx ; then
+		rm -vf lib/*/lib*{decora,fx,glass,prism}* \
+		   lib/*/libgstreamer-lite.* lib/{,ext/}*fx* || die
+	fi
+
+	if ! use nsplugin ; then
+		rm -vf lib/*/libnpjp2.* || die
+	else
+		local nsplugin=$(echo lib/*/libnpjp2.*)
+	fi
+
+	# Even though plugins linked against multiple ffmpeg versions are
+	# provided, they generally lag behind what Gentoo has available.
+	rm -vf lib/*/libavplugin* || die
+
+	dodoc COPYRIGHT
+	dodir "${dest}"
+	cp -pPR	bin lib man "${ddest}" || die
+
+	if use jce ; then
+		dodir ${dest}/lib/security/strong-jce
+		mv "${ddest}"/lib/security/US_export_policy.jar \
+			"${ddest}"/lib/security/strong-jce || die
+		mv "${ddest}"/lib/security/local_policy.jar \
+			"${ddest}"/lib/security/strong-jce || die
+		dosym "${dest}"/lib/security/${JCE_DIR}/US_export_policy.jar \
+			"${dest}"/lib/security/US_export_policy.jar
+		dosym "${dest}"/lib/security/${JCE_DIR}/local_policy.jar \
+			"${dest}"/lib/security/local_policy.jar
+	fi
+
+	if use nsplugin ; then
+		local nsplugin_link=${nsplugin##*/}
+		nsplugin_link=${nsplugin_link/./-${PN}-${SLOT}.}
+		dosym "${dest}/${nsplugin}" "/usr/$(get_libdir)/nsbrowser/plugins/${nsplugin_link}"
+	fi
+
+	# Install desktop file for the Java Control Panel.
+	# Using ${PN}-${SLOT} to prevent file collision with jre and or other slots.
+	# make_desktop_entry can't be used as ${P} would end up in filename.
+	newicon lib/desktop/icons/hicolor/48x48/apps/sun-jcontrol.png \
+		sun-jcontrol-${PN}-${SLOT}.png || die
+	sed -e "s#Name=.*#Name=Java Control Panel for Oracle JRE ${SLOT}#" \
+		-e "s#Exec=.*#Exec=/opt/${P}/bin/jcontrol#" \
+		-e "s#Icon=.*#Icon=sun-jcontrol-${PN}-${SLOT}#" \
+		-e "s#Application;##" \
+		-e "/Encoding/d" \
+		lib/desktop/applications/sun_java.desktop > \
+		"${T}"/jcontrol-${PN}-${SLOT}.desktop || die
+	domenu "${T}"/jcontrol-${PN}-${SLOT}.desktop
+
+	# Prune all fontconfig files so libfontconfig will be used and only install
+	# a Gentoo specific one if fontconfig is disabled.
+	# http://docs.oracle.com/javase/8/docs/technotes/guides/intl/fontconfig.html
+	rm "${ddest}"/lib/fontconfig.* || die
+	if ! use fontconfig ; then
+		cp "${FILESDIR}"/fontconfig.Gentoo.properties "${T}"/fontconfig.properties || die
+		eprefixify "${T}"/fontconfig.properties
+		insinto "${dest}"/lib/
+		doins "${T}"/fontconfig.properties
+	fi
+
+	# This needs to be done before CDS - #215225
+	java-vm_set-pax-markings "${ddest}"
+
+	# see bug #207282
+	einfo "Creating the Class Data Sharing archives"
+	case ${ARCH} in
+		arm|ia64)
+			${ddest}/bin/java -client -Xshare:dump || die
+			;;
+		x86)
+			${ddest}/bin/java -client -Xshare:dump || die
+			# limit heap size for large memory on x86 #467518
+			# this is a workaround and shouldn't be needed.
+			${ddest}/bin/java -server -Xms64m -Xmx64m -Xshare:dump || die
+			;;
+		*)
+			${ddest}/bin/java -server -Xshare:dump || die
+			;;
+	esac
+
+	# Remove empty dirs we might have copied.
+	find "${D}" -type d -empty -exec rmdir -v {} + || die
+
+	java-vm_install-env "${FILESDIR}"/${PN}.env.sh
+	java-vm_revdep-mask
+	java-vm_sandbox-predict /dev/random /proc/self/coredump_filter
+}
+
+pkg_postinst() {
+	java-vm-2_pkg_postinst
+
+	if ! use headless-awt && ! use javafx; then
+		ewarn "You have disabled the javafx flag. Some modern desktop Java applications"
+		ewarn "require this and they may fail with a confusing error message."
+	fi
+}