[gentoo-commits] gentoo-x86 commit in media-video/mpeg4ip: ChangeLog mpeg4ip-1.5.0.1-r3.ebuild

[Steve Dibb (beandog)]

beandog     08/01/09 17:52:16

  Modified:             ChangeLog
  Added:                mpeg4ip-1.5.0.1-r3.ebuild
  Log:
  Fix nasm detection, bug 204505
  (Portage version: 2.1.4_rc14)

Revision  Changes    Path
1.54                 media-video/mpeg4ip/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-video/mpeg4ip/ChangeLog?rev=1.54&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-video/mpeg4ip/ChangeLog?rev=1.54&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-video/mpeg4ip/ChangeLog?r1=1.53&r2=1.54

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-video/mpeg4ip/ChangeLog,v
retrieving revision 1.53
retrieving revision 1.54
diff -u -r1.53 -r1.54
--- ChangeLog	27 Nov 2007 15:10:56 -0000	1.53
+++ ChangeLog	9 Jan 2008 17:52:15 -0000	1.54
@@ -1,6 +1,12 @@
 # ChangeLog for media-video/mpeg4ip
-# Copyright 2000-2007 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-video/mpeg4ip/ChangeLog,v 1.53 2007/11/27 15:10:56 zzam Exp $
+# Copyright 2000-2008 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/media-video/mpeg4ip/ChangeLog,v 1.54 2008/01/09 17:52:15 beandog Exp $
+
+*mpeg4ip-1.5.0.1-r3 (09 Jan 2008)
+
+  09 Jan 2008; Steve Dibb <beandog@g.o>
+  +files/mpeg4ip-1.5.0.1-nasm-r.patch, +mpeg4ip-1.5.0.1-r3.ebuild:
+  Fix nasm detection, bug 204505
 
   27 Nov 2007; Matthias Schwarzott <zzam@g.o>
   mpeg4ip-1.5.0.1-r1.ebuild, mpeg4ip-1.5.0.1-r2.ebuild:



1.1                  media-video/mpeg4ip/mpeg4ip-1.5.0.1-r3.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-video/mpeg4ip/mpeg4ip-1.5.0.1-r3.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-video/mpeg4ip/mpeg4ip-1.5.0.1-r3.ebuild?rev=1.1&content-type=text/plain

Index: mpeg4ip-1.5.0.1-r3.ebuild
===================================================================
# Copyright 1999-2008 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-video/mpeg4ip/mpeg4ip-1.5.0.1-r3.ebuild,v 1.1 2008/01/09 17:52:15 beandog Exp $

WANT_AUTOMAKE="1.9"

inherit eutils multilib autotools

DESCRIPTION="MPEG 4 implementation library"
HOMEPAGE="http://www.mpeg4ip.net/"
SRC_URI="mirror://sourceforge/${PN}/${P}.tar.gz"
LICENSE="MPL-1.1 LGPL-2 GPL-2 LGPL-2.1 BSD UCL MPEG4"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~x86"
IUSE="ipv6 mmx v4l2 xvid nas alsa esd arts ffmpeg a52 mpeg2 lame aac id3 player mp4live x264"

RDEPEND=" media-libs/libsdl
	player? (
		>=x11-libs/gtk+-2
		ffmpeg? ( >=media-video/ffmpeg-0.4.7 )
		mpeg2? ( media-libs/libmpeg2 )
		id3? ( media-libs/libid3tag )
		a52? ( media-libs/a52dec )
	)
	xvid? ( >=media-libs/xvid-0.9.8 )
	mp4live? (
		>=x11-libs/gtk+-2
		lame? ( >=media-sound/lame-3.92 )
		aac? ( >=media-libs/faac-1.24-r1 )
		ffmpeg? ( >=media-video/ffmpeg-0.4.7 )
		x264? ( media-libs/x264-svn )
	)
	nas? ( media-libs/nas x11-libs/libXt )
	alsa? ( media-libs/alsa-lib )
	arts? ( kde-base/arts )
	esd? ( media-sound/esound )
	=media-libs/libmp4v2-1.5.0.1
	!<media-libs/faad2-2.0-r9 "

