[gentoo-commits] gentoo-x86 commit in sys-libs/ss: ChangeLog ss-1.40.9.ebuild

[Mike Frysinger (vapier)]

vapier      08/04/27 22:22:44

  Modified:             ChangeLog
  Added:                ss-1.40.9.ebuild
  Log:
  Version bump.
  (Portage version: 2.2_pre5)

Revision  Changes    Path
1.57                 sys-libs/ss/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/sys-libs/ss/ChangeLog?rev=1.57&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/sys-libs/ss/ChangeLog?rev=1.57&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/sys-libs/ss/ChangeLog?r1=1.56&r2=1.57

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sys-libs/ss/ChangeLog,v
retrieving revision 1.56
retrieving revision 1.57
diff -u -r1.56 -r1.57
--- ChangeLog	28 Mar 2008 08:15:52 -0000	1.56
+++ ChangeLog	27 Apr 2008 22:22:44 -0000	1.57
@@ -1,6 +1,11 @@
 # ChangeLog for sys-libs/ss
 # Copyright 1999-2008 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sys-libs/ss/ChangeLog,v 1.56 2008/03/28 08:15:52 jer Exp $
+# $Header: /var/cvsroot/gentoo-x86/sys-libs/ss/ChangeLog,v 1.57 2008/04/27 22:22:44 vapier Exp $
+
+*ss-1.40.9 (27 Apr 2008)
+
+  27 Apr 2008; Mike Frysinger <vapier@g.o> +ss-1.40.9.ebuild:
+  Version bump.
 
   28 Mar 2008; Jeroen Roovers <jer@g.o> ss-1.40.6.ebuild:
   Stable for HPPA too.



1.1                  sys-libs/ss/ss-1.40.9.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/sys-libs/ss/ss-1.40.9.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/sys-libs/ss/ss-1.40.9.ebuild?rev=1.1&content-type=text/plain

Index: ss-1.40.9.ebuild
===================================================================
# Copyright 1999-2008 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sys-libs/ss/ss-1.40.9.ebuild,v 1.1 2008/04/27 22:22:44 vapier Exp $

inherit eutils flag-o-matic toolchain-funcs multilib

DESCRIPTION="Subsystem command parsing library"
HOMEPAGE="http://e2fsprogs.sourceforge.net/"
SRC_URI="mirror://sourceforge/e2fsprogs/e2fsprogs-${PV}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~x86-fbsd"
IUSE="nls"

RDEPEND="~sys-libs/com_err-${PV}"
DEPEND="${RDEPEND}
	nls? ( sys-devel/gettext )"

S=${WORKDIR}/e2fsprogs-${PV}

env_setup() {
	export LDCONFIG=/bin/true
	export CC=$(tc-getCC)
	export STRIP=/bin/true
}

src_unpack() {
	unpack ${A}
	cd "${S}"
	epatch "${FILESDIR}"/${PN}-1.39-makefile.patch

	# since we've split out com_err/ss into their own ebuilds, we
	# need to fake out the local files.  let the toolchain find them.
	echo "GROUP ( /usr/$(get_libdir)/libcom_err.a )" > lib/libcom_err.a
	echo "GROUP ( /usr/$(get_libdir)/libcom_err.so )" > lib/libcom_err.so
}

src_compile() {
	env_setup

	# We want to use the "bsd" libraries while building on Darwin, but while
	# building on other Gentoo/*BSD we prefer elf-naming scheme.
	local libtype
	case ${CHOST} in
		*-darwin*) libtype=bsd;;
		*)         libtype=elf;;
	esac

	econf \
		--enable-${libtype}-shlibs \
		--with-ldopts="${LDFLAGS}" \
		$(use_enable nls) \
		|| die
	emake -C lib/ss COMPILE_ET=compile_et || die "make ss failed"
}

src_test() {
	env_setup
	emake -j1 -C lib/ss check || die "make check failed"
}

src_install() {
	env_setup

	dodir /usr/share/man/man1
	emake -C lib/ss DESTDIR="${D}" install || die

	# Move shared libraries to /lib/, install static libraries to /usr/lib/,
	# and install linker scripts to /usr/lib/.
	dodir /$(get_libdir)
	mv "${D}"/usr/$(get_libdir)/*.so* "${D}"/$(get_libdir)/ || die "move .so"
	dolib.a lib/libss.a || die "dolib.a"
	gen_usr_ldscript libss.so
}



-- 
gentoo-commits@l.g.o mailing list