[gentoo-commits] repo/gentoo:master commit in: media-video/kmplayer/

[Johannes Huber]

commit:     7c530c202a231774791e3726664a4cd48cfaca15
Author:     Johannes Huber <johu <AT> gentoo <DOT> org>
AuthorDate: Tue Apr 26 09:08:18 2016 +0000
Commit:     Johannes Huber <johu <AT> gentoo <DOT> org>
CommitDate: Tue Apr 26 09:08:39 2016 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=7c530c20

media-video/kmplayer: Version bump 0.11.5

Uses tagged version in upstream repo. No proper release by tarball, lacks
translations and handbook feature.

Gentoo-bug: 580680

Package-Manager: portage-2.2.28

 media-video/kmplayer/Manifest               |  1 +
 media-video/kmplayer/kmplayer-0.11.5.ebuild | 67 +++++++++++++++++++++++++++++
 2 files changed, 68 insertions(+)

diff --git a/media-video/kmplayer/Manifest b/media-video/kmplayer/Manifest
index 542eb5e..1c4725b 100644
--- a/media-video/kmplayer/Manifest
+++ b/media-video/kmplayer/Manifest
@@ -1 +1,2 @@
 DIST kmplayer-0.11.3d.tar.bz2 573173 SHA256 7ebecbc906edcc13e1ae94f4791da80ed4ef73164ef6b81d76c71708c39a6bfb SHA512 c2f0fa1864eecd9a0bf3039639aad41bc36bc6ff8742a8e9714c6df72dd4ee63f80c36036a0582ee8464b48ce22eb96814600ddb199c61fda0b87cfd4c457797 WHIRLPOOL 1a651d1dee10b0ee3609055d645835b4b19e5acf47df39a7773d297749407ea49c893e154f77013469ee4c23724c55ae8c2032b5ca00ddf8f560eb5feb8d1f12
+DIST kmplayer-0.11.5.tar.bz2 684467 SHA256 074afea4187b1e5d2899940da558f584e0145fa6a3e9a5eca5c028d4ba516c09 SHA512 15b53eb3c9d1ac867bf762c8f7aa02bc3ecc813116db7b2aa87b2f9f3f0fc50c3fae5514dd92b18baf6fe16fe2f79ca7e9b64ea4fae13e341e5817be6e0ea729 WHIRLPOOL 6efc74f908c93d784c6e29c4052065c2f0bfb3be9353e8887a3f3008298ad10aa3f92751ed024be9e44161023ccbadbc69579c8d0bd50139c733b8fea7ec67db

diff --git a/media-video/kmplayer/kmplayer-0.11.5.ebuild b/media-video/kmplayer/kmplayer-0.11.5.ebuild
new file mode 100644
index 0000000..d74586e
--- /dev/null
+++ b/media-video/kmplayer/kmplayer-0.11.5.ebuild
@@ -0,0 +1,67 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=6
+
+inherit kde4-base
+
+DESCRIPTION="Video player plugin for Konqueror and basic MPlayer frontend"
+HOMEPAGE="https://projects.kde.org/projects/extragear/multimedia/kmplayer"
+COMMIT_ID="a28ff105e76a227b799c2bbf6e732791de5fb84e"
+SRC_URI="https://quickgit.kde.org/?p=kmplayer.git&a=snapshot&h=${COMMIT_ID}&fmt=tbz2 -> ${P}.tar.bz2"
+
+LICENSE="GPL-2 FDL-1.2 LGPL-2.1"
+SLOT="4"
+KEYWORDS="~amd64 ~x86"
+IUSE="cairo debug expat npp"
+
+DEPEND="
+	media-libs/phonon[qt4]
+	x11-libs/libX11
+	cairo? (
+		x11-libs/cairo
+		x11-libs/pango
+	)
+	expat? ( >=dev-libs/expat-2.0.1 )
+	npp? (
+		$(add_kdeapps_dep kreadconfig)
+		dev-libs/dbus-glib
+		www-plugins/adobe-flash
+		>=x11-libs/gtk+-2.10.14:2
+	)
+"
+RDEPEND="${DEPEND}
+	media-video/mplayer
+"
+
+PATCHES=( "${FILESDIR}/${PN}-0.11.3d-cmake34.patch" )
+
+S="${WORKDIR}/${PN}"
+
+src_prepare() {
+	use npp && epatch "${FILESDIR}/${PN}-flash.patch"
+	sed -e '/add_subdirectory(icons)/d' \
+		-i CMakeLists.txt || die
+
+	kde4-base_src_prepare
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DKMPLAYER_BUILT_WITH_CAIRO=$(usex cairo)
+		-DKMPLAYER_BUILT_WITH_EXPAT=$(usex expat)
+		-DKMPLAYER_BUILT_WITH_NPP=$(usex npp)
+	)
+
+	kde4-base_src_configure
+}
+
+src_install() {
+	kde4-base_src_install
+
+	if use npp; then
+		kwriteconfig --file "${ED}/usr/share/config/kmplayerrc" --group "application/x-shockwave-flash" --key player npp
+		kwriteconfig --file "${ED}/usr/share/config/kmplayerrc" --group "application/x-shockwave-flash" --key plugin /usr/lib/nsbrowser/plugins/libflashplayer.so
+	fi
+}