DEPEND="${RDEPEND}
	player? ( mmx? ( >=dev-lang/nasm-0.98.19 ) )"

pkg_setup() {
	if ! built_with_use media-libs/libsdl X;
	then
		eerror "media-libs/libsdl does not has X support"
		eerror "You need to rebuild media-libs/libsdl with USE=X"
		die
	fi
}

src_unpack() {
	unpack ${A}

	cd "${S}"
	epatch "${FILESDIR}/mpeg4ip-1.4.1-disable-faac-test.patch"
	epatch "${FILESDIR}/${P}-x264.patch"
	epatch "${FILESDIR}/mpeg4ip-1.5.0.1-newffmpeg.patch"
	epatch "${FILESDIR}/mpeg4ip-1.5.0.1-lX11.patch"
	epatch "${FILESDIR}/mpeg4ip-1.5.0.1-as-needed.patch"
	epatch "${FILESDIR}/${P}-gcc42.patch"
	epatch "${FILESDIR}/${P}-nasm-r.patch"

	eautoreconf
}

src_compile() {
	local myconf
	myconf=" --datadir=/usr/share/mpeg4ip
			$(use_enable ipv6)
			$(use_enable ppc)
			$(use_enable player)
			$(use_enable mp4live)
			$(use_enable xvid)
			$(use_enable nas)
			$(use_enable esd)
			$(use_enable alsa)
			$(use_enable arts)
			--disable-srtp" # need ot add libsrtp to portage

	# Those are possible for both player and mp4live
	if use player || use mp4live ; then
		myconf="${myconf} --enable-gtk-glib
			$(use_enable ffmpeg)"
	fi

	# Those are only relevant for the player
	use player && myconf="${myconf}
			$(use_enable mmx)
			$(use_enable a52 a52dec)
			$(use_enable mpeg2 mpeg2dec)
			$(use_enable id3 id3tags)"
	use player || myconf="${myconf}
			--disable-a52
			--disable-mmx
			--disable-mpeg2dec
			--disable-id3tags"

	# those can only be used for mp4live
	use mp4live && myconf="${myconf}
			$(use_enable v4l2)
			$(use_enable lame mp3lame)
			$(use_enable aac faac)
			$(use_enable x264)"
			# $(use_enable alsa mp4live-alsa)
	use mp4live || myconf="${myconf}
			--disable-v4l2
			--disable-mp3lame
			--disable-faac
			--disable-mp4live-alsa
			--disable-x264"

	./bootstrap --prefix=/usr \
		--host=${CHOST} \
		--mandir=/usr/share/man \
		--infodir=/usr/share/info \
		--datadir=/usr/share \
		--sysconfdir=/etc \
		--libdir=/usr/$(get_libdir) \
		--localstatedir=/var/lib \
		--disable-warns-as-err \
		--enable-server \
		${EXTRA_ECONF} \
		${myconf} || die "configure failed"

	sed -i -e 's:-Werror::' common/video/iso-mpeg4/src/Makefile || die "sed failed"

	emake || die "make failed"
}

src_install () {
	make install DESTDIR="${D}" || die "make install failed"

	rm -f "${D}"/usr/include/mp4.h
	rm -f "${D}"/usr/$(get_libdir)/libmp4v2*

	dodoc doc/MPEG4IP_Guide.pdf doc/*txt AUTHORS TODO

	dohtml doc/*.html FEATURES.html || die

	docinto ietf
	dodoc doc/ietf/*.txt || die

	docinto mcast
	dodoc doc/mcast/mcast.txt doc/mcast/mcast_example doc/mcast/playlist_example || die

}



-- 
gentoo-commits@l.g.o mailing list