[gentoo-commits] repo/gentoo:master commit in: games-rpg/to-the-moon/

[Ionen Wolkens]

commit:     f7274b22fe2f253bc446933430635e30dd05bc61
Author:     Ionen Wolkens <ionen <AT> gentoo <DOT> org>
AuthorDate: Sun Jul 18 04:04:18 2021 +0000
Commit:     Ionen Wolkens <ionen <AT> gentoo <DOT> org>
CommitDate: Sun Jul 18 05:14:52 2021 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=f7274b22

games-rpg/to-the-moon: remove use of ARCH in global scope, tidy

Was only used for QA_PREBUILT but is still global variance.

Do not own this version of the game, so only doing (hopefully)
safe changes.

Cleaned up DEPEND (which, at most, should've been BDEPEND). While
these deps can make sense on early stage packages, it's a bit much
for some standalone game.

Also stop calling non-existing gnome2_icon_* in EAPI-7.

Signed-off-by: Ionen Wolkens <ionen <AT> gentoo.org>

 games-rpg/to-the-moon/to-the-moon-0-r1.ebuild | 53 +++++++++------------------
 1 file changed, 17 insertions(+), 36 deletions(-)

diff --git a/games-rpg/to-the-moon/to-the-moon-0-r1.ebuild b/games-rpg/to-the-moon/to-the-moon-0-r1.ebuild
index 619cdd02666..a5cc9e2b6f8 100644
--- a/games-rpg/to-the-moon/to-the-moon-0-r1.ebuild
+++ b/games-rpg/to-the-moon/to-the-moon-0-r1.ebuild
@@ -3,27 +3,25 @@
 
 EAPI=7
 
-inherit desktop gnome2-utils unpacker wrapper
+inherit desktop unpacker wrapper
+
+MY_PN="ToTheMoon"
 
-MY_PN=ToTheMoon
 DESCRIPTION="Two doctors traversing the memories of a dying man to fulfill his last wish"
 HOMEPAGE="http://freebirdgames.com/games/to-the-moon"
 SRC_URI="${MY_PN}_linux_1389114090.sh"
-S="${WORKDIR}"/data
+S="${WORKDIR}/data"
 
 LICENSE="all-rights-reserved bundled-libs? ( LGPL-2 LGPL-2.1 ZLIB )"
 SLOT="0"
 KEYWORDS="~amd64 ~x86"
 IUSE="bundled-libs"
+RESTRICT="bindist fetch"
 
-RESTRICT="fetch bindist splitdebug"
-
-QA_PREBUILT="opt/${PN}/${MY_PN}.bin*"
-if [[ ${ARCH} == "amd64" ]] ; then
-	QA_PREBUILT="${QA_PREBUILT} opt/${PN}/lib64/*"
-else
-	QA_PREBUILT="${QA_PREBUILT} opt/${PN}/lib/*"
-fi
+QA_PREBUILT="
+	opt/${PN}/${MY_PN}.bin*
+	opt/${PN}/lib/*
+	opt/${PN}/lib64/*"
 
 # TODO: unbundling sdl-sound breaks the game
 RDEPEND="
@@ -37,17 +35,11 @@ RDEPEND="
 		media-libs/sdl2-ttf
 	)
 "
-DEPEND="
-	sys-apps/coreutils
-	sys-apps/grep
-"
 
 pkg_nofetch() {
-	einfo
 	einfo "Please buy & download ${SRC_URI} from:"
 	einfo "  ${HOMEPAGE}"
 	einfo "and move/link it to your DISTDIR directory."
-	einfo
 }
 
 src_unpack() {
@@ -64,35 +56,24 @@ src_unpack() {
 
 src_install() {
 	local dir=/opt/${PN}
-	local libsuffix=$(usex amd64 "64" "")
-	local arch=$(usex amd64 "x86_64" "x86")
+	local libsuffix=$(usex amd64 64 '')
+	local arch=$(usex amd64 x86_64 x86)
 
-	insinto "${dir}"
+	insinto ${dir}
 	doins -r noarch/{Audio,Data,Fonts,Graphics,Game.ini,mkxp.conf,ToTheMoon.png}
 
-	exeinto "${dir}"
+	exeinto ${dir}
 	doexe ${arch}/${MY_PN}.bin.${arch}
 
-	exeinto "${dir}/lib${libsuffix}"
+	exeinto ${dir}/lib${libsuffix}
 	if use bundled-libs ; then
 		doexe ${arch}/lib${libsuffix}/*
 	else
 		doexe ${arch}/lib${libsuffix}/libSDL_sound-1.0.so.1
 	fi
 
-	make_wrapper ${PN} "./${MY_PN}.bin.${arch}" "${dir}" "${dir}/lib${libsuffix}"
-	make_desktop_entry ${PN} "To the Moon"
-	newicon -s 32 noarch/${MY_PN}.png ${PN}.png
-}
-
-pkg_preinst() {
-	gnome2_icon_savelist
-}
+	make_wrapper ${PN} ./${MY_PN}.bin.${arch} ${dir}{,/lib${libsuffix}}
 
-pkg_postinst() {
-	gnome2_icon_cache_update
-}
-
-pkg_postrm() {
-	gnome2_icon_cache_update
+	newicon noarch/${MY_PN}.png ${PN}.png
+	make_desktop_entry ${PN} "To the Moon"
 }